[gentoo-commits] gentoo-x86 commit in www-client/uget: ChangeLog uget-1.10.3-r1.ebuild uget-1.10.2.ebuild

[gentoo-commits] gentoo-x86 commit in www-client/uget: ChangeLog uget-1.10.3-r1.ebuild uget-1.10.2.ebuild

[Alex Alexander (wired)]

wired       13/05/03 04:08:22

  Modified:             ChangeLog
  Added:                uget-1.10.3-r1.ebuild
  Removed:              uget-1.10.2.ebuild
  Log:
  respect AR - bug #466600 - patch by Ted Tanberry. removed old.
  
  (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key EB9B4AFA)

Revision  Changes    Path
1.39                 www-client/uget/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/uget/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/uget/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/uget/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/uget/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	22 Apr 2013 09:09:11 -0000	1.38
+++ ChangeLog	3 May 2013 04:08:22 -0000	1.39
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/uget
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/uget/ChangeLog,v 1.38 2013/04/22 09:09:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/uget/ChangeLog,v 1.39 2013/05/03 04:08:22 wired Exp $
+
+*uget-1.10.3-r1 (03 May 2013)
+
+  03 May 2013; Alex Alexander <wired@gentoo.org> -uget-1.10.2.ebuild,
+  +uget-1.10.3-r1.ebuild, +files/uget-ar-hardcoded.patch:
+  respect AR - bug #466600 - patch by Ted Tanberry. removed old.
 
   22 Apr 2013; Agostino Sarubbo <ago@gentoo.org> uget-1.10.3.ebuild:
   Stable for ppc, wrt bug #463152



1.1                  www-client/uget/uget-1.10.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/uget/uget-1.10.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/uget/uget-1.10.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: uget-1.10.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/uget/uget-1.10.3-r1.ebuild,v 1.1 2013/05/03 04:08:22 wired Exp $

EAPI="4"

inherit base autotools

IUSE="aria2 +curl gstreamer hide-temp-files libnotify nls"
if [[ ${PV} == *9999* ]]; then
	inherit git-2
	KEYWORDS=""
	SRC_URI=""
	EGIT_REPO_URI="git://urlget.git.sourceforge.net/gitroot/urlget/uget"
else
	KEYWORDS="~amd64 ~ppc ~x86"
	SRC_URI="mirror://sourceforge/urlget/${P}.tar.gz"
fi

DESCRIPTION="Download manager using gtk+ and libcurl"
HOMEPAGE="http://urlget.sourceforge.net/"

LICENSE="LGPL-2.1"
SLOT="0"

REQUIRED_USE="|| ( aria2 curl )"

RDEPEND="
	dev-libs/libpcre
	>=dev-libs/glib-2.32:2
	>=x11-libs/gtk+-3.4:3
	curl? ( >=net-misc/curl-7.10 )
	gstreamer? ( media-libs/gstreamer:0.10 )
	libnotify? ( x11-libs/libnotify )
	"
DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig
	sys-devel/gettext"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-ar-hardcoded.patch
	eautoreconf

	if [[ ${PV} == *9999* ]]; then
		intltoolize || die "intltoolize failed"
		eautoreconf
	fi

	# fix the .desktop file for QA
	sed -i 's/Network;FileTransfer/Network;FileTransfer;/g' uget-gtk.desktop
}

src_configure() {
	econf $(use_enable nls) \
		  $(use_enable curl plugin-curl) \
		  $(use_enable aria2 plugin-aria2) \
		  $(use_enable gstreamer) \
		  $(use_enable hide-temp-files hidden) \
		  $(use_enable libnotify notify)
}

src_compile() {
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install

	# the build system forgets this :p
	dobin uget-cmd/uget-cmd

	if [[ ${PV} == *9999* ]]; then
		dodoc AUTHORS ChangeLog README
	else
		dodoc AUTHORS ChangeLog NEWS README
	fi
}

pkg_postinst() {
	if use aria2; then
		echo
		elog "You've enabled the aria2 USE flag, so the aria2 plug-in has been"
		elog "built. This allows you to control a local or remote instance of aria2"
		elog "through xmlrpc. To use aria2 locally you have to emerge"
		elog "net-misc/aria2 with the xmlrpc USE enabled manually."
		echo
	fi
}