[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlnet: ChangeLog ocamlnet-3.6.5.ebuild

[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlnet: ChangeLog ocamlnet-3.6.5.ebuild

[Alexis Ballier (aballier)]

aballier    13/06/11 23:54:54

  Modified:             ChangeLog
  Added:                ocamlnet-3.6.5.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha179/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.74                 dev-ml/ocamlnet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	30 Mar 2013 14:55:23 -0000	1.73
+++ ChangeLog	11 Jun 2013 23:54:54 -0000	1.74
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/ocamlnet
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.73 2013/03/30 14:55:23 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.74 2013/06/11 23:54:54 aballier Exp $
+
+*ocamlnet-3.6.5 (11 Jun 2013)
+
+  11 Jun 2013; Alexis Ballier <aballier@gentoo.org> +ocamlnet-3.6.5.ebuild:
+  version bump
 
   30 Mar 2013; Ulrich Müller <ulm@gentoo.org> ocamlnet-3.5.ebuild,
   ocamlnet-3.6.3.ebuild:



1.1                  dev-ml/ocamlnet/ocamlnet-3.6.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.6.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.6.5.ebuild?rev=1.1&content-type=text/plain

Index: ocamlnet-3.6.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.6.5.ebuild,v 1.1 2013/06/11 23:54:54 aballier Exp $

EAPI="5"

inherit eutils findlib

MY_P=${P/_beta/test}
DESCRIPTION="Modules for OCaml application-level Internet protocols"
HOMEPAGE="http://projects.camlcity.org/projects/ocamlnet.html"
SRC_URI="http://download.camlcity.org/download/${MY_P}.tar.gz"

LICENSE="ZLIB GPL-2+"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="cryptokit gtk ssl tk httpd +ocamlopt +pcre zip"
RESTRICT="installsources"

# the auth-dh compile flag has been disabled as well, since it depends on
# ocaml-cryptgps, which is not available.

DEPEND=">=dev-ml/findlib-1.0
		pcre? ( >=dev-ml/pcre-ocaml-5:= )
		>=dev-lang/ocaml-3.10.2:=[tk?,ocamlopt?]
		cryptokit? ( dev-ml/cryptokit:= )
		gtk? ( >=dev-ml/lablgtk-2:= )
		ssl? ( >=dev-ml/ocaml-ssl-0.4:= )
		zip? ( dev-ml/camlzip:= )
		"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

ocamlnet_use_with() {
	if use $1; then
		echo "-with-$2"
	else
		echo "-without-$2"
	fi
}

ocamlnet_use_enable() {
	if use $1; then
		echo "-enable-$2"
	else
		echo "-disable-$2"
	fi
}

src_configure() {
	./configure \
		-bindir /usr/bin \
		-datadir /usr/share/${PN} \
		$(ocamlnet_use_enable cryptokit crypto) \
		$(ocamlnet_use_enable gtk gtk2) \
		$(ocamlnet_use_enable pcre pcre) \
		$(ocamlnet_use_enable ssl ssl) \
		$(ocamlnet_use_enable tk tcl) \
		$(ocamlnet_use_enable zip zip) \
		$(ocamlnet_use_with httpd nethttpd) \
		|| die "Error : econf failed!"
}

src_compile() {
	emake -j1 all
	if use ocamlopt; then
		emake -j1 opt
	fi
}

src_install() {
	export STRIP_MASK="*/bin/*"
	findlib_src_install
}