[gentoo-commits] gentoo-x86 commit in sys-auth/fprintd: fprintd-0.5.0.ebuild ChangeLog

["Michael Weber (xmw)" <xmw@gentoo.org>]

xmw         13/05/09 08:25:08

  Modified:             ChangeLog
  Added:                fprintd-0.5.0.ebuild
  Log:
  Version bump (thanks pva for the suggestions on bug 469088)
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.14                 sys-auth/fprintd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fprintd/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fprintd/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fprintd/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/fprintd/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	2 Feb 2013 23:10:27 -0000	1.13
+++ ChangeLog	9 May 2013 08:25:08 -0000	1.14
@@ -1,6 +1,11 @@
 # ChangeLog for sys-auth/fprintd
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/fprintd/ChangeLog,v 1.13 2013/02/02 23:10:27 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/fprintd/ChangeLog,v 1.14 2013/05/09 08:25:08 xmw Exp $
+
+*fprintd-0.5.0 (09 May 2013)
+
+  09 May 2013; Michael Weber <xmw@gentoo.org> +fprintd-0.5.0.ebuild:
+  Version bump (thanks pva for the suggestions on bug 469088)
 
   02 Feb 2013; Agostino Sarubbo <ago@gentoo.org> fprintd-0.4.1.ebuild:
   Add ~arm, wrt bug #449220



1.1                  sys-auth/fprintd/fprintd-0.5.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fprintd/fprintd-0.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fprintd/fprintd-0.5.0.ebuild?rev=1.1&content-type=text/plain

Index: fprintd-0.5.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/fprintd/fprintd-0.5.0.ebuild,v 1.1 2013/05/09 08:25:08 xmw Exp $

EAPI=4

inherit autotools pam systemd versionator

DESCRIPTION="D-Bus service to access fingerprint readers"
HOMEPAGE="http://cgit.freedesktop.org/libfprint/fprintd/"
MY_PV="V_$(replace_all_version_separators _)"
SRC_URI="http://cgit.freedesktop.org/libfprint/${PN}/snapshot/${MY_PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc pam static-libs"

RDEPEND="dev-libs/dbus-glib
	dev-libs/glib:2
	sys-auth/libfprint
	sys-auth/polkit
	pam? ( sys-libs/pam )"
DEPEND="${RDEPEND}
	dev-util/gtk-doc
	dev-util/gtk-doc-am
	dev-util/intltool
	doc? ( dev-libs/libxml2 dev-libs/libxslt )"

S=${WORKDIR}/${MY_PV}

src_prepare() {
	eautoreconf
}

src_configure() {
	econf --disable-silent-rules \
		$(use_enable pam) \
		$(use_enable static-libs static) \
		$(use_enable doc gtk-doc-html) \
		$(systemd_with_unitdir)
}

src_install() {
	emake DESTDIR="${D}" install \
		pammoddir=$(getpam_mod_dir)

	keepdir /var/lib/fprint

	find "${D}" -name "*.la" -delete || die

	dodoc AUTHORS NEWS README{,.transifex} TODO
	newdoc pam/README README.pam_fprintd
	if use doc ; then
		insinto /usr/share/doc/${PF}/html
		doins doc/{fprintd-docs,version}.xml
		insinto /usr/share/doc/${PF}/html/dbus
		doins doc/dbus/net.reactivated.Fprint.{Device,Manager}.ref.xml
	fi
}

pkg_postinst() {
	elog "Please take a look at README.pam_fprintd for integration docs."
}