[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: metadata.xml ChangeLog git-cola-1.8.2.ebuild

[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: metadata.xml ChangeLog git-cola-1.8.2.ebuild

[Justin Lecher (jlec)]

jlec        13/04/29 08:59:22

  Modified:             metadata.xml ChangeLog
  Added:                git-cola-1.8.2.ebuild
  Log:
  dev-vcs/git-cola: Version BUmp and move to new python eclasses
  
  (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.4                  dev-vcs/git-cola/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	24 May 2012 21:20:34 -0000	1.3
+++ metadata.xml	29 Apr 2013 08:59:22 -0000	1.4
@@ -1,12 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<maintainer>
-		<email>dev-zero@gentoo.org</email>
-		<name>Tiziano Müller</name>
-	</maintainer>
-	<maintainer>
-		<email>jlec@gentoo.org</email>
-		<name>Justin Lecher</name>
-	</maintainer>
+  <maintainer>
+    <email>dev-zero@gentoo.org</email>
+    <name>Tiziano Müller</name>
+  </maintainer>
+  <maintainer>
+    <email>jlec@gentoo.org</email>
+    <name>Justin Lecher</name>
+  </maintainer>
 </pkgmetadata>



1.7                  dev-vcs/git-cola/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	10 Dec 2012 07:41:36 -0000	1.6
+++ ChangeLog	29 Apr 2013 08:59:22 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/git-cola
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.6 2012/12/10 07:41:36 jlec Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.7 2013/04/29 08:59:22 jlec Exp $
+
+*git-cola-1.8.2 (29 Apr 2013)
+
+  29 Apr 2013; Justin Lecher <jlec@gentoo.org> +git-cola-1.8.2.ebuild,
+  metadata.xml:
+  Version BUmp and move to new python eclasses
 
 *git-cola-1.8.1 (10 Dec 2012)
 



1.1                  dev-vcs/git-cola/git-cola-1.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-1.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-1.8.2.ebuild?rev=1.1&content-type=text/plain

Index: git-cola-1.8.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/git-cola-1.8.2.ebuild,v 1.1 2013/04/29 08:59:22 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
DISTUTILS_SINGLE_IMPL=true

inherit distutils-r1

DESCRIPTION="The highly caffeinated git GUI"
HOMEPAGE="http://git-cola.github.com/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc test"

RDEPEND="
	dev-python/jsonpickle[${PYTHON_USEDEP}]
	dev-python/pyinotify[${PYTHON_USEDEP}]
	dev-python/PyQt4[${PYTHON_USEDEP}]
	dev-vcs/git"
DEPEND="${RDEPEND}
	doc? (
		app-text/asciidoc
		dev-python/sphinx[${PYTHON_USEDEP}]
		app-text/xmlto )
	sys-devel/gettext
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"

# tests currently broken due to unfinished translation framework
RESTRICT="test"

PATCHES=(
	"${FILESDIR}"/1.3.8-disable-tests.patch
	"${FILESDIR}"/1.8.1-system-ssh-askpass.patch
	)

python_prepare_all() {
	# don't install docs into wrong location
	sed -i \
		-e '/doc/d' \
		setup.py || die "sed failed"

	sed -i \
		-e  "s|'doc', 'git-cola'|'doc', '${PF}', 'html'|" \
		cola/resources.py || die "sed failed"

	distutils-r1_python_prepare_all
}

python_compile_all() {
	cd share/doc/${PN}/
	if use doc ; then
		emake all
	else
		sed \
			-e '/^install:/s:install-html::g' \
			-i Makefile || die
	fi
}

python_install_all() {
	cd share/doc/${PN}/
	emake \
		DESTDIR="${D}" \
		docdir="${EPREFIX}/usr/share/doc/${PF}" \
		prefix="${EPREFIX}/usr" \
		install

	if use doc ; then
		HTML_DOCS=( share/doc/${PN}/_build/html/. )
	else
		HTML_DOCS=( "${FILESDIR}"/index.html )
	fi

	distutils-r1_python_install_all
}

python_test() {
	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C" nosetests \
		--verbose --with-doctest --with-id --exclude=jsonpickle --exclude=json \
		|| die "running nosetests failed"
}

pkg_postinst() {
	elog "Please make sure you have either a SSH key management installed and activated or"
	elog "installed a SSH askpass app like net-misc/x11-ssh-askpass."
	elog "Otherwise ${PN} may hang when pushing/pulling from remote git repositories via SSH. "
}