public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-01-06  2:00 Mike Frysinger (vapier)
  0 siblings, 0 replies; 6+ messages in thread
From: Mike Frysinger (vapier) @ 2013-01-06  2:00 UTC (permalink / raw
  To: gentoo-commits

vapier      13/01/06 02:00:17

  Modified:             ChangeLog
  Added:                netpbm-10.61.00.ebuild
  Log:
  Version bump #450154 by Samuli Suominen.
  
  (Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.266                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.266&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.266&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.265&r2=1.266

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.265
retrieving revision 1.266
diff -u -r1.265 -r1.266
--- ChangeLog	18 Jul 2012 21:50:27 -0000	1.265
+++ ChangeLog	6 Jan 2013 02:00:17 -0000	1.266
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/netpbm
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.265 2012/07/18 21:50:27 vapier Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.266 2013/01/06 02:00:17 vapier Exp $
+
+*netpbm-10.61.00 (06 Jan 2013)
+
+  06 Jan 2013; Mike Frysinger <vapier@gentoo.org> +netpbm-10.61.00.ebuild:
+  Version bump #450154 by Samuli Suominen.
 
 *netpbm-10.59.00 (18 Jul 2012)
 



1.1                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.1&content-type=text/plain

Index: netpbm-10.61.00.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.1 2013/01/06 02:00:17 vapier Exp $

EAPI="4"

inherit toolchain-funcs eutils multilib

DESCRIPTION="A set of utilities for converting to/from the netpbm (and related) formats"
HOMEPAGE="http://netpbm.sourceforge.net/"
SRC_URI="mirror://gentoo/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc jbig jpeg jpeg2k png rle svga tiff X xml zlib"

RDEPEND="jbig? ( media-libs/jbigkit )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( media-libs/jasper )
	png? ( >=media-libs/libpng-1.4:0 )
	rle? ( media-libs/urt )
	svga? ( media-libs/svgalib )
	tiff? ( >=media-libs/tiff-3.5.5:0 )
	xml? ( dev-libs/libxml2 )
	zlib? ( sys-libs/zlib )
	X? ( x11-libs/libX11 )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	sys-devel/flex"

netpbm_libtype() {
	case ${CHOST} in
		*-darwin*) echo dylib;;
		*)         echo unixshared;;
	esac
}
netpbm_libsuffix() {
	local suffix=$(get_libname)
	echo ${suffix//\.}
}
netpbm_ldshlib() {
	case ${CHOST} in
		*-darwin*) echo '$(LDFLAGS) -dynamiclib -install_name $(SONAME)';;
		*)         echo '$(LDFLAGS) -shared -Wl,-soname,$(SONAME)';;
	esac
}
netpbm_config() {
	if use $1 ; then
		[[ $2 != "!" ]] && echo -l${2:-$1}
	else
		echo NONE
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/netpbm-10.31-build.patch

	# make sure we use system urt
	sed -i '/SUPPORT_SUBDIRS/s:urt::' GNUmakefile || die
	rm -rf urt

	# take care of the importinc stuff ourselves by only doing it once
	# at the top level and having all subdirs use that one set #149843
	sed -i \
		-e '/^importinc:/s|^|importinc:\nmanual_|' \
		-e '/-Iimportinc/s|-Iimp|-I"$(BUILDDIR)"/imp|g'\
		common.mk || die
	sed -i \
		-e '/%.c/s: importinc$::' \
		common.mk lib/Makefile lib/util/Makefile || die

	# avoid ugly depend.mk warnings
	touch $(find . -name Makefile | sed s:Makefile:depend.mk:g)
}

