* [gentoo-commits] gentoo-x86 commit in app-text/calibre: calibre-0.9.28.ebuild ChangeLog
@ 2013-04-27 23:04 Zac Medico (zmedico)
0 siblings, 0 replies; only message in thread
From: Zac Medico (zmedico) @ 2013-04-27 23:04 UTC (permalink / raw
To: gentoo-commits
zmedico 13/04/27 23:04:28
Modified: ChangeLog
Added: calibre-0.9.28.ebuild
Log:
0.9.28 version bump and migrate off of python.eclass.
(Portage version: 2.2.0_alpha173/cvs/Linux i686, signed Manifest commit with key 0xFDE8EF85AE5719A3)
Revision Changes Path
1.274 app-text/calibre/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/calibre/ChangeLog?rev=1.274&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/calibre/ChangeLog?rev=1.274&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/calibre/ChangeLog?r1=1.273&r2=1.274
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v
retrieving revision 1.273
retrieving revision 1.274
diff -u -r1.273 -r1.274
--- ChangeLog 23 Apr 2013 19:51:32 -0000 1.273
+++ ChangeLog 27 Apr 2013 23:04:28 -0000 1.274
@@ -1,6 +1,11 @@
# ChangeLog for app-text/calibre
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.273 2013/04/23 19:51:32 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.274 2013/04/27 23:04:28 zmedico Exp $
+
+*calibre-0.9.28 (27 Apr 2013)
+
+ 27 Apr 2013; Zac Medico <zmedico@gentoo.org> +calibre-0.9.28.ebuild:
+ 0.9.28 version bump and migrate off of python.eclass.
23 Apr 2013; Tomáš Chvátal <scarabeus@gentoo.org> -calibre-0.9.20.ebuild,
-calibre-0.9.26.ebuild, calibre-0.9.27.ebuild:
1.1 app-text/calibre/calibre-0.9.28.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/calibre/calibre-0.9.28.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/calibre/calibre-0.9.28.ebuild?rev=1.1&content-type=text/plain
Index: calibre-0.9.28.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/calibre-0.9.28.ebuild,v 1.1 2013/04/27 23:04:28 zmedico Exp $
EAPI=5
inherit eutils fdo-mime bash-completion-r1 multilib toolchain-funcs
DESCRIPTION="Ebook management application."
HOMEPAGE="http://calibre-ebook.com/"
SRC_URI="http://sourceforge.net/projects/calibre/files/${PV}/${P}.tar.xz"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="+udisks"
COMMON_DEPEND="
>=app-text/podofo-0.8.2:=
>=app-text/poppler-0.12.3-r3:=[qt4,xpdf-headers(+)]
>=dev-lang/python-2.7.1:2.7[sqlite,ssl]
>=dev-libs/chmlib-0.40:=
>=dev-libs/icu-4.4:=
>=dev-python/beautifulsoup-3.0.5:python-2
dev-python/netifaces
dev-python/python-dateutil
>=dev-python/dnspython-1.6.0
>=dev-python/cssselect-0.7.1
>=dev-python/cssutils-0.9.9
>=dev-python/dbus-python-0.82.2
>=dev-python/imaging-1.1.6
>=dev-python/lxml-2.2.1
>=dev-python/mechanize-0.1.11
>=dev-python/python-dateutil-1.4.1
>=dev-python/PyQt4-4.9.1[X,svg,webkit]
media-fonts/liberation-fonts
>=media-gfx/imagemagick-6.5.9[jpeg,png]
>=media-libs/freetype-2:=
>=media-libs/libwmf-0.2.8
>=media-libs/libmtp-1.1.4:=
virtual/libusb:1=
dev-qt/qtdbus:4=
dev-qt/qtsvg:4=
>=x11-misc/xdg-utils-1.0.2-r2"
RDEPEND="${COMMON_DEPEND}
udisks? ( || ( sys-fs/udisks:2 sys-fs/udisks:0 ) )"
DEPEND="${COMMON_DEPEND}
>=dev-python/setuptools-0.6_rc5"
S=${WORKDIR}/${PN}
src_prepare() {
# Fix outdated version constant.
#sed -e "s#\\(^numeric_version =\\).*#\\1 (${PV//./, })#" \
# -i src/calibre/constants.py || \
# die "sed failed to patch constants.py"
# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
# calls xdg-* (bug #258938).
sed -e "s|'xdg-desktop-menu', 'install'|\\0, '--mode', 'user'|" \
-e "s|check_call(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
-e "s|\\(CurrentDir(tdir)\\), \\\\\$|\\1:|" \
-e "s|PreserveMIMEDefaults():||" \
-e "s|xdg-icon-resource install|\\0 --mode user|" \
-e "s|cc(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
-e "s|xdg-mime install|\\0 --mode user|" \
-i src/calibre/linux.py || die "sed failed to patch linux.py"
# Disable unnecessary privilege dropping for bug #287067.
sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
-i setup/install.py || die "sed failed to patch install.py"
sed -e "/^ self\\.check_call(qmc + \\[.*\\.pro'\\])$/a\
\\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ self.check_call(['sed', \
'-e', 's|^CFLAGS .*|\\\\\\\\0 ${CFLAGS}|', \
'-e', 's|^CXXFLAGS .*|\\\\\\\\0 ${CXXFLAGS}|', \
'-e', 's|^LFLAGS .*|\\\\\\\\0 ${LDFLAGS}|', \
'-i', 'Makefile'])" \
-i setup/extensions.py || die "sed failed to patch extensions.py"
# no_updates: do not annoy user with "new version is availible all the time
# disable_plugins: walking sec-hole, wait for upstream to use GHNS interface
epatch \
"${FILESDIR}/${PN}-no_updates_dialog.patch" \
"${FILESDIR}/${PN}-disable_plugins.patch"
}
src_install() {
# Bypass kbuildsycoca and update-mime-database in order to
# avoid sandbox violations if xdg-mime tries to call them.
cat - > "${T}/kbuildsycoca" <<-EOF
#!${BASH}
exit 0
EOF
cp "${T}"/{kbuildsycoca,update-mime-database}
chmod +x "${T}"/{kbuildsycoca,update-mime-database}
# Unset DISPLAY in order to prevent xdg-mime from triggering a sandbox
# violation with kbuildsycoca as in bug #287067, comment #13.
export -n DISPLAY
# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
# File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
# return _parse_localename(localename)
# File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
# raise ValueError, 'unknown locale: %s' % localename
#ValueError: unknown locale: 46
export -n LANGUAGE
# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
# variables to point to our fake temporary $HOME.
export HOME="${T}/fake_homedir"
export XDG_CONFIG_HOME="${HOME}/.config"
export XDG_DATA_HOME="${HOME}/.local/share"
export CALIBRE_CONFIG_DIRECTORY="${XDG_CONFIG_HOME}/calibre"
mkdir -p "${XDG_CONFIG_HOME}" "${CALIBRE_CONFIG_DIRECTORY}"
tc-export CC CXX
# Bug #334243 - respect LDFLAGS when building calibre-mount-helper
export OVERRIDE_CFLAGS="$CFLAGS" OVERRIDE_LDFLAGS="$LDFLAGS"
local libdir=$(get_libdir)
[[ -n $libdir ]] || die "get_libdir returned an empty string"
dodir "/usr/$(get_libdir)/python2.7/site-packages" # for init_calibre.py
PATH=${T}:${PATH} PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
"${EPREFIX}"/usr/bin/python2.7 setup.py install \
--root="${D}" \
--prefix="${EPREFIX}/usr" \
--libdir="${EPREFIX}/usr/${libdir}" \
--staging-root="${ED}usr" \
--staging-libdir="${ED}usr/${libdir}" || die
grep -rlZ "${ED}" "${ED}" | xargs -0 sed -e "s:${D}:/:g" -i ||
die "failed to fix harcoded \$D in paths"
# Remove dummy calibre-mount-helper which is unused since calibre-0.8.25
# due to bug #389515 (instead, calibre now calls udisks via dbus).
rm "${ED}usr/bin/calibre-mount-helper" || die
# The menu entries end up here due to '--mode user' being added to
# xdg-* options in src_prepare.
dodir /usr/share/mime/packages
chmod -fR a+rX,u+w,g-w,o-w "${HOME}"/.local
mv "${HOME}"/.local/share/mime/packages/* "${ED}"usr/share/mime/packages/ ||
die "failed to register mime types"
dodir /usr/share/icons
mv "${HOME}"/.local/share/icons/* "${ED}"usr/share/icons/ ||
die "failed to install icon files"
domenu "${HOME}"/.local/share/applications/*.desktop ||
die "failed to install .desktop menu files"
dobashcomp "${ED}"usr/etc/bash_completion.d/calibre
rm -r "${ED}"usr/etc/bash_completion.d
find "${ED}"usr/etc -type d -empty -delete
cd "${ED}"/usr/share/calibre/fonts/liberation || die
local x
for x in * ; do
[[ -f ${EROOT}usr/share/fonts/liberation-fonts/${x} ]] || continue
ln -sf "../../../fonts/liberation-fonts/${x}" "${x}" || die
done
einfo "Converting python shebangs"
while read -r -d $'\0' ; do
local shebang=$(head -n1 "$REPLY")
if [[ ${shebang} == "#!"*python* ]] ; then
sed -i -e "1s:.*:#!${EPREFIX}/usr/bin/python2.7:" "$REPLY" || \
die "sed failed"
fi
done < <(find "${ED}" -type f -print0)
einfo "Compiling python modules"
"${EPREFIX}"/usr/bin/python2.7 -m compileall -q -f \
-d "${EPREFIX}"/usr/lib/calibre "${ED}"usr/lib/calibre || die
newinitd "${FILESDIR}"/calibre-server.init calibre-server
newconfd "${FILESDIR}"/calibre-server.conf calibre-server
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-04-27 23:04 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-04-27 23:04 [gentoo-commits] gentoo-x86 commit in app-text/calibre: calibre-0.9.28.ebuild ChangeLog Zac Medico (zmedico)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox