[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.2.7.ebuild ChangeLog freeipmi-1.1.7.ebuild freeipmi-1.2.5.ebuild

[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.2.7.ebuild ChangeLog freeipmi-1.1.7.ebuild freeipmi-1.2.5.ebuild

[Diego Petteno (flameeyes)]

flameeyes    13/05/20 19:58:18

  Modified:             ChangeLog
  Added:                freeipmi-1.2.7.ebuild
  Removed:              freeipmi-1.1.7.ebuild freeipmi-1.2.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha175/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.71                 sys-libs/freeipmi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	6 May 2013 16:37:11 -0000	1.70
+++ ChangeLog	20 May 2013 19:58:18 -0000	1.71
@@ -1,6 +1,14 @@
 # ChangeLog for sys-libs/freeipmi
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.70 2013/05/06 16:37:11 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.71 2013/05/20 19:58:18 flameeyes Exp $
+
+*freeipmi-1.2.7 (20 May 2013)
+
+  20 May 2013; Diego E. Pettenò <flameeyes@gentoo.org> +freeipmi-1.2.7.ebuild,
+  -files/freeipmi-1.1.6-thresholds.patch,
+  -files/freeipmi-1.2.5-out-of-source-build.patch, -files/ipmidetectd.initd.3,
+  -freeipmi-1.1.7.ebuild, -freeipmi-1.2.5.ebuild:
+  Version bump.
 
   06 May 2013; Peter Volkov <pva@gentoo.org> freeipmi-1.2.6.ebuild:
   Fix build failure with automake-1.13, bug #468200 wrt Matt McAdoo.



1.1                  sys-libs/freeipmi/freeipmi-1.2.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.2.7.ebuild?rev=1.1&content-type=text/plain

Index: freeipmi-1.2.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.2.7.ebuild,v 1.1 2013/05/20 19:58:18 flameeyes Exp $

EAPI=5

inherit autotools eutils multilib autotools-utils

DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
HOMEPAGE="http://www.gnu.org/software/freeipmi/"

MY_P="${P/_/.}"
S="${WORKDIR}"/${MY_P}
[[ ${MY_P} == *.beta* ]] && ALPHA="-alpha"
SRC_URI="mirror://gnu${ALPHA}/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug nagios"

RDEPEND="dev-libs/libgcrypt"
DEPEND="${RDEPEND}
		virtual/os-headers"
RDEPEND="${RDEPEND}
	nagios? (
		|| ( net-analyzer/icinga net-analyzer/nagios )
		dev-lang/perl
	)
	sys-apps/openrc"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch
	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.ac || die

	AT_M4DIR="config" eautoreconf
}

src_configure() {
	local myeconfargs=(
		$(use_enable debug)
		--disable-static
		--disable-init-scripts
		--localstatedir=/var
	)

	autotools-utils_src_configure
}

# There are no tests
src_test() { :; }

src_install() {
	autotools-utils_src_install

	# freeipmi by defaults install _all_ commands to /usr/sbin, but
	# quite a few can be run remotely as standard user, so move them
	# in /usr/bin afterwards.
	dodir /usr/bin
	for file in ipmi{detect,ping,power,console}; do
		mv "${D}"/usr/{s,}bin/${file} || die

		# The default install symlinks these commands to add a dash
		# after the ipmi prefix; we repeat those after move for
		# consistency.
		rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
		dosym ${file} /usr/bin/${file/ipmi/ipmi-}
	done

	# Install the nagios plugin in its proper place, if desired
	if use nagios; then
		dodir /usr/$(get_libdir)/nagios/plugins
		mv "${D}"/usr/share/doc/${PF}/contrib/nagios/nagios_ipmi_sensors.pl \
			"${D}"/usr/$(get_libdir)/nagios/plugins/ || die
		fperms 0755 /usr/$(get_libdir)/nagios/plugins/nagios_ipmi_sensors.pl

		insinto /etc/icinga/conf.d
		newins "${FILESDIR}"/freeipmi.icinga freeipmi-command.cfg
	fi

	dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt

	keepdir \
		/var/cache/ipmimonitoringsdrcache \
		/var/lib/freeipmi \
		/var/log/ipmiconsole

	# starting from version 1.2.0 the two daemons are similar enough
	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 ipmidetectd
	newconfd "${FILESDIR}"/ipmidetectd.confd ipmidetectd

	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 bmc-watchdog
	newconfd "${FILESDIR}"/bmc-watchdog.confd bmc-watchdog

	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 ipmiseld
	newconfd "${FILESDIR}"/ipmiseld.confd ipmiseld
}