[gentoo-commits] gentoo-x86 commit in sci-chemistry/theseus: ChangeLog theseus-2.0.3.ebuild

[gentoo-commits] gentoo-x86 commit in sci-chemistry/theseus: ChangeLog theseus-2.0.3.ebuild

[Justin Lecher (jlec)]

jlec        13/05/29 06:13:10

  Modified:             ChangeLog
  Added:                theseus-2.0.3.ebuild
  Log:
  sci-chemistry/theseus: Version Bump
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.7                  sci-chemistry/theseus/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/theseus/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/theseus/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/theseus/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/theseus/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	24 Apr 2013 10:21:00 -0000	1.6
+++ ChangeLog	29 May 2013 06:13:10 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/theseus
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/theseus/ChangeLog,v 1.6 2013/04/24 10:21:00 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/theseus/ChangeLog,v 1.7 2013/05/29 06:13:10 jlec Exp $
+
+*theseus-2.0.3 (29 May 2013)
+
+  29 May 2013; Justin Lecher <jlec@gentoo.org> +theseus-2.0.3.ebuild:
+  Version Bump
 
 *theseus-2.0.1-r1 (24 Apr 2013)
 



1.1                  sci-chemistry/theseus/theseus-2.0.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/theseus/theseus-2.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/theseus/theseus-2.0.3.ebuild?rev=1.1&content-type=text/plain

Index: theseus-2.0.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/theseus/theseus-2.0.3.ebuild,v 1.1 2013/05/29 06:13:10 jlec Exp $

EAPI=5

inherit multilib toolchain-funcs

DESCRIPTION="maximum likelihood superpositioning and analysis of macromolecular structures"
HOMEPAGE="http://www.theseus3d.org/"
SRC_URI="http://www.theseus3d.org/src/${PN}_${PV}.tar.gz"

SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples"

RDEPEND="
	sci-libs/gsl
	|| (
		sci-biology/probcons
		sci-biology/mafft
		sci-biology/t-coffee
		sci-biology/kalign
		sci-biology/clustalw
		sci-biology/muscle
		)"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S="${WORKDIR}"/${PN}_src/

src_prepare() {
	cat >> make.inc <<- EOF
	ARCH = $(tc-getAR)
	ARCHFLAGS = -rvs
	RANLIB = $(tc-getRANLIB)
	LOCALLIBDIR = "${EPREFIX}/usr/$(get_libdir)
	SYSLIBS = $(pkg-config --libs gsl) -lpthread
	LIBS = -ldistfit -lmsa -ldssplite -ldltmath -lDLTutils -ltheseus
	LIBDIR = -L./lib
	INSTALLDIR = "${ED}"/usr/bin
	OPT =
	WARN =
	CFLAGS = ${CFLAGS} \$(WARN)
	CC = $(tc-getCC)
	EOF

	sed \
		-e 's|theseus:|theseus: libs|g' \
		-e '/-o theseus/s:$(CC):$(CC) ${LDFLAGS}:g' \
		-i Makefile || die

	sed \
		-e 's:/usr/bin/sed:sed:g' \
		-e "s:/usr/local/bin/:${EPREFIX}/usr/bin/:g" \
		-e "s:/usr/bin/:${EPREFIX}/usr/bin/:g" \
		-i theseus_align || die
}

src_install() {
	dobin theseus theseus_align
	dodoc theseus_man.pdf README AUTHORS
	use examples && insinto /usr/share/${PN} && doins -r examples
}