[gentoo-commits] gentoo-x86 commit in media-gfx/feh: ChangeLog feh-2.9.2.ebuild

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    13/05/19 05:52:24

  Modified:             ChangeLog
  Added:                feh-2.9.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha175/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.129                media-gfx/feh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/feh/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/feh/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/feh/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	27 Mar 2013 09:19:44 -0000	1.128
+++ ChangeLog	19 May 2013 05:52:24 -0000	1.129
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/feh
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.128 2013/03/27 09:19:44 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.129 2013/05/19 05:52:24 radhermit Exp $
+
+*feh-2.9.2 (19 May 2013)
+
+  19 May 2013; Tim Harder <radhermit@gentoo.org> +feh-2.9.2.ebuild:
+  Version bump.
 
   27 Mar 2013; Agostino Sarubbo <ago@gentoo.org> feh-2.9.1-r1.ebuild:
   Stable for ppc64, wrt bug #463090



1.1                  media-gfx/feh/feh-2.9.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/feh/feh-2.9.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/feh/feh-2.9.2.ebuild?rev=1.1&content-type=text/plain

Index: feh-2.9.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/feh-2.9.2.ebuild,v 1.1 2013/05/19 05:52:24 radhermit Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="A fast, lightweight imageviewer using imlib2"
HOMEPAGE="http://feh.finalrewind.org/"
SRC_URI="http://feh.finalrewind.org/${P}.tar.bz2"

LICENSE="feh"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE="debug curl exif test xinerama"

COMMON_DEPEND=">=media-libs/giblib-1.2.4
	media-libs/imlib2
	>=media-libs/libpng-1.2:0
	x11-libs/libX11
	curl? ( net-misc/curl )
	exif? ( media-libs/libexif )
	xinerama? ( x11-libs/libXinerama )"
RDEPEND="${COMMON_DEPEND}
	virtual/jpeg"
DEPEND="${COMMON_DEPEND}
	x11-libs/libXt
	x11-proto/xproto
	test? (
		>=dev-lang/perl-5.10
		dev-perl/Test-Command
		)"

pkg_setup() {
	use_feh() { usex $1 1 0; }

	fehopts=(
		DESTDIR="${D}"
		PREFIX=/usr
		doc_dir='${main_dir}'/share/doc/${PF}
		example_dir='${main_dir}'/share/doc/${PF}/examples
		curl=$(use_feh curl)
		debug=$(use_feh debug)
		xinerama=$(use_feh xinerama)
		exif=$(use_feh exif)
		)
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.6.2-debug-cflags.patch
	# fix desktop file
	sed -i -e "s:^Icon=.*:Icon=/usr/share/feh/images/logo.svg:" \
		share/applications/${PN}.pre || die
}

src_compile() {
	tc-export CC
	emake "${fehopts[@]}"
}

src_install() {
	emake "${fehopts[@]}" install
}