[gentoo-commits] gentoo-x86 commit in net-libs/gnome-online-accounts: gnome-online-accounts-3.6.3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-libs/gnome-online-accounts: gnome-online-accounts-3.6.3.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         13/03/30 23:05:37

  Modified:             ChangeLog
  Added:                gnome-online-accounts-3.6.3.ebuild
  Log:
  Version bump, bug #456072.
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.14                 net-libs/gnome-online-accounts/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	29 Mar 2013 23:31:06 -0000	1.13
+++ ChangeLog	30 Mar 2013 23:05:37 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gnome-online-accounts
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog,v 1.13 2013/03/29 23:31:06 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog,v 1.14 2013/03/30 23:05:37 eva Exp $
+
+*gnome-online-accounts-3.6.3 (30 Mar 2013)
+
+  30 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-online-accounts-3.6.3.ebuild:
+  Version bump, bug #456072.
 
   29 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
   -gnome-online-accounts-3.4.2.ebuild:



1.1                  net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild?rev=1.1&content-type=text/plain

Index: gnome-online-accounts-3.6.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild,v 1.1 2013/03/30 23:05:37 eva Exp $

EAPI="5"
GNOME2_LA_PUNT="yes"

inherit eutils gnome2

DESCRIPTION="GNOME framework for accessing online accounts"
HOMEPAGE="https://live.gnome.org/GnomeOnlineAccounts"

LICENSE="LGPL-2+"
SLOT="0"
IUSE="gnome +introspection kerberos"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

# pango used in goaeditablelabel
# libsoup used in goaoauthprovider
# goa kerberos provider is incompatible with app-crypt/heimdal, see
# https://bugzilla.gnome.org/show_bug.cgi?id=692250
RDEPEND="
	>=dev-libs/glib-2.32:2
	app-crypt/libsecret
	dev-libs/json-glib
	dev-libs/libxml2:2
	net-libs/libsoup:2.4
	>=net-libs/libsoup-gnome-2.38:2.4
	net-libs/rest:0.7
	net-libs/webkit-gtk:3
	>=x11-libs/gtk+-3.5.1:3
	>=x11-libs/libnotify-0.7:=
	x11-libs/pango

	introspection? ( >=dev-libs/gobject-introspection-0.6.2 )
	kerberos? (
		app-crypt/gcr
		app-crypt/mit-krb5 )
"
# goa-daemon can launch gnome-control-center
PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	>=dev-util/gtk-doc-am-1.3
	>=dev-util/gdbus-codegen-2.30.0
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig
"

src_prepare() {
	# fix build failure with gcc-4.5 and USE=kerberos, bug #450706
	# https://bugzilla.gnome.org/show_bug.cgi?id=692251
	epatch "${FILESDIR}/${PN}-3.6.2-GoaKerberosIdentity.patch"
	gnome2_src_prepare
}

src_configure() {
	# TODO: Give users a way to set the G/Y!/FB/Twitter/Windows Live secrets
	gnome2_src_configure \
		--disable-static \
		--enable-documentation \
		--enable-exchange \
		--enable-facebook \
		--enable-windows-live \
		$(use_enable kerberos)
}