[gentoo-commits] gentoo-x86 commit in dev-libs/libconfig: ChangeLog libconfig-1.4.9-r1.ebuild

["Jeroen Roovers (jer)" <jer@gentoo.org>]

jer         13/04/02 18:55:41

  Modified:             ChangeLog
  Added:                libconfig-1.4.9-r1.ebuild
  Log:
  Add multilib support by Karl Lindén (bug #464128).
  
  (Portage version: 2.2.0_alpha171/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.53                 dev-libs/libconfig/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libconfig/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libconfig/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libconfig/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libconfig/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	5 Mar 2013 03:38:47 -0000	1.52
+++ ChangeLog	2 Apr 2013 18:55:41 -0000	1.53
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libconfig
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libconfig/ChangeLog,v 1.52 2013/03/05 03:38:47 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libconfig/ChangeLog,v 1.53 2013/04/02 18:55:41 jer Exp $
+
+*libconfig-1.4.9-r1 (02 Apr 2013)
+
+  02 Apr 2013; Jeroen Roovers <jer@gentoo.org> +libconfig-1.4.9-r1.ebuild,
+  +files/libconfig-1.4.9-out-of-source-build.patch:
+  Add multilib support by Karl Lindén (bug #464128).
 
   05 Mar 2013; Jeroen Roovers <jer@gentoo.org> metadata.xml:
   Add proxy-maintainers herd.



1.1                  dev-libs/libconfig/libconfig-1.4.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libconfig/libconfig-1.4.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libconfig/libconfig-1.4.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: libconfig-1.4.9-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libconfig/libconfig-1.4.9-r1.ebuild,v 1.1 2013/04/02 18:55:41 jer Exp $

EAPI="5"

inherit eutils autotools-multilib

DESCRIPTION="Libconfig is a simple library for manipulating structured configuration files"
HOMEPAGE="http://www.hyperrealm.com/libconfig/libconfig.html"
SRC_URI="http://www.hyperrealm.com/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
IUSE="+cxx examples static-libs"

DEPEND="
	sys-devel/libtool
	sys-devel/bison"
RDEPEND=""

PATCHES=( "${FILESDIR}/${P}-out-of-source-build.patch" )

AUTOTOOLS_AUTORECONF="1"

src_configure() {
	local myeconfargs=(
		$(use_enable cxx)
		--disable-examples
	)
	autotools-multilib_src_configure
}

local_src_test() {
	pushd "${BUILD_DIR}" > /dev/null || die
	emake test || die "test failed"
	popd > /dev/null || die
}

src_test() {
	# It responds to check but that does not work as intended
	multilib_foreach_abi local_src_test
}

src_install() {
	autotools-multilib_src_install
	if use examples; then
		local dir
		for dir in examples/c examples/c++; do
			insinto /usr/share/doc/${PF}/${dir}
			doins ${dir}/*
		done
	fi
}