* [gentoo-commits] gentoo-x86 commit in net-dns/nsd: nsd-3.2.15.ebuild nsd-4.0.0_beta4-r1.ebuild metadata.xml ChangeLog nsd-4.0.0_beta4.ebuild
@ 2013-04-03 19:10 Wolfram Schlich (wschlich)
0 siblings, 0 replies; only message in thread
From: Wolfram Schlich (wschlich) @ 2013-04-03 19:10 UTC (permalink / raw
To: gentoo-commits
wschlich 13/04/03 19:10:39
Modified: metadata.xml ChangeLog
Added: nsd-3.2.15.ebuild nsd-4.0.0_beta4-r1.ebuild
Removed: nsd-4.0.0_beta4.ebuild
Log:
added nsd-3.x ebuild, added nsd-4.x munin plugin config. thanks to Tom Hendrikx <tom@whyscream.net>
(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, unsigned Manifest commit)
Revision Changes Path
1.4 net-dns/nsd/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/metadata.xml?r1=1.3&r2=1.4
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/nsd/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml 17 Mar 2013 15:17:11 -0000 1.3
+++ metadata.xml 3 Apr 2013 19:10:39 -0000 1.4
@@ -28,5 +28,7 @@
<flag name='munin'>
Install a plugin for <pkg>net-analyzer/munin</pkg> to graph
statistical data from nsd.</flag>
+ <flag name='zone-stats'>Enable per-zone statistics logging, this
+ could lead to a reduced service level</flag>
</use>
</pkgmetadata>
1.5 net-dns/nsd/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?r1=1.4&r2=1.5
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog 17 Mar 2013 15:17:11 -0000 1.4
+++ ChangeLog 3 Apr 2013 19:10:39 -0000 1.5
@@ -1,6 +1,16 @@
# ChangeLog for net-dns/nsd
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v 1.4 2013/03/17 15:17:11 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v 1.5 2013/04/03 19:10:39 wschlich Exp $
+
+*nsd-4.0.0_beta4-r1 (03 Apr 2013)
+*nsd-3.2.15 (03 Apr 2013)
+
+ 03 Apr 2013; Wolfram Schlich <wschlich@gentoo.org> +files/nsd.munin-conf,
+ +files/nsd3-patch.cron, +files/nsd3.initd, +nsd-3.2.15.ebuild,
+ +nsd-4.0.0_beta4-r1.ebuild, -nsd-4.0.0_beta4.ebuild, files/nsd.initd,
+ metadata.xml:
+ added nsd-3.x ebuild, added nsd-4.x munin plugin config. thanks to Tom
+ Hendrikx <tom@whyscream.net>
17 Mar 2013; Markos Chandras <hwoarang@gentoo.org> metadata.xml:
Add proxy-maintainers to metadata.xml
1.1 net-dns/nsd/nsd-3.2.15.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-3.2.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-3.2.15.ebuild?rev=1.1&content-type=text/plain
Index: nsd-3.2.15.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/nsd-3.2.15.ebuild,v 1.1 2013/04/03 19:10:39 wschlich Exp $
EAPI=4
inherit user
DESCRIPTION="An authoritative only, high performance, open source name server"
HOMEPAGE="http://www.nlnetlabs.nl/projects/nsd"
SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bind8-stats ipv6 minimal-responses mmap +nsec3 ratelimit root-server runtime-checks zone-stats"
RDEPEND="
dev-libs/openssl
virtual/yacc
"
DEPEND="
${RDEPEND}
sys-devel/flex
"
pkg_setup() {
enewgroup nsd
enewuser nsd -1 -1 -1 nsd
}
src_configure() {
# ebuild.sh sets localstatedir to /var/lib, but nsd expects /var in several locations
# some of these cannot be changed by arguments to econf/configure, f.i. logfile
econf \
--localstatedir="${EPREFIX}/var" \
--with-pidfile="${EPREFIX}/var/run/nsd/nsd.pid" \
--with-zonesdir="${EPREFIX}/var/lib/nsd" \
--enable-largefile \
$(use_enable bind8-stats) \
$(use_enable ipv6) \
$(use_enable minimal-responses) \
$(use_enable mmap) \
$(use_enable nsec3) \
$(use_enable ratelimit) \
$(use_enable root-server) \
$(use_enable runtime-checks checking) \
$(use_enable zone-stats)
}
src_install() {
emake DESTDIR="${D}" install
dodoc doc/{ChangeLog,CREDITS,NSD-FOR-BIND-USERS,README,RELNOTES,REQUIREMENTS}
insinto /usr/share/nsd
doins contrib/nsd.zones2nsd.conf
exeinto /etc/cron.daily
newexe "${FILESDIR}"/nsd3-patch.cron nsd-patch.cron
newinitd "${FILESDIR}"/nsd3.initd nsd
# database directory, writable by nsd for database updates and zone transfers
dodir /var/db/nsd
fowners nsd:nsd /var/db/nsd
fperms 750 /var/db/nsd
# zones directory, writable by root for 'nsdc patch'
dodir /var/lib/nsd
fowners root:nsd /var/lib/nsd
fperms 750 /var/lib/nsd
# remove /var/run data created by Makefile, handled by initd script
rm -r "${D}"/var/run || die "could not remove /var/run/ directory"
}
1.1 net-dns/nsd/nsd-4.0.0_beta4-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-4.0.0_beta4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-4.0.0_beta4-r1.ebuild?rev=1.1&content-type=text/plain
Index: nsd-4.0.0_beta4-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/nsd-4.0.0_beta4-r1.ebuild,v 1.1 2013/04/03 19:10:39 wschlich Exp $
EAPI=4
inherit user
DESCRIPTION="An authoritative only, high performance, open source name server"
HOMEPAGE="http://www.nlnetlabs.nl/projects/nsd"
# version voodoo needed only for non-release tarballs: 4.0.0_rc1 => 4.0.0rc1
MY_PV=${PV/_rc/rc}
MY_PV=${PV/_beta/b}
MY_P=${PN}-${MY_PV}
S="${WORKDIR}/${MY_P}"
SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bind8-stats ipv6 libevent minimal-responses mmap munin +nsec3 ratelimit root-server runtime-checks ssl"
RDEPEND="
dev-libs/openssl
virtual/yacc
libevent? ( dev-libs/libevent )
ssl? ( dev-libs/openssl )
munin? ( net-analyzer/munin )
"
DEPEND="
${RDEPEND}
sys-devel/flex
"
pkg_setup() {
enewgroup nsd
enewuser nsd -1 -1 -1 nsd
}
src_configure() {
econf \
--enable-largefile \
--with-logfile="${EPREFIX}"/var/log/nsd.log \
--with-pidfile="${EPREFIX}"/run/nsd/nsd.pid \
--with-dbfile="${EPREFIX}"/var/db/nsd/nsd.db \
--with-xfrdir="${EPREFIX}"/var/db/nsd \
--with-xfrdfile="${EPREFIX}"/var/db/nsd/xfrd.state \
--with-zonelistfile="${EPREFIX}"/var/db/nsd/zone.list \
--with-zonesdir="${EPREFIX}"/var/lib/nsd \
$(use_enable bind8-stats) \
$(use_enable ipv6) \
$(use_enable minimal-responses) \
$(use_enable mmap) \
$(use_enable nsec3) \
$(use_enable ratelimit) \
$(use_enable root-server) \
$(use_enable runtime-checks checking) \
$(use_with libevent) \
$(use_with ssl)
}
src_install() {
emake DESTDIR="${D}" install
dodoc doc/{ChangeLog,CREDITS,NSD-4-features,NSD-FOR-BIND-USERS,README,RELNOTES,REQUIREMENTS}
newinitd "${FILESDIR}"/nsd.initd nsd
# database directory, writable by nsd for database updates and zone transfers
dodir /var/db/nsd
fowners nsd:nsd /var/db/nsd
fperms 750 /var/db/nsd
# zones directory, writable by nsd for zone file updates (nsd-control write)
dodir /var/lib/nsd
fowners nsd:nsd /var/lib/nsd
fperms 750 /var/lib/nsd
# install munin plugin and config
if use munin; then
exeinto /usr/libexec/munin/plugins
doexe contrib/nsd_munin_
insinto /etc/munin/plugin-conf.d
newins "${FILESDIR}"/nsd.munin-conf nsd_munin
fi
# remove the /run directory that usually resides on tmpfs and is
# being taken care of by the nsd init script anyway (checkpath)
rm -rf "${D}"/run || die "Failed to remove /run"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-04-03 19:10 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-04-03 19:10 [gentoo-commits] gentoo-x86 commit in net-dns/nsd: nsd-3.2.15.ebuild nsd-4.0.0_beta4-r1.ebuild metadata.xml ChangeLog nsd-4.0.0_beta4.ebuild Wolfram Schlich (wschlich)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox