[gentoo-commits] gentoo-x86 commit in media-libs/libbluray: libbluray-0.3.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-libs/libbluray: libbluray-0.3.0.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    13/05/03 09:01:41

  Modified:             ChangeLog
  Added:                libbluray-0.3.0.ebuild
  Log:
  Version bump, add truetype use flag.
  
  (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.43                 media-libs/libbluray/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	16 Jan 2013 18:51:54 -0000	1.42
+++ ChangeLog	3 May 2013 09:01:41 -0000	1.43
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libbluray
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.42 2013/01/16 18:51:54 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.43 2013/05/03 09:01:41 radhermit Exp $
+
+*libbluray-0.3.0 (03 May 2013)
+
+  03 May 2013; Tim Harder <radhermit@gentoo.org> +libbluray-0.3.0.ebuild:
+  Version bump, add truetype use flag.
 
   16 Jan 2013; Agostino Sarubbo <ago@gentoo.org> libbluray-0.2.3.ebuild:
   Stable for ppc64, wrt bug #450336



1.1                  media-libs/libbluray/libbluray-0.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/libbluray-0.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/libbluray-0.3.0.ebuild?rev=1.1&content-type=text/plain

Index: libbluray-0.3.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-0.3.0.ebuild,v 1.1 2013/05/03 09:01:41 radhermit Exp $

EAPI=5

inherit autotools java-pkg-opt-2 flag-o-matic eutils

DESCRIPTION="Blu-ray playback libraries"
HOMEPAGE="http://www.videolan.org/developers/libbluray.html"
SRC_URI="ftp://ftp.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2
	java? ( http://dev.gentoo.org/~radhermit/dist/${P}-java.patch.bz2 )"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="aacs java static-libs +truetype utils +xml"

COMMON_DEPEND="
	truetype? ( media-libs/freetype:2 )
	xml? ( dev-libs/libxml2 )
"
RDEPEND="
	${COMMON_DEPEND}
	aacs? ( media-libs/libaacs )
	java? ( >=virtual/jre-1.6 )
"
DEPEND="
	${COMMON_DEPEND}
	java? (
		>=virtual/jdk-1.6
		dev-java/ant-core
	)
	virtual/pkgconfig
"
REQUIRED_USE="utils? ( static-libs )"

DOCS=( ChangeLog README.txt )

src_prepare() {
	if use java ; then
		export JDK_HOME="$(java-config -g JAVA_HOME)"

		# upstream 0.3.0 tarball is missing a lot of java files
		epatch "${WORKDIR}"/${P}-java.patch

		# don't install a duplicate jar file
		sed -i '/^jar_DATA/d' src/Makefile.am || die

		eautoreconf

		java-pkg-opt-2_src_prepare
	fi
}

src_configure() {
	if use java; then
		export JAVACFLAGS="$(java-pkg_javac-args)"
		append-cflags "$(java-pkg_get-jni-cflags)"
	fi

	econf \
		--disable-optimizations \
		$(use_enable utils examples) \
		$(use_enable java bdjava) \
		$(use_enable static-libs static) \
		$(use_with xml libxml2) \
		$(use_with truetype freetype)
}

src_install() {
	default

	if use utils; then
		cd src/examples/
		dobin clpi_dump index_dump mobj_dump mpls_dump sound_dump
		cd .libs/
		dobin bd_info bdsplice hdmv_test libbluray_test list_titles
		if use java; then
			dobin bdj_test
		fi
	fi

	if use java; then
		java-pkg_dojar "${S}/src/.libs/${PN}.jar"
		doenvd "${FILESDIR}"/90${PN}
	fi

	prune_libtool_files
}