* [gentoo-commits] gentoo-x86 commit in app-editors/emacs: ChangeLog emacs-24.3_rc1.ebuild
@ 2013-03-05 13:49 Ulrich Mueller (ulm)
0 siblings, 0 replies; 2+ messages in thread
From: Ulrich Mueller (ulm) @ 2013-03-05 13:49 UTC (permalink / raw
To: gentoo-commits
ulm 13/03/05 13:49:13
Modified: ChangeLog
Added: emacs-24.3_rc1.ebuild
Log:
Version bump, release candidate for Emacs 24.3.
(Portage version: 2.1.11.54/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)
Revision Changes Path
1.555 app-editors/emacs/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?rev=1.555&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?rev=1.555&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?r1=1.554&r2=1.555
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v
retrieving revision 1.554
retrieving revision 1.555
diff -u -r1.554 -r1.555
--- ChangeLog 5 Mar 2013 09:17:11 -0000 1.554
+++ ChangeLog 5 Mar 2013 13:49:13 -0000 1.555
@@ -1,6 +1,11 @@
# ChangeLog for app-editors/emacs
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v 1.554 2013/03/05 09:17:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v 1.555 2013/03/05 13:49:13 ulm Exp $
+
+*emacs-24.3_rc1 (05 Mar 2013)
+
+ 05 Mar 2013; Ulrich Müller <ulm@gentoo.org> +emacs-24.3_rc1.ebuild:
+ Version bump, release candidate for Emacs 24.3.
05 Mar 2013; Agostino Sarubbo <ago@gentoo.org> emacs-23.4-r5.ebuild,
emacs-24.2-r1.ebuild:
1.1 app-editors/emacs/emacs-24.3_rc1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild?rev=1.1&content-type=text/plain
Index: emacs-24.3_rc1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild,v 1.1 2013/03/05 13:49:13 ulm Exp $
EAPI=5
inherit autotools elisp-common eutils flag-o-matic multilib readme.gentoo
DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"
HOMEPAGE="http://www.gnu.org/software/emacs/"
SRC_URI="mirror://gnu-alpha/emacs/pretest/${P/_/-}.tar.xz"
LICENSE="GPL-3+ FDL-1.3+ BSD HPND MIT W3C unicode PSF-2"
SLOT="24"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="alsa aqua athena dbus games gconf gif gnutls gpm gsettings gtk +gtk3 gzip-el hesiod imagemagick jpeg kerberos libxml2 livecd m17n-lib motif pax_kernel png selinux sound source svg tiff toolkit-scroll-bars wide-int X Xaw3d xft +xpm"
REQUIRED_USE="?? ( aqua X )"
RDEPEND="sys-libs/ncurses
>=app-admin/eselect-emacs-1.2
>=app-emacs/emacs-common-gentoo-1.3-r3[games?,X?]
net-libs/liblockfile
hesiod? ( net-dns/hesiod )
kerberos? ( virtual/krb5 )
alsa? ( media-libs/alsa-lib )
gpm? ( sys-libs/gpm )
dbus? ( sys-apps/dbus )
gnutls? ( net-libs/gnutls )
libxml2? ( >=dev-libs/libxml2-2.2.0 )
selinux? ( sys-libs/libselinux )
X? (
x11-libs/libXmu
x11-libs/libXt
x11-misc/xbitmaps
gconf? ( >=gnome-base/gconf-2.26.2 )
gsettings? ( >=dev-libs/glib-2.28.6 )
gif? ( media-libs/giflib )
jpeg? ( virtual/jpeg )
png? ( >=media-libs/libpng-1.4:0 )
svg? ( >=gnome-base/librsvg-2.0 )
tiff? ( media-libs/tiff )
xpm? ( x11-libs/libXpm )
imagemagick? ( >=media-gfx/imagemagick-6.6.2 )
xft? (
media-libs/fontconfig
media-libs/freetype
x11-libs/libXft
m17n-lib? (
>=dev-libs/libotf-0.9.4
>=dev-libs/m17n-lib-1.5.1
)
)
gtk? (
gtk3? ( x11-libs/gtk+:3 )
!gtk3? ( x11-libs/gtk+:2 )
)
!gtk? (
Xaw3d? ( x11-libs/libXaw3d )
!Xaw3d? (
athena? ( x11-libs/libXaw )
!athena? ( motif? ( >=x11-libs/motif-2.3:0 ) )
)
)
)"
DEPEND="${RDEPEND}
app-arch/xz-utils
alsa? ( virtual/pkgconfig )
dbus? ( virtual/pkgconfig )
gnutls? ( virtual/pkgconfig )
libxml2? ( virtual/pkgconfig )
X? ( virtual/pkgconfig )
gzip-el? ( app-arch/gzip )
pax_kernel? ( sys-apps/paxctl )"
RDEPEND="${RDEPEND}
!<app-editors/emacs-vcs-${PV}"
EMACS_SUFFIX="${PN/emacs/emacs-${SLOT}}"
SITEFILE="20${PN}-${SLOT}-gentoo.el"
# FULL_VERSION keeps the full version number, which is needed in
# order to determine some path information correctly for copy/move
# operations later on
FULL_VERSION="${PV%%_*}"
S="${WORKDIR}/emacs-${FULL_VERSION}"
src_prepare() {
#EPATCH_SUFFIX=patch epatch
epatch_user
if ! use alsa; then
# ALSA is detected even if not requested by its USE flag.
# Suppress it by supplying pkg-config with a wrong library name.
sed -i -e "/ALSA_MODULES=/s/alsa/DiSaBlEaLsA/" configure.ac \
|| die "unable to sed configure.ac"
fi
if ! use gzip-el; then
# Emacs' build system automatically detects the gzip binary and
# compresses el files. We don't want that so confuse it with a
# wrong binary name
sed -i -e "/AC_PATH_PROG/s/gzip/PrEvEnTcOmPrEsSiOn/" configure.ac \
|| die "unable to sed configure.ac"
fi
AT_M4DIR=m4 eautoreconf
}
src_configure() {
strip-flags
if use sh; then
replace-flags "-O[1-9]" -O0 #262359
elif use ia64; then
replace-flags "-O[2-9]" -O1 #325373
else
replace-flags "-O[3-9]" -O2
fi
local myconf
if use alsa && ! use sound; then
einfo "Although sound USE flag is disabled you chose to have alsa,"
einfo "so sound is switched on anyway."
myconf+=" --with-sound"
else
myconf+=" $(use_with sound)"
fi
if use X; then
myconf+=" --with-x --without-ns"
myconf+=" $(use_with gconf)"
myconf+=" $(use_with gsettings)"
myconf+=" $(use_with toolkit-scroll-bars)"
myconf+=" $(use_with gif)"
myconf+=" $(use_with jpeg)"
myconf+=" $(use_with png)"
myconf+=" $(use_with svg rsvg)"
myconf+=" $(use_with tiff)"
myconf+=" $(use_with xpm)"
myconf+=" $(use_with imagemagick)"
if use xft; then
myconf+=" --with-xft"
myconf+=" $(use_with m17n-lib libotf)"
myconf+=" $(use_with m17n-lib m17n-flt)"
else
myconf+=" --without-xft"
myconf+=" --without-libotf --without-m17n-flt"
use m17n-lib && ewarn \
"USE flag \"m17n-lib\" has no effect if \"xft\" is not set."
fi
if use gtk; then
einfo "Configuring to build with GIMP Toolkit (GTK+)"
myconf+=" --with-x-toolkit=$(usex gtk3 gtk3 gtk2)"
local f
for f in athena Xaw3d motif; do
use ${f} && ewarn "USE flag \"${f}\" ignored" \
"(superseded by \"gtk\")"
done
elif use athena || use Xaw3d; then
einfo "Configuring to build with Athena/Lucid toolkit"
myconf+=" --with-x-toolkit=lucid $(use_with Xaw3d xaw3d)"
use motif && ewarn "USE flag \"motif\" ignored" \
"(superseded by \"athena\" or \"Xaw3d\")"
elif use motif; then
einfo "Configuring to build with Motif toolkit"
myconf+=" --with-x-toolkit=motif"
else
einfo "Configuring to build with no toolkit"
myconf+=" --with-x-toolkit=no"
fi
elif use aqua; then
einfo "Configuring to build with Cocoa support"
myconf+=" --with-ns --disable-ns-self-contained"
myconf+=" --without-x"
else
myconf+=" --without-x --without-ns"
fi
# Save version information in the Emacs binary. It will be available
# in variable "system-configuration-options".
myconf+=" GENTOO_PACKAGE=${CATEGORY}/${PF}"
# According to configure, this option is only used for GNU/Linux
# (x86_64 and s390). For Gentoo Prefix we have to explicitly spell
# out the location because $(get_libdir) does not necessarily return
# something that matches the host OS's libdir naming (e.g. RHEL).
local crtdir=$($(tc-getCC) -print-file-name=crt1.o)
crtdir=${crtdir%/*}
econf \
--program-suffix=-${EMACS_SUFFIX} \
--program-transform-name="s/emacs-[0-9].*/${EMACS_SUFFIX}/" \
--infodir="${EPREFIX}"/usr/share/info/${EMACS_SUFFIX} \
--enable-locallisppath="${EPREFIX}/etc/emacs:${EPREFIX}${SITELISP}" \
--with-crt-dir="${crtdir}" \
--with-gameuser="${GAMES_USER_DED:-games}" \
--without-compress-info \
$(use_with hesiod) \
$(use_with kerberos) $(use_with kerberos kerberos5) \
$(use_with gpm) \
$(use_with dbus) \
$(use_with gnutls) \
$(use_with libxml2 xml2) \
$(use_with selinux) \
$(use_with wide-int) \
${myconf}
}
src_compile() {
export SANDBOX_ON=0 # for the unbelievers, see Bug #131505
emake
}
src_install () {
emake DESTDIR="${D}" NO_BIN_LINK=t install
# move man pages to the correct place
local m
for m in "${ED}"/usr/share/man/man1/* ; do
mv "${m}" "${m%.1}-${EMACS_SUFFIX}.1" || die "mv man failed"
done
# move info dir to avoid collisions with the dir file generated by portage
mv "${ED}"/usr/share/info/${EMACS_SUFFIX}/dir{,.orig} \
|| die "moving info dir failed"
touch "${ED}"/usr/share/info/${EMACS_SUFFIX}/.keepinfodir
docompress -x /usr/share/info/${EMACS_SUFFIX}/dir.orig
# avoid collision between slots, see bug #169033 e.g.
rm "${ED}"/usr/share/emacs/site-lisp/subdirs.el
rm -rf "${ED}"/usr/share/{applications,icons}
rm -rf "${ED}"/var
# remove unused <version>/site-lisp dir
rm -rf "${ED}"/usr/share/emacs/${FULL_VERSION}/site-lisp
local c=";;"
if use source; then
insinto /usr/share/emacs/${FULL_VERSION}/src
# This is not meant to install all the source -- just the
# C source you might find via find-function
doins src/*.{c,h,m}
c=""
fi
sed 's/^X//' >"${T}/${SITEFILE}" <<-EOF
X
;;; ${PN}-${SLOT} site-lisp configuration
X
(when (string-match "\\\\\`${FULL_VERSION//./\\\\.}\\\\>" emacs-version)
X ${c}(setq find-function-C-source-directory
X ${c} "${EPREFIX}/usr/share/emacs/${FULL_VERSION}/src")
X (let ((path (getenv "INFOPATH"))
X (dir "${EPREFIX}/usr/share/info/${EMACS_SUFFIX}")
X (re "\\\\\`${EPREFIX}/usr/share/info\\\\>"))
X (and path
X ;; move Emacs Info dir before anything else in /usr/share/info
X (let* ((p (cons nil (split-string path ":" t))) (q p))
X (while (and (cdr q) (not (string-match re (cadr q))))
X (setq q (cdr q)))
X (setcdr q (cons dir (delete dir (cdr q))))
X (setq Info-directory-list (prune-directory-list (cdr p)))))))
EOF
elisp-site-file-install "${T}/${SITEFILE}" || die
dodoc README BUGS
if use aqua; then
dodir /Applications/Gentoo
rm -rf "${ED}"/Applications/Gentoo/Emacs${EMACS_SUFFIX#emacs}.app
mv nextstep/Emacs.app \
"${ED}"/Applications/Gentoo/Emacs${EMACS_SUFFIX#emacs}.app || die
fi
DOC_CONTENTS="You can set the version to be started by /usr/bin/emacs
through the Emacs eselect module, which also redirects man and info
pages. Therefore, several Emacs versions can be installed at the
same time. \"man emacs.eselect\" for details.
\\n\\nIf you upgrade from Emacs version 24.2 or earlier, then it is
strongly recommended that you use app-admin/emacs-updater to rebuild
all byte-compiled elisp files of the installed Emacs packages."
use X && DOC_CONTENTS+="\\n\\nYou need to install some fonts for Emacs.
Installing media-fonts/font-adobe-{75,100}dpi on the X server's
machine would satisfy basic Emacs requirements under X11.
See also http://www.gentoo.org/proj/en/lisp/emacs/xft.xml
for how to enable anti-aliased fonts."
use aqua && DOC_CONTENTS+="\\n\\nEmacs${EMACS_SUFFIX#emacs}.app is in
${EPREFIX}/Applications/Gentoo. You may want to copy or symlink it
into /Applications by yourself."
[[ ${REPLACING_VERSIONS} =~ (^|[[:space:]])24\.[12]($|[^0-9]) ]] \
&& FORCE_PRINT_ELOG=1
readme.gentoo_create_doc
}
pkg_preinst() {
# move Info dir file to correct name
local infodir=/usr/share/info/${EMACS_SUFFIX} f
if [[ -f ${ED}${infodir}/dir.orig ]]; then
mv "${ED}"${infodir}/dir{.orig,} || die "moving info dir failed"
elif [[ -d "${ED}"${infodir} ]]; then
# this should not happen in EAPI 4
ewarn "Regenerating Info directory index in ${infodir} ..."
rm -f "${ED}"${infodir}/dir{,.*}
for f in "${ED}"${infodir}/*; do
if [[ ${f##*/} != *-[0-9]* && -e ${f} ]]; then
install-info --info-dir="${ED}"${infodir} "${f}" \
|| die "install-info failed"
fi
done
fi
}
pkg_postinst() {
elisp-site-regen
readme.gentoo_print_elog
if use livecd; then
# force an update of the emacs symlink for the livecd/dvd,
# because some microemacs packages set it with USE=livecd
eselect emacs update
else
eselect emacs update ifunset
fi
}
pkg_postrm() {
elisp-site-regen
eselect emacs update ifunset
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-editors/emacs: ChangeLog emacs-24.3_rc1.ebuild
@ 2013-03-06 9:05 Ulrich Mueller (ulm)
0 siblings, 0 replies; 2+ messages in thread
From: Ulrich Mueller (ulm) @ 2013-03-06 9:05 UTC (permalink / raw
To: gentoo-commits
ulm 13/03/06 09:05:37
Modified: ChangeLog emacs-24.3_rc1.ebuild
Log:
Fix previous commit, REPLACING_VERSIONS is not valid in src_install.
(Portage version: 2.1.11.55/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)
Revision Changes Path
1.557 app-editors/emacs/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?rev=1.557&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?rev=1.557&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/ChangeLog?r1=1.556&r2=1.557
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v
retrieving revision 1.556
retrieving revision 1.557
diff -u -r1.556 -r1.557
--- ChangeLog 5 Mar 2013 18:25:34 -0000 1.556
+++ ChangeLog 6 Mar 2013 09:05:37 -0000 1.557
@@ -1,6 +1,9 @@
# ChangeLog for app-editors/emacs
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v 1.556 2013/03/05 18:25:34 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/ChangeLog,v 1.557 2013/03/06 09:05:37 ulm Exp $
+
+ 06 Mar 2013; Ulrich Müller <ulm@gentoo.org> emacs-24.3_rc1.ebuild:
+ Fix previous commit, REPLACING_VERSIONS is not valid in src_install.
05 Mar 2013; Ulrich Müller <ulm@gentoo.org> emacs-23.4-r5.ebuild:
Use functions from readme.gentoo.eclass instead of elog.
1.2 app-editors/emacs/emacs-24.3_rc1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild?r1=1.1&r2=1.2
Index: emacs-24.3_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- emacs-24.3_rc1.ebuild 5 Mar 2013 13:49:13 -0000 1.1
+++ emacs-24.3_rc1.ebuild 6 Mar 2013 09:05:37 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild,v 1.1 2013/03/05 13:49:13 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs/emacs-24.3_rc1.ebuild,v 1.2 2013/03/06 09:05:37 ulm Exp $
EAPI=5
@@ -289,8 +289,6 @@
use aqua && DOC_CONTENTS+="\\n\\nEmacs${EMACS_SUFFIX#emacs}.app is in
${EPREFIX}/Applications/Gentoo. You may want to copy or symlink it
into /Applications by yourself."
- [[ ${REPLACING_VERSIONS} =~ (^|[[:space:]])24\.[12]($|[^0-9]) ]] \
- && FORCE_PRINT_ELOG=1
readme.gentoo_create_doc
}
@@ -314,6 +312,9 @@
pkg_postinst() {
elisp-site-regen
+
+ [[ ${REPLACING_VERSIONS} =~ (^|[[:space:]])24\.[12]($|[^0-9]) ]] \
+ && FORCE_PRINT_ELOG=1
readme.gentoo_print_elog
if use livecd; then
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-03-06 9:05 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-03-05 13:49 [gentoo-commits] gentoo-x86 commit in app-editors/emacs: ChangeLog emacs-24.3_rc1.ebuild Ulrich Mueller (ulm)
-- strict thread matches above, loose matches on Subject: below --
2013-03-06 9:05 Ulrich Mueller (ulm)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox