From: "Eray Aslan (eras)" <eras@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in app-antivirus/clamav: clamav-0.97.6-r3.ebuild ChangeLog
Date: Fri, 1 Mar 2013 08:18:17 +0000 (UTC) [thread overview]
Message-ID: <20130301081817.EA1642171E@flycatcher.gentoo.org> (raw)
eras 13/03/01 08:18:17
Modified: ChangeLog
Added: clamav-0.97.6-r3.ebuild
Log:
Be nice to gentoo/bsd - bug #459686
(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 0x77F1F175586A3B1F)
Revision Changes Path
1.442 app-antivirus/clamav/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.442&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.442&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-antivirus/clamav/ChangeLog?r1=1.441&r2=1.442
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v
retrieving revision 1.441
retrieving revision 1.442
diff -u -r1.441 -r1.442
--- ChangeLog 26 Feb 2013 14:50:41 -0000 1.441
+++ ChangeLog 1 Mar 2013 08:18:17 -0000 1.442
@@ -1,6 +1,12 @@
# ChangeLog for app-antivirus/clamav
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.441 2013/02/26 14:50:41 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.442 2013/03/01 08:18:17 eras Exp $
+
+*clamav-0.97.6-r3 (01 Mar 2013)
+
+ 01 Mar 2013; Eray Aslan <eras@gentoo.org> +clamav-0.97.6-r3.ebuild,
+ +files/clamd.initd-r3:
+ Be nice to gentoo/bsd - bug #459686
26 Feb 2013; Jeroen Roovers <jer@gentoo.org> clamav-0.97.6-r2.ebuild:
Stable for HPPA (bug #457144).
1.1 app-antivirus/clamav/clamav-0.97.6-r3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-antivirus/clamav/clamav-0.97.6-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-antivirus/clamav/clamav-0.97.6-r3.ebuild?rev=1.1&content-type=text/plain
Index: clamav-0.97.6-r3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/clamav-0.97.6-r3.ebuild,v 1.1 2013/03/01 08:18:17 eras Exp $
EAPI=4
inherit eutils flag-o-matic user
DESCRIPTION="Clam Anti-Virus Scanner"
HOMEPAGE="http://www.clamav.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
IUSE="bzip2 clamdtop iconv ipv6 milter selinux static-libs uclibc"
CDEPEND="bzip2? ( app-arch/bzip2 )
clamdtop? ( sys-libs/ncurses )
iconv? ( virtual/libiconv )
milter? ( || ( mail-filter/libmilter mail-mta/sendmail ) )
dev-libs/libtommath
>=sys-libs/zlib-1.2.2
sys-devel/libtool"
DEPEND="${CDEPEND}
virtual/pkgconfig"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-clamav )"
RESTRICT="test"
DOCS=( AUTHORS BUGS ChangeLog FAQ INSTALL NEWS README UPGRADE )
PATCHES=(
"${FILESDIR}"/${PN}-0.97-nls.patch
)
pkg_setup() {
enewgroup clamav
enewuser clamav -1 -1 /dev/null clamav
}
src_prepare() {
use ppc64 && append-flags -mminimal-toic
use uclibc && export ac_cv_type_error_t=yes
}
src_configure() {
econf \
--disable-experimental \
--enable-id-check \
--with-dbdir="${EPREFIX}"/var/lib/clamav \
--with-system-tommath \
--with-zlib="${EPREFIX}"/usr \
$(use_enable bzip2) \
$(use_enable clamdtop) \
$(use_enable ipv6) \
$(use_enable milter) \
$(use_enable static-libs static) \
$(use_with iconv)
}
src_install() {
default
rm -rf "${ED}"/var/lib/clamav
newinitd "${FILESDIR}"/clamd.initd-r3 clamd
newconfd "${FILESDIR}"/clamd.conf clamd
keepdir /var/lib/clamav
fowners clamav:clamav /var/lib/clamav
keepdir /var/log/clamav
fowners clamav:clamav /var/log/clamav
dodir /etc/logrotate.d
insinto /etc/logrotate.d
newins "${FILESDIR}"/clamav.logrotate clamav
# Modify /etc/{clamd,freshclam}.conf to be usable out of the box
sed -i -e "s:^\(Example\):\# \1:" \
-e "s:.*\(PidFile\) .*:\1 ${EPREFIX}/var/run/clamav/clamd.pid:" \
-e "s:.*\(LocalSocket\) .*:\1 ${EPREFIX}/var/run/clamav/clamd.sock:" \
-e "s:.*\(User\) .*:\1 clamav:" \
-e "s:^\#\(LogFile\) .*:\1 ${EPREFIX}/var/log/clamav/clamd.log:" \
-e "s:^\#\(LogTime\).*:\1 yes:" \
-e "s:^\#\(AllowSupplementaryGroups\).*:\1 yes:" \
"${ED}"/etc/clamd.conf
sed -i -e "s:^\(Example\):\# \1:" \
-e "s:.*\(PidFile\) .*:\1 ${EPREFIX}/var/run/clamav/freshclam.pid:" \
-e "s:.*\(DatabaseOwner\) .*:\1 clamav:" \
-e "s:^\#\(UpdateLogFile\) .*:\1 ${EPREFIX}/var/log/clamav/freshclam.log:" \
-e "s:^\#\(NotifyClamd\).*:\1 ${EPREFIX}/etc/clamd.conf:" \
-e "s:^\#\(ScriptedUpdates\).*:\1 yes:" \
-e "s:^\#\(AllowSupplementaryGroups\).*:\1 yes:" \
"${ED}"/etc/freshclam.conf
if use milter ; then
# MilterSocket one to include ' /' because there is a 2nd line for
# inet: which we want to leave
dodoc "${FILESDIR}"/clamav-milter.README.gentoo
sed -i -e "s:^\(Example\):\# \1:" \
-e "s:.*\(PidFile\) .*:\1 ${EPREFIX}/var/run/clamav/clamav-milter.pid:" \
-e "s+^\#\(ClamdSocket\) .*+\1 unix:${EPREFIX}/var/run/clamav/clamd.sock+" \
-e "s:.*\(User\) .*:\1 clamav:" \
-e "s+^\#\(MilterSocket\) /.*+\1 unix:${EPREFIX}/var/run/clamav/clamav-milter.sock+" \
-e "s:^\#\(AllowSupplementaryGroups\).*:\1 yes:" \
-e "s:^\#\(LogFile\) .*:\1 ${EPREFIX}/var/log/clamav/clamav-milter.log:" \
"${ED}"/etc/clamav-milter.conf
cat > "${ED}"/etc/conf.d/clamd <<-EOF
MILTER_NICELEVEL=19
START_MILTER=no
EOF
fi
prune_libtool_files --all
}
pkg_postinst() {
if use milter ; then
elog "For simple instructions how to setup the clamav-milter read the"
elog "clamav-milter.README.gentoo in /usr/share/doc/${PF}"
fi
}
reply other threads:[~2013-03-01 8:18 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20130301081817.EA1642171E@flycatcher.gentoo.org \
--to=eras@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox