[gentoo-commits] gentoo-x86 commit in app-emulation/winetricks: ChangeLog winetricks-952.ebuild winetricks-947.ebuild

[gentoo-commits] gentoo-x86 commit in app-emulation/winetricks: ChangeLog winetricks-952.ebuild winetricks-947.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    13/05/13 02:47:53

  Modified:             ChangeLog
  Added:                winetricks-952.ebuild
  Removed:              winetricks-947.ebuild
  Log:
  Version bump, fixes .NET 1.1 download. Remove old.
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.20                 app-emulation/winetricks/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/winetricks/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/winetricks/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/winetricks/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/winetricks/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	28 Apr 2013 05:09:03 -0000	1.19
+++ ChangeLog	13 May 2013 02:47:53 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/winetricks
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/winetricks/ChangeLog,v 1.19 2013/04/28 05:09:03 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/winetricks/ChangeLog,v 1.20 2013/05/13 02:47:53 tetromino Exp $
+
+*winetricks-952 (13 May 2013)
+
+  13 May 2013; Alexandre Rostovtsev <tetromino@gentoo.org>
+  -winetricks-947.ebuild, +winetricks-952.ebuild:
+  Version bump, fixes .NET 1.1 download. Remove old.
 
 *winetricks-949 (28 Apr 2013)
 



1.1                  app-emulation/winetricks/winetricks-952.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/winetricks/winetricks-952.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/winetricks/winetricks-952.ebuild?rev=1.1&content-type=text/plain

Index: winetricks-952.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/winetricks/winetricks-952.ebuild,v 1.1 2013/05/13 02:47:53 tetromino Exp $

EAPI=4

inherit gnome2-utils eutils

if [[ ${PV} == "99999999" ]] ; then
	ESVN_REPO_URI="http://winetricks.googlecode.com/svn/trunk"
	inherit subversion
else
	SRC_URI="http://winetricks.googlecode.com/svn-history/r${PV}/trunk/src/winetricks -> ${P}
		http://winetricks.googlecode.com/svn-history/r${PV}/trunk/src/winetricks.1 -> ${P}.1"
	KEYWORDS="~amd64 ~x86"
fi
wtg=winetricks-gentoo-2012.11.24
SRC_URI="${SRC_URI}
	gtk? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )
	kde? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )"

DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
HOMEPAGE="http://code.google.com/p/winetricks/ http://wiki.winehq.org/winetricks"

LICENSE="LGPL-2.1+"
SLOT="0"
IUSE="gtk kde"

DEPEND=""
RDEPEND="app-arch/cabextract
	app-arch/unzip
	app-emulation/wine
	gtk? ( gnome-extra/zenity )
	kde? ( kde-base/kdialog )"

# Uses non-standard "Wine" category, which is provided by app-emulation/wine; #451552
QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"

S="${WORKDIR}"

src_unpack() {
	if [[ ${PV} == "99999999" ]] ; then
		subversion_src_unpack
	else
		mkdir src
		cp "${DISTDIR}"/${P} src/${PN} || die
		cp "${DISTDIR}"/${P}.1 src/${PN}.1 || die
	fi
	if use gtk || use kde; then
		unpack ${wtg}.tar.bz2
	fi
}

src_install() {
	cd src
	dobin ${PN}
	doman ${PN}.1
	if use gtk || use kde; then
		cd ../${wtg} || die
		domenu winetricks.desktop
		insinto /usr/share/icons/hicolor/scalable/apps
		doins wine-winetricks.svg
	fi
}

pkg_preinst() {
	if use gtk || use kde; then
		gnome2_icon_savelist
	fi
}

pkg_postinst() {
	if use gtk || use kde; then
		gnome2_icon_cache_update
	fi
}

pkg_postrm() {
	if use gtk || use kde; then
		gnome2_icon_cache_update
	fi
}