src_configure() {
	cat config.mk.in - >> config.mk <<-EOF
	# Misc crap
	BUILD_FIASCO = N
	SYMLINK = ln -sf

	# Toolchain options
	CC = $(tc-getCC) -Wall
	LD = \$(CC)
	CC_FOR_BUILD = $(tc-getBUILD_CC)
	LD_FOR_BUILD = \$(CC_FOR_BUILD)
	AR = $(tc-getAR)
	RANLIB = $(tc-getRANLIB)

	STRIPFLAG =
	CFLAGS_SHLIB = -fPIC

	LDRELOC = \$(LD) -r
	LDSHLIB = $(netpbm_ldshlib)
	LINKER_CAN_DO_EXPLICIT_LIBRARY = N # we can, but dont want to
	LINKERISCOMPILER = Y
	NETPBMLIBSUFFIX = $(netpbm_libsuffix)
	NETPBMLIBTYPE = $(netpbm_libtype)

	# Gentoo build options
	TIFFLIB = $(netpbm_config tiff)
	# Let tiff worry about its own dependencies #395753
	TIFFLIB_NEEDS_JPEG = N
	TIFFLIB_NEEDS_Z = N
	JPEGLIB = $(netpbm_config jpeg)
	PNGLIB = $(netpbm_config png)
	ZLIB = $(netpbm_config zlib z)
	LINUXSVGALIB = $(netpbm_config svga vga)
	XML2_LIBS = $(netpbm_config xml xml2)
	JBIGLIB = -ljbig
	JBIGHDR_DIR = $(netpbm_config jbig "!")
	JASPERLIB = -ljasper
	JASPERHDR_DIR = $(netpbm_config jpeg2k "!")
	URTLIB = $(netpbm_config rle)
	URTHDR_DIR =
	X11LIB = $(netpbm_config X X11)
	X11HDR_DIR =
	EOF
	# cannot chain the die with the heredoc above as bash-3
	# has a parser bug in that setup #282902
	[ $? -eq 0 ] || die "writing config.mk failed"
}

src_compile() {
	emake -j1 pm_config.h version.h manual_importinc #149843
	emake
}

src_install() {
	# Subdir make targets like to use `mkdir` all over the place
	# without any actual dependencies, thus the -j1.
	emake -j1 package pkgdir="${D}"/usr

	[[ $(get_libdir) != "lib" ]] && mv "${D}"/usr/lib "${D}"/usr/$(get_libdir)

	# Remove cruft that we don't need, and move around stuff we want
	rm "${D}"/usr/bin/{doc.url,manweb} || die
	rm -r "${D}"/usr/man/web || die
	rm -r "${D}"/usr/link || die
	rm "${D}"/usr/{README,VERSION,config_template,pkginfo} || die
	dodir /usr/share
	mv "${D}"/usr/man "${D}"/usr/share/ || die
	mv "${D}"/usr/misc "${D}"/usr/share/netpbm || die

	doman userguide/*.[0-9]
	use doc && dohtml -r userguide
	dodoc README
	cd doc
	dodoc HISTORY Netpbm.programming USERDOC
	dohtml -r .
}





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-01-06 19:16 Mike Frysinger (vapier)
  0 siblings, 0 replies; 6+ messages in thread
From: Mike Frysinger (vapier) @ 2013-01-06 19:16 UTC (permalink / raw
  To: gentoo-commits

vapier      13/01/06 19:16:58

  Modified:             netpbm-10.61.00.ebuild ChangeLog
  Log:
  Set up environment for src_test to run properly #450530 by Michael Palimaka.
  
  (Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.2                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?r1=1.1&r2=1.2

Index: netpbm-10.61.00.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- netpbm-10.61.00.ebuild	6 Jan 2013 02:00:17 -0000	1.1
+++ netpbm-10.61.00.ebuild	6 Jan 2013 19:16:58 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.1 2013/01/06 02:00:17 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.2 2013/01/06 19:16:58 vapier Exp $
 
 EAPI="4"
 
@@ -60,6 +60,21 @@
 	sed -i '/SUPPORT_SUBDIRS/s:urt::' GNUmakefile || die
 	rm -rf urt
 
+	# disable certain tests based on active USE flags
+	local del=(
+		$(usex rle '' utahrle-roundtrip)
+	)
+	if [[ ${#del[@]} -gt 0 ]] ; then
+		sed -i -r $(printf -- ' -e /%s.test/d' "${del[@]}") test/Test-Order || die
+	fi
+	del=(
+		pnmtofiasco # We always disable fiasco
+		$(usex rle '' 'pnmtorle rletopnm')
+	)
+	if [[ ${#del[@]} -gt 0 ]] ; then
+		sed -i -r $(printf -- ' -e s/\<%s\>(:.ok)?//' "${del[@]}") test/all-in-place.{ok,test} || die
+	fi
+
 	# take care of the importinc stuff ourselves by only doing it once
 	# at the top level and having all subdirs use that one set #149843
 	sed -i \
@@ -80,6 +95,10 @@
 	BUILD_FIASCO = N
 	SYMLINK = ln -sf
 
+	# These vars let src_test work by default
+	PKGDIR_DEFAULT = ${T}/netpbm
+	RESULTDIR_DEFAULT = ${T}/netpbm-test
+
 	# Toolchain options
 	CC = $(tc-getCC) -Wall
 	LD = \$(CC)
@@ -127,6 +146,12 @@
 	emake
 }
 
+src_test() {
+	# The code wants to install everything first and then test the result.
+	emake install.bin
+	emake check
+}
+
 src_install() {
 	# Subdir make targets like to use `mkdir` all over the place
 	# without any actual dependencies, thus the -j1.



1.267                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.267&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.267&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.266&r2=1.267

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.266
retrieving revision 1.267
diff -u -r1.266 -r1.267
--- ChangeLog	6 Jan 2013 02:00:17 -0000	1.266
+++ ChangeLog	6 Jan 2013 19:16:58 -0000	1.267
@@ -1,6 +1,9 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.266 2013/01/06 02:00:17 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.267 2013/01/06 19:16:58 vapier Exp $
+
+  06 Jan 2013; Mike Frysinger <vapier@gentoo.org> netpbm-10.61.00.ebuild:
+  Set up environment for src_test to run properly #450530 by Michael Palimaka.
 
 *netpbm-10.61.00 (06 Jan 2013)
 





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-05-12 21:25 Mike Frysinger (vapier)
  0 siblings, 0 replies; 6+ messages in thread
From: Mike Frysinger (vapier) @ 2013-05-12 21:25 UTC (permalink / raw
  To: gentoo-commits

vapier      13/05/12 21:25:01

  Modified:             netpbm-10.61.00.ebuild ChangeLog
  Log:
  Install local set of libs before testing #467198 by Patrick Lauer.
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.3                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?r1=1.2&r2=1.3

Index: netpbm-10.61.00.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- netpbm-10.61.00.ebuild	6 Jan 2013 19:16:58 -0000	1.2
+++ netpbm-10.61.00.ebuild	12 May 2013 21:25:01 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.2 2013/01/06 19:16:58 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.3 2013/05/12 21:25:01 vapier Exp $
 
 EAPI="4"
 
@@ -148,7 +148,7 @@
 
 src_test() {
 	# The code wants to install everything first and then test the result.
-	emake install.bin
+	emake install.{bin,lib}
 	emake check
 }
 



1.269                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.269&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.269&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.268&r2=1.269

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.268
retrieving revision 1.269
diff -u -r1.268 -r1.269
--- ChangeLog	5 Feb 2013 17:47:08 -0000	1.268
+++ ChangeLog	12 May 2013 21:25:01 -0000	1.269
@@ -1,6 +1,9 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.268 2013/02/05 17:47:08 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.269 2013/05/12 21:25:01 vapier Exp $
+
+  12 May 2013; Mike Frysinger <vapier@gentoo.org> netpbm-10.61.00.ebuild:
+  Install local set of libs before testing #467198 by Patrick Lauer.
 
   05 Feb 2013; Michael Sterrett <mr_bones_@gentoo.org>
   -files/netpbm-10.56.00-alloca.patch, -netpbm-10.56.00.ebuild,





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-05-29 15:15 Mike Frysinger (vapier)
  0 siblings, 0 replies; 6+ messages in thread
From: Mike Frysinger (vapier) @ 2013-05-29 15:15 UTC (permalink / raw
  To: gentoo-commits

vapier      13/05/29 15:15:05

  Modified:             netpbm-10.61.00.ebuild ChangeLog
  Log:
  Disable jbig tests when USE=-jbig and fix all-in-place test failure due to fiascotopnm #450530#6 by Andreas Sturmlechner.
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.4                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?r1=1.3&r2=1.4

Index: netpbm-10.61.00.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- netpbm-10.61.00.ebuild	12 May 2013 21:25:01 -0000	1.3
+++ netpbm-10.61.00.ebuild	29 May 2013 15:15:05 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.3 2013/05/12 21:25:01 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.4 2013/05/29 15:15:05 vapier Exp $
 
 EAPI="4"
 
@@ -55,6 +55,7 @@
 
 src_prepare() {
 	epatch "${FILESDIR}"/netpbm-10.31-build.patch
+	epatch "${FILESDIR}"/netpbm-10.61-test.patch
 
 	# make sure we use system urt
 	sed -i '/SUPPORT_SUBDIRS/s:urt::' GNUmakefile || die
@@ -62,17 +63,20 @@
 
 	# disable certain tests based on active USE flags
 	local del=(
-		$(usex rle '' utahrle-roundtrip)
+		$(usex jbig '' 'jbigtopnm pnmtojbig')
+		$(usex rle '' 'utahrle-roundtrip')
 	)
 	if [[ ${#del[@]} -gt 0 ]] ; then
 		sed -i -r $(printf -- ' -e /%s.test/d' "${del[@]}") test/Test-Order || die
 	fi
 	del=(
-		pnmtofiasco # We always disable fiasco
+		pnmtofiasco fiascotopnm # We always disable fiasco
+		$(usex jbig '' 'jbigtopnm pnmtojbig')
 		$(usex rle '' 'pnmtorle rletopnm')
 	)
 	if [[ ${#del[@]} -gt 0 ]] ; then
 		sed -i -r $(printf -- ' -e s/\<%s\>(:.ok)?//' "${del[@]}") test/all-in-place.{ok,test} || die
+		sed -i '/^$/d' test/all-in-place.ok || die
 	fi
 
 	# take care of the importinc stuff ourselves by only doing it once



1.270                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.270&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.270&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.269&r2=1.270

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.269
retrieving revision 1.270
diff -u -r1.269 -r1.270
--- ChangeLog	12 May 2013 21:25:01 -0000	1.269
+++ ChangeLog	29 May 2013 15:15:05 -0000	1.270
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.269 2013/05/12 21:25:01 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.270 2013/05/29 15:15:05 vapier Exp $
+
+  29 May 2013; Mike Frysinger <vapier@gentoo.org>
+  +files/netpbm-10.61-test.patch, netpbm-10.61.00.ebuild:
+  Disable jbig tests when USE=-jbig and fix all-in-place test failure due to
+  fiascotopnm #450530#6 by Andreas Sturmlechner.
 
   12 May 2013; Mike Frysinger <vapier@gentoo.org> netpbm-10.61.00.ebuild:
   Install local set of libs before testing #467198 by Patrick Lauer.





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-06-13 20:05 Sebastien Fabbro (bicatali)
  0 siblings, 0 replies; 6+ messages in thread
From: Sebastien Fabbro (bicatali) @ 2013-06-13 20:05 UTC (permalink / raw
  To: gentoo-commits

bicatali    13/06/13 20:05:30

  Modified:             netpbm-10.61.00.ebuild ChangeLog
  Log:
  Keyword amd64-linux and x86-linux
  
  (Portage version: 2.2.01.22013-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.5                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?r1=1.4&r2=1.5

Index: netpbm-10.61.00.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- netpbm-10.61.00.ebuild	29 May 2013 15:15:05 -0000	1.4
+++ netpbm-10.61.00.ebuild	13 Jun 2013 20:05:30 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.4 2013/05/29 15:15:05 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.5 2013/06/13 20:05:30 bicatali Exp $
 
 EAPI="4"
 
@@ -12,7 +12,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~amd64-linux ~x86 ~x86-fbsd ~x86-linux"
 IUSE="doc jbig jpeg jpeg2k png rle svga tiff X xml zlib"
 
 RDEPEND="jbig? ( media-libs/jbigkit )
@@ -159,18 +159,18 @@
 src_install() {
 	# Subdir make targets like to use `mkdir` all over the place
 	# without any actual dependencies, thus the -j1.
-	emake -j1 package pkgdir="${D}"/usr
+	emake -j1 package pkgdir="${ED}"/usr
 
-	[[ $(get_libdir) != "lib" ]] && mv "${D}"/usr/lib "${D}"/usr/$(get_libdir)
+	[[ $(get_libdir) != "lib" ]] && mv "${ED}"/usr/lib "${ED}"/usr/$(get_libdir)
 
 	# Remove cruft that we don't need, and move around stuff we want
-	rm "${D}"/usr/bin/{doc.url,manweb} || die
-	rm -r "${D}"/usr/man/web || die
-	rm -r "${D}"/usr/link || die
-	rm "${D}"/usr/{README,VERSION,config_template,pkginfo} || die
+	rm "${ED}"/usr/bin/{doc.url,manweb} || die
+	rm -r "${ED}"/usr/man/web || die
+	rm -r "${ED}"/usr/link || die
+	rm "${ED}"/usr/{README,VERSION,config_template,pkginfo} || die
 	dodir /usr/share
-	mv "${D}"/usr/man "${D}"/usr/share/ || die
-	mv "${D}"/usr/misc "${D}"/usr/share/netpbm || die
+	mv "${ED}"/usr/man "${ED}"/usr/share/ || die
+	mv "${ED}"/usr/misc "${ED}"/usr/share/netpbm || die
 
 	doman userguide/*.[0-9]
 	use doc && dohtml -r userguide



1.271                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.271&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.271&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.270&r2=1.271

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.270
retrieving revision 1.271
diff -u -r1.270 -r1.271
--- ChangeLog	29 May 2013 15:15:05 -0000	1.270
+++ ChangeLog	13 Jun 2013 20:05:30 -0000	1.271
@@ -1,6 +1,9 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.270 2013/05/29 15:15:05 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.271 2013/06/13 20:05:30 bicatali Exp $
+
+  13 Jun 2013; Sébastien Fabbro <bicatali@gentoo.org> netpbm-10.61.00.ebuild:
+  Keyword amd64-linux and x86-linux
 
   29 May 2013; Mike Frysinger <vapier@gentoo.org>
   +files/netpbm-10.61-test.patch, netpbm-10.61.00.ebuild:





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog
@ 2013-07-28 19:32 Alexis Ballier (aballier)
  0 siblings, 0 replies; 6+ messages in thread
From: Alexis Ballier (aballier) @ 2013-07-28 19:32 UTC (permalink / raw
  To: gentoo-commits

aballier    13/07/28 19:32:53

  Modified:             netpbm-10.61.00.ebuild ChangeLog
  Log:
  keyword ~amd64-fbsd, bug #477750
  
  (Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.6                  media-libs/netpbm/netpbm-10.61.00.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild?r1=1.5&r2=1.6

Index: netpbm-10.61.00.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- netpbm-10.61.00.ebuild	13 Jun 2013 20:05:30 -0000	1.5
+++ netpbm-10.61.00.ebuild	28 Jul 2013 19:32:53 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.5 2013/06/13 20:05:30 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.61.00.ebuild,v 1.6 2013/07/28 19:32:53 aballier Exp $
 
 EAPI="4"
 
@@ -12,7 +12,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~amd64-linux ~x86 ~x86-fbsd ~x86-linux"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
 IUSE="doc jbig jpeg jpeg2k png rle svga tiff X xml zlib"
 
 RDEPEND="jbig? ( media-libs/jbigkit )



1.272                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.272&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.272&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.271&r2=1.272

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.271
retrieving revision 1.272
diff -u -r1.271 -r1.272
--- ChangeLog	13 Jun 2013 20:05:30 -0000	1.271
+++ ChangeLog	28 Jul 2013 19:32:53 -0000	1.272
@@ -1,6 +1,9 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.271 2013/06/13 20:05:30 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.272 2013/07/28 19:32:53 aballier Exp $
+
+  28 Jul 2013; Alexis Ballier <aballier@gentoo.org> netpbm-10.61.00.ebuild:
+  keyword ~amd64-fbsd, bug #477750
 
   13 Jun 2013; Sébastien Fabbro <bicatali@gentoo.org> netpbm-10.61.00.ebuild:
   Keyword amd64-linux and x86-linux





^ permalink raw reply	[flat|nested] 6+ messages in thread
end of thread, other threads:[~2013-07-28 19:32 UTC | newest]

Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-06-13 20:05 [gentoo-commits] gentoo-x86 commit in media-libs/netpbm: netpbm-10.61.00.ebuild ChangeLog Sebastien Fabbro (bicatali)
  -- strict thread matches above, loose matches on Subject: below --
2013-07-28 19:32 Alexis Ballier (aballier)
2013-05-29 15:15 Mike Frysinger (vapier)
2013-05-12 21:25 Mike Frysinger (vapier)
2013-01-06 19:16 Mike Frysinger (vapier)
2013-01-06  2:00 Mike Frysinger (vapier)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox