[gentoo-commits] gentoo-x86 commit in app-text/xdvik: ChangeLog xdvik-22.86.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/xdvik: ChangeLog xdvik-22.86.ebuild

[Alexis Ballier (aballier)]

aballier    13/05/18 00:17:33

  Modified:             ChangeLog
  Added:                xdvik-22.86.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha175/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.105                app-text/xdvik/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/xdvik/ChangeLog?rev=1.105&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/xdvik/ChangeLog?rev=1.105&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/xdvik/ChangeLog?r1=1.104&r2=1.105

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v
retrieving revision 1.104
retrieving revision 1.105
diff -u -r1.104 -r1.105
--- ChangeLog	17 May 2013 23:36:28 -0000	1.104
+++ ChangeLog	18 May 2013 00:17:33 -0000	1.105
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/xdvik
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v 1.104 2013/05/17 23:36:28 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v 1.105 2013/05/18 00:17:33 aballier Exp $
+
+*xdvik-22.86 (18 May 2013)
+
+  18 May 2013; Alexis Ballier <aballier@gentoo.org> +xdvik-22.86.ebuild:
+  version bump
 
   17 May 2013; Alexis Ballier <aballier@gentoo.org> -xdvik-22.84.16.ebuild,
   -files/xdvik-22.84.16-cvararg.patch,



1.1                  app-text/xdvik/xdvik-22.86.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/xdvik/xdvik-22.86.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/xdvik/xdvik-22.86.ebuild?rev=1.1&content-type=text/plain

Index: xdvik-22.86.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/xdvik-22.86.ebuild,v 1.1 2013/05/18 00:17:33 aballier Exp $

EAPI=4
inherit eutils flag-o-matic elisp-common toolchain-funcs multilib

DESCRIPTION="DVI previewer for X Window System"
HOMEPAGE="http://xdvi.sourceforge.net/"
SRC_URI="mirror://sourceforge/xdvi/${P}.tar.gz"

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
SLOT="0"
LICENSE="GPL-2"
IUSE="motif neXt Xaw3d emacs"

RDEPEND="media-libs/freetype:2
	x11-libs/libXmu
	x11-libs/libXp
	x11-libs/libXpm
	motif? ( >=x11-libs/motif-2.3:0 )
	!motif? (
		neXt? ( x11-libs/neXtaw )
		!neXt? (
			Xaw3d? ( x11-libs/libXaw3d )
			!Xaw3d? ( x11-libs/libXaw )
		)
	)
	dev-libs/kpathsea"
DEPEND="sys-devel/flex
	virtual/yacc
	${RDEPEND}"
RDEPEND="${RDEPEND}
	virtual/latex-base
	!<app-text/texlive-2007"
S=${WORKDIR}/${P}/texk/xdvik

src_prepare() {
	# Make sure system kpathsea headers are used
	cd "${WORKDIR}/${P}/texk/kpathsea"
	for i in *.h ; do echo "#include_next \"$i\"" > $i; done
}

src_configure() {
	local toolkit

	if use motif ; then
		toolkit="motif"
		use neXt && ewarn "neXt USE flag ignored (superseded by motif)"
		use Xaw3d && ewarn "Xaw3d USE flag ignored (superseded by motif)"
	elif use neXt ; then
		toolkit="neXtaw"
		use Xaw3d && ewarn "Xaw3d USE flag ignored (superseded by neXt)"
	elif use Xaw3d ; then
		toolkit="xaw3d"
	else
		toolkit="xaw"
	fi

	econf \
		--with-system-freetype2 \
		--with-system-kpathsea \
		--with-kpathsea-include="${EPREFIX}"/usr/include/kpathsea \
		--with-xdvi-x-toolkit="${toolkit}" \
		--x-includes="${EPREFIX}"/usr/include \
		--x-libraries="${EPREFIX}"/usr/$(get_libdir)
}

src_compile() {
	emake kpathsea_dir="${EPREFIX}/usr/include/kpathsea"
	use emacs && elisp-compile xdvi-search.el
}

src_install() {
	dodir /usr/share/texmf-dist/dvips/config

	emake DESTDIR="${D}" install

	dosym /usr/share/texmf-dist/xdvi/XDvi /usr/share/X11/app-defaults/XDvi

	dodoc BUGS FAQ README.*

	use emacs && elisp-install tex-utils *.el *.elc

	doicon "${FILESDIR}"/${PN}.xpm
	make_desktop_entry xdvi "XDVI" xdvik "Graphics;Viewer"
	echo "MimeType=application/x-dvi;" >> "${ED}"usr/share/applications/xdvi-"${PN}".desktop
}

pkg_postinst() {
	if use emacs; then
		elog "Add"
		elog "	(add-to-list 'load-path \"${EPREFIX}${SITELISP}/tex-utils\")"
		elog "	(require 'xdvi-search)"
		elog "to your ~/.emacs file"
	fi
}