[gentoo-commits] gentoo-x86 commit in sci-libs/geos: ChangeLog geos-3.3.8.ebuild

[gentoo-commits] gentoo-x86 commit in sci-libs/geos: ChangeLog geos-3.3.8.ebuild

[Aaron Swenson (titanofold)]

titanofold    13/03/02 04:04:09

  Modified:             ChangeLog
  Added:                geos-3.3.8.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.11.50/cvs/Linux x86_64, signed Manifest commit with key D1BBFDA0)

Revision  Changes    Path
1.71                 sci-libs/geos/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	2 Feb 2013 06:04:19 -0000	1.70
+++ ChangeLog	2 Mar 2013 04:04:09 -0000	1.71
@@ -1,6 +1,11 @@
 # ChangeLog for sci-libs/geos
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v 1.70 2013/02/02 06:04:19 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v 1.71 2013/03/02 04:04:09 titanofold Exp $
+
+*geos-3.3.8 (02 Mar 2013)
+
+  02 Mar 2013; Aaron W. Swenson <titanofold@gentoo.org> +geos-3.3.8.ebuild:
+  version bump
 
 *geos-3.3.7 (02 Feb 2013)
 



1.1                  sci-libs/geos/geos-3.3.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/geos-3.3.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/geos-3.3.8.ebuild?rev=1.1&content-type=text/plain

Index: geos-3.3.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/geos-3.3.8.ebuild,v 1.1 2013/03/02 04:04:09 titanofold Exp $

EAPI=4

PYTHON_DEPEND="python? 2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"
inherit autotools eutils python

DESCRIPTION="Geometry engine library for Geographic Information Systems"
HOMEPAGE="http://trac.osgeo.org/geos/"
SRC_URI="http://download.osgeo.org/geos/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="doc php python ruby static-libs"

RDEPEND="php? ( dev-lang/php:5.3[-threads] )
	ruby? ( dev-lang/ruby )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	php? ( dev-lang/swig )
	python? ( dev-lang/swig )
	ruby? ( dev-lang/swig )"

pkg_setup() {
	use python && python_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/3.2.0-python.patch \
		"${FILESDIR}"/3.2.0-darwin.patch \
		"${FILESDIR}"/3.3.2-solaris-isnan.patch
	eautoreconf
	echo "#!${EPREFIX}/bin/bash" > py-compile
}

src_configure() {
	econf \
		$(use_enable python) \
		$(use_enable ruby) \
		$(use_enable php) \
		$(use_enable static-libs static)
}

src_compile() {
	emake
	if use python; then
		emake -C swig/python clean
		python_copy_sources swig/python
		building() {
			emake \
				PYTHON_CPPFLAGS="-I${EPREFIX}$(python_get_includedir)" \
				PYTHON_LDFLAGS="$(python_get_library -l)" \
				SWIG_PYTHON_CPPFLAGS="-I${EPREFIX}$(python_get_includedir)" \
				pyexecdir="${EPREFIX}$(python_get_sitedir)" \
				pythondir="${EPREFIX}$(python_get_sitedir)"
		}
		python_execute_function -s --source-dir swig/python building
	fi
	use doc && emake -C "${S}/doc" doxygen-html
}

src_install() {
	default
	if use python; then
		installation() {
			emake \
				DESTDIR="${D}" \
				pyexecdir="${EPREFIX}$(python_get_sitedir)" \
				pythondir="${EPREFIX}$(python_get_sitedir)" \
				install
		}
		python_execute_function -s --source-dir swig/python installation
		python_clean_installation_image
	fi
	use doc && dohtml -r "${S}/doc" doxygen_docs/html/*
	find "${ED}" -name '*.la' -exec rm -f {} +
}

pkg_postinst() {
	use python && python_mod_optimize geos/geos.py
}

pkg_postrm() {
	use python && python_mod_cleanup geos/geos.py
}