[gentoo-commits] gentoo-x86 commit in media-sound/murmur: ChangeLog murmur-1.2.4.ebuild murmur-1.2.4_beta1-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/murmur: ChangeLog murmur-1.2.4.ebuild murmur-1.2.4_beta1-r1.ebuild

[Timo Gurr (tgurr)]

tgurr       13/06/04 19:56:58

  Modified:             ChangeLog
  Added:                murmur-1.2.4.ebuild
  Removed:              murmur-1.2.4_beta1-r1.ebuild
  Log:
  Version bump, remove old. Fixes bug #452740,#460524,#472128.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 0xD1CB9BF8)

Revision  Changes    Path
1.39                 media-sound/murmur/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/murmur/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/murmur/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/murmur/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/murmur/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	2 Mar 2013 21:58:23 -0000	1.38
+++ ChangeLog	4 Jun 2013 19:56:58 -0000	1.39
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/murmur
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/murmur/ChangeLog,v 1.38 2013/03/02 21:58:23 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/murmur/ChangeLog,v 1.39 2013/06/04 19:56:58 tgurr Exp $
+
+*murmur-1.2.4 (04 Jun 2013)
+
+  04 Jun 2013; Timo Gurr <tgurr@gentoo.org> -murmur-1.2.4_beta1-r1.ebuild,
+  +murmur-1.2.4.ebuild, +files/murmur-1.2.4-ice-3.5.0-compat.patch,
+  +files/murmur.initd-r1:
+  Version bump, remove old. Fixes bug #452740,#460524,#472128.
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> murmur-1.2.3-r4.ebuild,
   murmur-1.2.4_beta1-r1.ebuild:



1.1                  media-sound/murmur/murmur-1.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/murmur/murmur-1.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/murmur/murmur-1.2.4.ebuild?rev=1.1&content-type=text/plain

Index: murmur-1.2.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/murmur/murmur-1.2.4.ebuild,v 1.1 2013/06/04 19:56:58 tgurr Exp $

EAPI="5"

QT_MINIMAL="4.6"

inherit eutils qt4-r2 user

MY_P="${PN/murmur/mumble}-${PV/_/~}"

DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="http://mumble.info/snapshot/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~x86"
IUSE="+dbus debug +ice pch zeroconf"

RDEPEND=">=dev-libs/openssl-1.0.0b
	>=dev-libs/protobuf-2.2.0
	sys-apps/lsb-release
	>=sys-libs/libcap-2.15
	dev-qt/qtcore:4[ssl]
	|| ( dev-qt/qtsql:4[sqlite] dev-qt/qtsql:4[mysql] )
	dev-qt/qtxmlpatterns:4
	dbus? ( dev-qt/qtdbus:4 )
	ice? ( dev-libs/Ice )
	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )"

DEPEND="${RDEPEND}
	>=dev-libs/boost-1.41.0
	virtual/pkgconfig"

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}"/${PN}-1.2.4-ice-3.5.0-compat.patch
)

pkg_setup() {
	enewgroup murmur
	enewuser murmur -1 -1 /var/lib/murmur murmur
}

src_prepare() {
	qt4-r2_src_prepare

	sed \
		-e 's:mumble-server:murmur:g' \
		-e 's:/var/run:/run:g' \
		-i "${S}"/scripts/murmur.{conf,ini.system} || die
}

src_configure() {
	local conf_add

	use dbus || conf_add="${conf_add} no-dbus"
	use debug && conf_add="${conf_add} symbols debug" || conf_add="${conf_add} release"
	use ice || conf_add="${conf_add} no-ice"
	use pch || conf_add="${conf_add} no-pch"
	use zeroconf || conf_add="${conf_add} no-bonjour"

	eqmake4 main.pro -recursive \
		CONFIG+="${conf_add} no-client"
}

src_compile() {
	# parallel make workaround, upstream bug #3190498
	emake -j1
}

src_install() {
	dodoc README CHANGES

	docinto scripts
	dodoc scripts/*.php scripts/*.pl

	local dir
	if use debug; then
		dir=debug
	else
		dir=release
	fi

	dobin "${dir}"/murmurd

	insinto /etc/murmur/
	newins scripts/murmur.ini.system murmur.ini

	insinto /etc/logrotate.d/
	newins "${FILESDIR}"/murmur.logrotate murmur

	insinto /etc/dbus-1/system.d/
	doins scripts/murmur.conf

	insinto /usr/share/murmur/
	doins src/murmur/Murmur.ice

	newinitd "${FILESDIR}"/murmur.initd-r1 murmur
	newconfd "${FILESDIR}"/murmur.confd murmur

	keepdir /var/lib/murmur /var/log/murmur
	fowners -R murmur /var/lib/murmur /var/log/murmur
	fperms 750 /var/lib/murmur /var/log/murmur

	doman man/murmurd.1
}

pkg_postinst() {
	echo
	elog "Useful scripts are located in /usr/share/doc/${PF}/scripts."
	elog "Please execute:"
	elog "murmurd -ini /etc/murmur/murmur.ini -supw <pw>"
	elog "chown murmur:murmur /var/lib/murmur/murmur.sqlite"
	elog "to set the build-in 'SuperUser' password before starting murmur."
	elog "Please restart dbus before starting murmur, or else dbus"
	elog "registration will fail."
	echo
}