[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-live: ChangeLog vdr-live-0.3.0-r1.ebuild vdr-live-0.3.0.ebuild

[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-live: ChangeLog vdr-live-0.3.0-r1.ebuild vdr-live-0.3.0.ebuild

[Joerg Bornkessel (hd_brummy)]

hd_brummy    13/04/07 18:20:39

  Modified:             ChangeLog
  Added:                vdr-live-0.3.0-r1.ebuild
  Removed:              vdr-live-0.3.0.ebuild
  Log:
  fixed wrong install of some dir's, changed by plugin maintainer without leave any notes about this
  
  (Portage version: 2.1.11.50/cvs/Linux i686, signed Manifest commit with key 34C2808A)

Revision  Changes    Path
1.40                 media-plugins/vdr-live/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-live/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-live/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-live/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-live/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	6 Apr 2013 06:21:04 -0000	1.39
+++ ChangeLog	7 Apr 2013 18:20:39 -0000	1.40
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/vdr-live
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-live/ChangeLog,v 1.39 2013/04/06 06:21:04 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-live/ChangeLog,v 1.40 2013/04/07 18:20:39 hd_brummy Exp $
+
+*vdr-live-0.3.0-r1 (07 Apr 2013)
+
+  07 Apr 2013; Joerg Bornkessel <hd_brummy@gentoo.org> -vdr-live-0.3.0.ebuild,
+  +vdr-live-0.3.0-r1.ebuild:
+  fixed wrong install of some dir's, changed by plugin maintainer without leave
+  any notes about this
 
 *vdr-live-0.3.0 (06 Apr 2013)
 



1.1                  media-plugins/vdr-live/vdr-live-0.3.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-live/vdr-live-0.3.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-live/vdr-live-0.3.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: vdr-live-0.3.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-live/vdr-live-0.3.0-r1.ebuild,v 1.1 2013/04/07 18:20:39 hd_brummy Exp $

EAPI="5"

inherit vdr-plugin-2 ssl-cert

DESCRIPTION="VDR Plugin: Web Access To Settings"
HOMEPAGE="http://live.vdr-developer.org"
SRC_URI="http://live.vdr-developer.org/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pcre ssl"

DEPEND="media-video/vdr
	>=dev-libs/tntnet-2.0[ssl=,sdk]
	>=dev-libs/cxxtools-2.0
	pcre? ( >=dev-libs/libpcre-8.12[cxx] )"
RDEPEND="${DEPEND}"

VDR_CONFD_FILE="${FILESDIR}/confd-0.2"
VDR_RCADDON_FILE="${FILESDIR}/rc-addon-0.2.sh"

KEEP_I18NOBJECT="yes"

make_live_cert() {
	# TODO: still true?
	# ssl-cert eclass creates a "invalid" cert, create our own one
	local base=$(get_base 1)
	local keydir="/etc/vdr/plugins/live"

	SSL_ORGANIZATION="${SSL_ORGANIZATION:-VDR Plugin Live}"
	SSL_COMMONNAME="${SSL_COMMONNAME:-`hostname -f`}"

	echo
	gen_cnf || return 1
	echo
	gen_key 1 || return 1
	gen_csr 1 || return 1
	gen_crt 1 || return 1
	echo

	install -d "${ROOT}${keydir}"
	install -m0400 "${base}.key" "${ROOT}${keydir}/live-key.pem"
	install -m0444 "${base}.crt" "${ROOT}${keydir}/live.pem"
	chown vdr:vdr "${ROOT}"/etc/vdr/plugins/live/live{,-key}.pem
}

src_prepare() {
	# remove untranslated language files
	rm "${S}"/po/{ca_ES,da_DK,el_GR,et_EE,hr_HR,hu_HU,nl_NL,nn_NO,pt_PT,ro_RO,ru_RU,sl_SI,sv_SE,tr_TR}.po

	vdr-plugin-2_src_prepare

	if ! use pcre; then
		sed -i "s:^HAVE_LIBPCRECPP:#HAVE_LIBPCRECPP:" Makefile || die
	fi
}

src_install() {
	vdr-plugin-2_src_install

	insinto /usr/share/vdr/plugins/live
	doins -r live/*

	fowners -R vdr:vdr /usr/share/vdr/plugins/live
}

pkg_postinst() {
	vdr-plugin-2_pkg_postinst

	elog "To be able to use all functions of vdr-live"
	elog "you should emerge and enable"
	elog "media-plugins/vdr-epgsearch to search the EPG,"
	elog "media-plugins/vdr-streamdev for Live-TV streaming"

	elog "The default username/password is:"
	elog "\tadmin:live"

	if use ssl ; then
		if path_exists -a "${ROOT}"/etc/vdr/plugins/live/live.pem; then
			einfo "found an existing SSL cert, to create a new SSL cert, run:\n"
			einfo "emerge --config ${PN}"
		else
			einfo "No SSL cert found, creating a default one now"
			make_live_cert
		fi
	fi
}

pkg_config() {
	make_live_cert
}