[gentoo-commits] gentoo-x86 commit in media-plugins/mythplugins: ChangeLog mythplugins-0.26.0_p20130322.ebuild

[gentoo-commits] gentoo-x86 commit in media-plugins/mythplugins: ChangeLog mythplugins-0.26.0_p20130322.ebuild

[Richard Freeman (rich0)]

rich0       13/03/29 20:54:22

  Modified:             ChangeLog
  Added:                mythplugins-0.26.0_p20130322.ebuild
  Log:
  update patch set
  
  (Portage version: 2.1.11.55/cvs/Linux x86_64, signed Manifest commit with key 0x08C170DE55EC123A)

Revision  Changes    Path
1.12                 media-plugins/mythplugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	24 Mar 2013 17:39:48 -0000	1.11
+++ ChangeLog	29 Mar 2013 20:54:22 -0000	1.12
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/mythplugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.11 2013/03/24 17:39:48 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.12 2013/03/29 20:54:22 rich0 Exp $
+
+*mythplugins-0.26.0_p20130322 (29 Mar 2013)
+
+  29 Mar 2013; Richard Freeman <rich0@gentoo.org>
+  +mythplugins-0.26.0_p20130322.ebuild:
+  update patch set
 
 *mythplugins-0.25.3_p20130322 (24 Mar 2013)
 



1.1                  media-plugins/mythplugins/mythplugins-0.26.0_p20130322.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130322.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130322.ebuild?rev=1.1&content-type=text/plain

Index: mythplugins-0.26.0_p20130322.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130322.ebuild,v 1.1 2013/03/29 20:54:22 rich0 Exp $

EAPI=4

PYTHON_DEPEND="2:2.6"
BACKPORTS="a17d3f453b2528ec7d8da49c92b71f478f25f4a3"
MY_P=${P%_p*}

inherit eutils python

DESCRIPTION="Official MythTV plugins"
HOMEPAGE="http://www.mythtv.org"
SRC_URI="ftp://ftp.osuosl.org/pub/mythtv/${MY_P}.tar.bz2
	${BACKPORTS:+http://dev.gentoo.org/~rich0/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

MYTHPLUGINS="mytharchive mythbrowser mythgallery mythgame \
mythmusic mythnetvision mythnews mythweather"

IUSE="${MYTHPLUGINS} cdda cdr exif fftw raw"

DEPEND="!media-plugins/mytharchive
	!media-plugins/mythbrowser
	!media-plugins/mythgallery
	!media-plugins/mythgame
	!media-plugins/mythmovies
	!media-plugins/mythmusic
	!media-plugins/mythnetvision
	!media-plugins/mythnews
	!media-plugins/mythweather
	=media-tv/mythtv-${PV}*[python]
	mytharchive? (
		app-cdr/dvd+rw-tools
		dev-python/imaging
		media-video/dvdauthor
		media-video/mjpegtools[png]
		media-video/transcode
		virtual/cdrtools
	)
	mythgallery? (
		media-libs/tiff
		virtual/opengl
		exif? ( >media-libs/libexif-0.6.9 )
		raw? ( media-gfx/dcraw )
	)
	mythmusic? (
		>=media-libs/flac-1.1.2
		>=media-libs/libvorbis-1.0
		>=media-libs/taglib-1.6
		media-sound/lame
		virtual/opengl
		cdda? (
			dev-libs/libcdio
			cdr? ( virtual/cdrtools )
		)
		fftw? ( sci-libs/fftw )
	)
	mythnetvision? (
		=dev-lang/python-2*[xml]
		dev-python/lxml
		dev-python/mysql-python
		dev-python/oauth
		dev-python/pycurl
	)
	mythweather? (
		dev-perl/DateManip
		dev-perl/DateTime-Format-ISO8601
		dev-perl/ImageSize
		dev-perl/JSON
		dev-perl/SOAP-Lite
		dev-perl/XML-Simple
		dev-perl/XML-Parser
		dev-perl/XML-SAX
		dev-perl/XML-XPath
	)"
RDEPEND="${DEPEND}"

REQUIRED_USE="
	cdda? ( mythmusic )
	cdr? ( mythmusic cdda )
	exif? ( mythgallery )
	fftw? ( mythmusic )
	mythnews? ( mythbrowser )
	raw? ( mythgallery )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	[[ -n ${BACKPORTS} ]] && \
		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
			epatch

	epatch_user
}

src_configure() {
	./configure \
		--prefix=/usr \
		--python=python2 \
		--enable-opengl \
		--disable-mythzoneminder \
		$(use_enable mytharchive) \
		$(use_enable mythbrowser) \
		$(use_enable mythgallery) \
		$(use_enable mythgame) \
		$(use_enable mythmusic) \
		$(use_enable mythnetvision) \
		$(use_enable mythnews) \
		$(use_enable mythweather) \
		$(use_enable cdda cdio) \
		$(use_enable exif) \
		$(use_enable exif new-exif) \
		$(use_enable raw dcraw) \
		|| die "configure failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "make install failed"
}