[gentoo-commits] gentoo-x86 commit in net-misc/minidlna: minidlna-1.0.25-r2.ebuild ChangeLog

["Michael Weber (xmw)" <xmw@gentoo.org>]

xmw         13/05/08 07:29:49

  Modified:             ChangeLog
  Added:                minidlna-1.0.25-r2.ebuild
  Log:
  Move logfile to /var/log/minidlna (bug 457756 by Marc Schiffbauer), add epatch_user support (bug 437958 by BT), add rescan support (bug 462768 by Fabian Henze), add systemd service (bug 468820 by  Lee Trager).
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.29                 net-misc/minidlna/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	17 Feb 2013 17:38:11 -0000	1.28
+++ ChangeLog	8 May 2013 07:29:49 -0000	1.29
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/minidlna
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v 1.28 2013/02/17 17:38:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v 1.29 2013/05/08 07:29:49 xmw Exp $
+
+*minidlna-1.0.25-r2 (08 May 2013)
+
+  08 May 2013; Michael Weber <xmw@gentoo.org> +files/minidlna-1.0.25-r2.initd,
+  +files/minidlna-1.0.25.service, +minidlna-1.0.25-r2.ebuild:
+  Move logfile to /var/log/minidlna (bug 457756 by Marc Schiffbauer), add
+  epatch_user support (bug 437958 by BT), add rescan support (bug 462768 by
+  Fabian Henze), add systemd service (bug 468820 by  Lee Trager).
 
   17 Feb 2013; Agostino Sarubbo <ago@gentoo.org> minidlna-1.0.25-r1.ebuild:
   Stable for x86, wrt bug #456374



1.1                  net-misc/minidlna/minidlna-1.0.25-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/minidlna-1.0.25-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/minidlna-1.0.25-r2.ebuild?rev=1.1&content-type=text/plain

Index: minidlna-1.0.25-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/minidlna-1.0.25-r2.ebuild,v 1.1 2013/05/08 07:29:49 xmw Exp $

EAPI=4

inherit eutils systemd toolchain-funcs user

DESCRIPTION="DLNA/UPnP-AV compliant media server"
HOMEPAGE="http://minidlna.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}_src.tar.gz"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE=""

RDEPEND="dev-db/sqlite
	media-libs/flac
	media-libs/libexif
	media-libs/libid3tag
	media-libs/libogg
	media-libs/libvorbis
	virtual/ffmpeg
	virtual/jpeg"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

pkg_setup() {
	local my_is_new="yes"
	[ -d "${EPREFIX}"/var/lib/${PN} ] && my_is_new="no"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
	if [ -d "${EPREFIX}"/var/lib/${PN} ] && [ "${my_is_new}" == "yes" ] ; then
		# created by above enewuser command w/ wrong group and permissions
		chown ${PN}:${PN} "${EPREFIX}"/var/lib/${PN} || die
		chmod 0750 "${EPREFIX}"/var/lib/${PN} || die
		# if user already exists, but /var/lib/minidlna is missing
		# rely on ${D}/var/lib/minidlna created in src_install
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.0.18-Makefile.patch
	epatch "${FILESDIR}"/${PN}-1.0.25-ffmpeg.patch

	sed -e "/^DB_PATH=/s:\".*\":\"${EPREFIX}/var/lib/${PN}\":" \
		-e "/^LOG_PATH=/s:\".*\":\"${EPREFIX}/var/log/${PN}\":" \
		-i ./genconfig.sh || die
	sed -e "/log_dir/s:/var/log:/var/log/${PN}:" \
		-i ${PN}.conf || die

	sed -e 's:@$(CC):$(CC):' \
		-i Makefile || die

	epatch_user
}

src_configure() {
	./genconfig.sh || die
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	emake DESTDIR="${D}" install install-conf

	newconfd "${FILESDIR}"/${P}.confd ${PN}
	newinitd "${FILESDIR}"/${PF}.initd ${PN}
	systemd_newunit "${FILESDIR}"/${P}.service ${PN}.service

	dodir /var/{lib,log}/${PN}
	fowners ${PN}:${PN} /var/{lib,log}/${PN}
	fperms 0750 /var/{lib,log}/${PN}

	dodoc NEWS README TODO
}

pkg_postinst() {
	elog "minidlna now runs as minidlna:minidlna (bug 426726),"
	elog "logfile is moved to /var/log/minidlna/minidlna.log,"
	elog "cache is moved to /var/lib/minidlna."
	elog "Please edit /etc/conf.d/${PN} and file ownerships to suit your needs."
}