[gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: evolution-data-server-3.8.2.ebuild ChangeLog evolution-data-server-3.6.3.ebuild evolution-data-server-3.8.0.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: evolution-data-server-3.8.2.ebuild ChangeLog evolution-data-server-3.6.3.ebuild evolution-data-server-3.8.0.ebuild

[Pacho Ramos (pacho)]

pacho       13/05/12 16:06:39

  Modified:             ChangeLog
  Added:                evolution-data-server-3.8.2.ebuild
  Removed:              evolution-data-server-3.6.3.ebuild
                        evolution-data-server-3.8.0.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.368                gnome-extra/evolution-data-server/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.368&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.368&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?r1=1.367&r2=1.368

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v
retrieving revision 1.367
retrieving revision 1.368
diff -u -r1.367 -r1.368
--- ChangeLog	14 Apr 2013 19:00:11 -0000	1.367
+++ ChangeLog	12 May 2013 16:06:39 -0000	1.368
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/evolution-data-server
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.367 2013/04/14 19:00:11 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.368 2013/05/12 16:06:39 pacho Exp $
+
+*evolution-data-server-3.8.2 (12 May 2013)
+
+  12 May 2013; Pacho Ramos <pacho@gentoo.org>
+  +evolution-data-server-3.8.2.ebuild, -evolution-data-server-3.6.3.ebuild,
+  -evolution-data-server-3.8.0.ebuild:
+  Version bump, drop old
 
 *evolution-data-server-3.8.1 (14 Apr 2013)
 



1.1                  gnome-extra/evolution-data-server/evolution-data-server-3.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.8.2.ebuild?rev=1.1&content-type=text/plain

Index: evolution-data-server-3.8.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.8.2.ebuild,v 1.1 2013/05/12 16:06:39 pacho Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_7,3,3} )
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"

inherit db-use eutils flag-o-matic gnome2 python-any-r1 vala versionator virtualx

DESCRIPTION="Evolution groupware backend"
HOMEPAGE="http://projects.gnome.org/evolution/arch.shtml"

# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
SLOT="0/40" # subslot = libcamel-1.2 soname version
IUSE="api-doc-extras google +gnome-online-accounts +gtk +introspection ipv6 ldap kerberos vala +weather"
REQUIRED_USE="vala? ( introspection )"

KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"

RDEPEND="
	>=dev-libs/glib-2.34:2
	>=dev-db/sqlite-3.5:=
	>=dev-libs/libgdata-0.10:=
	>=app-crypt/libsecret-0.5
	>=dev-libs/libical-0.43:=
	>=net-libs/libsoup-2.40.3:2.4
	>=dev-libs/libxml2-2
	>=sys-libs/db-4:=
	>=dev-libs/nspr-4.4:=
	>=dev-libs/nss-3.9:=
	>=app-crypt/gcr-3.4

	sys-libs/zlib:=
	virtual/libiconv

	gtk? ( >=x11-libs/gtk+-3.2:3 )
	gnome-online-accounts? (
		>=net-libs/gnome-online-accounts-3.7.90
		)
	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
	kerberos? ( virtual/krb5:= )
	ldap? ( >=net-nds/openldap-2:= )
	weather? ( >=dev-libs/libgweather-3.5:2= )
"
DEPEND="${RDEPEND}
	dev-util/fix-la-relink-command
	dev-util/gperf
	>=dev-util/gtk-doc-am-1.9
	>=dev-util/intltool-0.35.5
	>=gnome-base/gnome-common-2
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
	vala? ( $(vala_depend) )"
# eautoreconf needs:
#	>=gnome-base/gnome-common-2

# FIXME
#RESTRICT="test"

pkg_setup() {
	python-any-r1_pkg_setup
}

src_prepare() {
	gnome2_src_prepare
	use vala && vala_src_prepare

	# /usr/include/db.h is always db-1 on FreeBSD
	# so include the right dir in CPPFLAGS
	append-cppflags "-I$(db_includedir)"

	# FIXME: Fix compilation flags crazyness
	# Touch configure.ac if doing eautoreconf
	sed 's/^\(AM_CPPFLAGS="\)$WARNING_FLAGS/\1/' \
		-i configure || die "sed failed"
}

src_configure() {
	gnome2_src_configure \
		$(use_enable api-doc-extras gtk-doc) \
		$(use_with api-doc-extras private-docs) \
		$(use_enable gnome-online-accounts goa) \
		$(use_enable introspection) \
		$(use_enable ipv6) \
		$(use_with kerberos krb5 "${EPREFIX}"/usr) \
		$(use_with ldap openldap) \
		$(use_enable vala vala-bindings) \
		$(use_enable weather) \
		$(use_enable gtk) \
		$(use_enable google) \
		--enable-nntp \
		--enable-largefile \
		--enable-smime \
		--with-libdb="${EPREFIX}"/usr \
		--disable-uoa
}

src_install() {
	# Prevent this evolution-data-server from linking to libs in the installed
	# evolution-data-server libraries by adding -L arguments for build dirs to
	# every .la file's relink_command field, forcing libtool to look there
	# first during relinking. This will mangle the .la files installed by
	# make install, but we don't care because we will be punting them anyway.
	fix-la-relink-command . || die "fix-la-relink-command failed"
	gnome2_src_install

	if use ldap; then
		insinto /etc/openldap/schema
		doins "${FILESDIR}"/calentry.schema
		dosym /usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
	fi
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	unset ORBIT_SOCKETDIR
	unset SESSION_MANAGER
	unset DISPLAY
	Xemake check
}