* [gentoo-commits] gentoo-x86 commit in app-misc/gramps: gramps-3.4.4.ebuild ChangeLog
@ 2013-05-16 3:50 Christian Faulhammer (fauli)
0 siblings, 0 replies; only message in thread
From: Christian Faulhammer (fauli) @ 2013-05-16 3:50 UTC (permalink / raw
To: gentoo-commits
fauli 13/05/16 03:50:49
Modified: ChangeLog
Added: gramps-3.4.4.ebuild
Log:
version bump
(Portage version: 2.1.11.62/cvs/Linux i686, signed Manifest commit with key 2B859DE3)
Revision Changes Path
1.165 app-misc/gramps/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gramps/ChangeLog?rev=1.165&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gramps/ChangeLog?rev=1.165&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gramps/ChangeLog?r1=1.164&r2=1.165
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v
retrieving revision 1.164
retrieving revision 1.165
diff -u -r1.164 -r1.165
--- ChangeLog 16 May 2013 03:37:36 -0000 1.164
+++ ChangeLog 16 May 2013 03:50:48 -0000 1.165
@@ -1,6 +1,11 @@
# ChangeLog for app-misc/gramps
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v 1.164 2013/05/16 03:37:36 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v 1.165 2013/05/16 03:50:48 fauli Exp $
+
+*gramps-3.4.4 (16 May 2013)
+
+ 16 May 2013; Christian Faulhammer <fauli@gentoo.org> +gramps-3.4.4.ebuild:
+ version bump
16 May 2013; Christian Faulhammer <fauli@gentoo.org> -gramps-3.4.0.ebuild,
-gramps-3.4.1.ebuild, -gramps-3.4.2.ebuild:
1.1 app-misc/gramps/gramps-3.4.4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gramps/gramps-3.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gramps/gramps-3.4.4.ebuild?rev=1.1&content-type=text/plain
Index: gramps-3.4.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/gramps-3.4.4.ebuild,v 1.1 2013/05/16 03:50:48 fauli Exp $
EAPI=3
PYTHON_DEPEND="2:2.6"
GCONF_DEBUG="no"
inherit eutils gnome2 python
DESCRIPTION="Genealogical Research and Analysis Management Programming System"
HOMEPAGE="http://www.gramps-project.org/"
SRC_URI="mirror://sourceforge/gramps/Stable/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gnome reports spell webkit"
RDEPEND="dev-python/bsddb3
>=dev-python/pygtk-2.16.0
dev-python/pygoocanvas
x11-misc/xdg-utils
gnome-base/librsvg:2
gnome? ( dev-python/libgnome-python
dev-python/gconf-python )
spell? ( dev-python/gtkspell-python )
reports? ( media-gfx/graphviz )
webkit? ( dev-python/pywebkitgtk )"
DEPEND="${RDEPEND}
dev-util/intltool
sys-devel/gettext
virtual/libiconv
virtual/pkgconfig"
DOCS="NEWS README TODO"
pkg_setup() {
G2CONF="${G2CONF} --disable-mime-install PYTHON="${EROOT}"/usr/bin/python2"
python_set_active_version 2
python_pkg_setup
}
src_prepare() {
gnome2_src_prepare
epatch "${FILESDIR}/${PN}-3.4.0-use_bsddb3.patch"
# This is for bug 215944, so .pyo/.pyc files don't get into the
# file system
python_clean_py-compile_files
# Fix install path, bug 423315 for example
einfo "Fix installation path"
find . -iname 'Makefile.in' | xargs \
sed "s;\(pkgdatadir = \)\(\$(datadir)\);\1$(python_get_sitedir);" -i \
|| die
find . -iname 'Makefile.in' | xargs \
sed "s;\(pkgpythondir = \)\(\$(datadir)\);\1$(python_get_sitedir);" -i \
|| die
sed "s;\$(prefix)/share/gramps;/$(python_get_sitedir)/@PACKAGE@;" \
-i src/Makefile.in || die
sed "s;\$(prefix)/share/gramps;/$(python_get_sitedir)/@PACKAGE@;" \
-i src/docgen/Makefile.in || die
einfo "Fix wrapper script"
sed "s;@datadir@;$(python_get_sitedir);" \
-i gramps.sh.in || die
einfo "Fix icon location"
sed "s;gramps/;pixmap/;g" -i data/gramps.keys.in || die
}
src_install() {
python_need_rebuild
gnome2_src_install
}
pkg_postinst() {
gnome2_pkg_postinst
python_mod_optimize ${PN}
}
pkg_postrm() {
gnome2_pkg_postrm
python_mod_cleanup ${PN}
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-05-16 3:50 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-05-16 3:50 [gentoo-commits] gentoo-x86 commit in app-misc/gramps: gramps-3.4.4.ebuild ChangeLog Christian Faulhammer (fauli)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox