* [gentoo-commits] gentoo-x86 commit in media-plugins/mythplugins: mythplugins-0.26.0_p20130526.ebuild ChangeLog
@ 2013-06-09 19:48 Richard Freeman (rich0)
0 siblings, 0 replies; only message in thread
From: Richard Freeman (rich0) @ 2013-06-09 19:48 UTC (permalink / raw
To: gentoo-commits
rich0 13/06/09 19:48:44
Modified: ChangeLog
Added: mythplugins-0.26.0_p20130526.ebuild
Log:
Update patch set.
(Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0x08C170DE55EC123A)
Revision Changes Path
1.16 media-plugins/mythplugins/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?r1=1.15&r2=1.16
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog 5 May 2013 01:43:54 -0000 1.15
+++ ChangeLog 9 Jun 2013 19:48:44 -0000 1.16
@@ -1,6 +1,12 @@
# ChangeLog for media-plugins/mythplugins
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.15 2013/05/05 01:43:54 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.16 2013/06/09 19:48:44 rich0 Exp $
+
+*mythplugins-0.26.0_p20130526 (09 Jun 2013)
+
+ 09 Jun 2013; Richard Freeman <rich0@gentoo.org>
+ +mythplugins-0.26.0_p20130526.ebuild:
+ Update patch set.
*mythplugins-0.25.3_p20130422 (05 May 2013)
1.1 media-plugins/mythplugins/mythplugins-0.26.0_p20130526.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130526.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130526.ebuild?rev=1.1&content-type=text/plain
Index: mythplugins-0.26.0_p20130526.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130526.ebuild,v 1.1 2013/06/09 19:48:44 rich0 Exp $
EAPI=4
PYTHON_DEPEND="2:2.6"
BACKPORTS="7150d64b6cf4d16ca0a0fd31d872ad2ba8dd0589"
MY_P=${P%_p*}
inherit eutils python
DESCRIPTION="Official MythTV plugins"
HOMEPAGE="http://www.mythtv.org"
SRC_URI="ftp://ftp.osuosl.org/pub/mythtv/${MY_P}.tar.bz2
${BACKPORTS:+http://dev.gentoo.org/~rich0/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
MYTHPLUGINS="mytharchive mythbrowser mythgallery mythgame \
mythmusic mythnetvision mythnews mythweather mythzoneminder"
IUSE="${MYTHPLUGINS} cdda cdr exif fftw raw"
DEPEND="!media-plugins/mytharchive
!media-plugins/mythbrowser
!media-plugins/mythgallery
!media-plugins/mythgame
!media-plugins/mythmovies
!media-plugins/mythmusic
!media-plugins/mythnetvision
!media-plugins/mythnews
!media-plugins/mythweather
=media-tv/mythtv-${PV}*[python]
mytharchive? (
app-cdr/dvd+rw-tools
dev-python/imaging
media-video/dvdauthor
media-video/mjpegtools[png]
media-video/transcode
virtual/cdrtools
)
mythgallery? (
media-libs/tiff
virtual/opengl
exif? ( >media-libs/libexif-0.6.9 )
raw? ( media-gfx/dcraw )
)
mythmusic? (
>=media-libs/flac-1.1.2
>=media-libs/libvorbis-1.0
>=media-libs/taglib-1.6
media-sound/lame
virtual/opengl
cdda? (
dev-libs/libcdio
cdr? ( virtual/cdrtools )
)
fftw? ( sci-libs/fftw )
)
mythnetvision? (
=dev-lang/python-2*[xml]
dev-python/lxml
dev-python/mysql-python
dev-python/oauth
dev-python/pycurl
)
mythweather? (
dev-perl/DateManip
dev-perl/DateTime-Format-ISO8601
dev-perl/ImageSize
dev-perl/JSON
dev-perl/SOAP-Lite
dev-perl/XML-Simple
dev-perl/XML-Parser
dev-perl/XML-SAX
dev-perl/XML-XPath
)"
RDEPEND="${DEPEND}"
REQUIRED_USE="
cdda? ( mythmusic )
cdr? ( mythmusic cdda )
exif? ( mythgallery )
fftw? ( mythmusic )
mythnews? ( mythbrowser )
raw? ( mythgallery )"
S="${WORKDIR}/${MY_P}"
pkg_setup() {
python_set_active_version 2
python_pkg_setup
}
src_prepare() {
[[ -n ${BACKPORTS} ]] && \
EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
epatch
epatch_user
}
src_configure() {
./configure \
--prefix=/usr \
--python=python2 \
--enable-opengl \
$(use_enable mythzoneminder) \
$(use_enable mytharchive) \
$(use_enable mythbrowser) \
$(use_enable mythgallery) \
$(use_enable mythgame) \
$(use_enable mythmusic) \
$(use_enable mythnetvision) \
$(use_enable mythnews) \
$(use_enable mythweather) \
$(use_enable cdda cdio) \
$(use_enable exif) \
$(use_enable exif new-exif) \
$(use_enable raw dcraw) \
|| die "configure failed"
}
src_install() {
emake INSTALL_ROOT="${D}" install || die "make install failed"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-06-09 19:48 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-06-09 19:48 [gentoo-commits] gentoo-x86 commit in media-plugins/mythplugins: mythplugins-0.26.0_p20130526.ebuild ChangeLog Richard Freeman (rich0)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox