[gentoo-commits] gentoo-x86 commit in media-sound/qsynth: ChangeLog qsynth-0.3.7.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/qsynth: ChangeLog qsynth-0.3.7.ebuild

[Alexis Ballier (aballier)]

aballier    13/04/17 18:34:24

  Modified:             ChangeLog
  Added:                qsynth-0.3.7.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.59                 media-sound/qsynth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/qsynth/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/qsynth/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/qsynth/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	2 Mar 2013 22:01:34 -0000	1.58
+++ ChangeLog	17 Apr 2013 18:34:24 -0000	1.59
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/qsynth
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.58 2013/03/02 22:01:34 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.59 2013/04/17 18:34:24 aballier Exp $
+
+*qsynth-0.3.7 (17 Apr 2013)
+
+  17 Apr 2013; Alexis Ballier <aballier@gentoo.org> +qsynth-0.3.7.ebuild:
+  version bump
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> qsynth-0.3.6.ebuild:
   Move Qt dependencies to the new category



1.1                  media-sound/qsynth/qsynth-0.3.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/qsynth/qsynth-0.3.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/qsynth/qsynth-0.3.7.ebuild?rev=1.1&content-type=text/plain

Index: qsynth-0.3.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.7.ebuild,v 1.1 2013/04/17 18:34:24 aballier Exp $

EAPI=4
LANGS="cs de es ru"

inherit qt4-r2 eutils flag-o-matic

DESCRIPTION="A Qt application to control FluidSynth"
HOMEPAGE="http://qsynth.sourceforge.net/"
SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="debug jack alsa pulseaudio"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND=">=dev-qt/qtcore-4.2:4
	>=dev-qt/qtgui-4.2:4
	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?,pulseaudio?]
	x11-libs/libX11
	!pulseaudio? ( !jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) ) )"
RDEPEND="${DEPEND}"

DOCS="AUTHORS ChangeLog README TODO TRANSLATORS"

src_prepare() {
	sed -e '/@install/,/share\/locale$/d' -i Makefile.in || die "sed translations failed"

	sed -e 's/@make/@\$(MAKE)/' -i Makefile.in || die "sed Makefile failed"

	qt4-r2_src_prepare
}

src_configure() {
	# Stupidly, qsynth's configure does *not* use pkg-config to
	# discover the presence of Qt4, but uses fixed paths; as they
	# don't really work that well for our case, let's just use this
	# nasty hack and be done with it. *NOTE*: this hinders
	# cross-compile.
	append-flags -I/usr/include/qt4
	append-ldflags -L/usr/$(get_libdir)/qt4

	econf \
		$(use_enable debug)
	eqmake4 "${PN}.pro" -o "${PN}.mak"
}

src_compile() {
	lupdate "${PN}.pro" || die "lupdate failed"
	qt4-r2_src_compile
}

src_install () {
	qt4-r2_src_install

	insinto /usr/share/locale
	local lang
	for lang in ${LANGS} ; do
		if use linguas_${lang} ; then
			doins "src/translations/${PN}_${lang}.qm"
		fi
	done

	# The desktop file is invalid, and we also change the command
	# depending on useflags
	rm -rf "${D}/usr/share/applications/qsynth.desktop"

	local cmd
	if use jack; then
		cmd="qsynth"
	elif use pulseaudio; then
		cmd="qsynth -a pulseaudio"
	elif use alsa; then
		cmd="qsynth -a alsa"
	else
		cmd="qsynth -a oss"
	fi

	make_desktop_entry "${cmd}" Qsynth qsynth
}