public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.0.2-r2.ebuild ChangeLog
@ 2013-02-19 20:41 Doug Goldstein (cardoe)
  0 siblings, 0 replies; 4+ messages in thread
From: Doug Goldstein (cardoe) @ 2013-02-19 20:41 UTC (permalink / raw
  To: gentoo-commits

cardoe      13/02/19 20:41:06

  Modified:             ChangeLog
  Added:                libvirt-1.0.2-r2.ebuild
  Log:
  Bump to fix compile issues with some USE flag combinations and fix for Python bindings.
  
  (Portage version: 2.1.11.50/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.248                app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.248&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.248&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.247&r2=1.248

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.247
retrieving revision 1.248
diff -u -r1.247 -r1.248
--- ChangeLog	1 Feb 2013 00:07:52 -0000	1.247
+++ ChangeLog	19 Feb 2013 20:41:05 -0000	1.248
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.247 2013/02/01 00:07:52 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.248 2013/02/19 20:41:05 cardoe Exp $
+
+*libvirt-1.0.2-r2 (19 Feb 2013)
+
+  19 Feb 2013; Doug Goldstein <cardoe@gentoo.org> +libvirt-1.0.2-r2.ebuild:
+  Bump to fix compile issues with some USE flag combinations and fix for Python
+  bindings.
 
   01 Feb 2013; Doug Goldstein <cardoe@gentoo.org> libvirt-1.0.2-r1.ebuild:
   Fix Xen support after user feedback on bug #454598



1.1                  app-emulation/libvirt/libvirt-1.0.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: libvirt-1.0.2-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.1 2013/02/19 20:41:05 cardoe Exp $

EAPI=5

BACKPORTS=1b2f2439
AUTOTOOLIZE=yes

MY_P="${P/_rc/-rc}"

PYTHON_DEPEND="python? 2:2.5"
#RESTRICT_PYTHON_ABIS="3.*"
#SUPPORT_PYTHON_ABIS="1"

inherit eutils python user autotools linux-info

if [[ ${PV} = *9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="git://libvirt.org/libvirt.git"
	AUTOTOOLIZE=yes
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://libvirt.org/sources/${MY_P}.tar.gz
		ftp://libvirt.org/libvirt/${MY_P}.tar.gz
		${BACKPORTS:+
			http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
	KEYWORDS="~amd64 ~x86"
fi
S="${WORKDIR}/${P%_rc*}"

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="audit avahi +caps firewalld iscsi +libvirtd lvm +lxc +macvtap nfs \
	nls numa openvz parted pcap phyp policykit python qemu rbd sasl \
	selinux +udev uml +vepa virtualbox virt-network xen elibc_glibc"
REQUIRED_USE="libvirtd? ( || ( lxc openvz qemu uml virtualbox xen ) )
	lxc? ( caps libvirtd )
	openvz? ( libvirtd )
	qemu? ( libvirtd )
	uml? ( libvirtd )
	vepa? ( macvtap )
	virtualbox? ( libvirtd )
	xen? ( libvirtd )
	virt-network? ( libvirtd )
	firewalld? ( virt-network )"

# gettext.sh command is used by the libvirt command wrappers, and it's
# non-optional, so put it into RDEPEND.
# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
# package will use 3 by default. Since we don't have slot pinning in an API,
# we must go with the most recent
RDEPEND="sys-libs/readline
	sys-libs/ncurses
	>=net-misc/curl-7.18.0
	dev-libs/libgcrypt
	>=dev-libs/libxml2-2.7.6
	dev-libs/libnl:3
	>=net-libs/gnutls-1.0.25
	net-libs/libssh2
	sys-apps/dmidecode
	>=sys-apps/util-linux-2.17
	sys-devel/gettext
	>=net-analyzer/netcat6-1.0-r2
	app-misc/scrub
	audit? ( sys-process/audit )
	avahi? ( >=net-dns/avahi-0.6[dbus] )
	caps? ( sys-libs/libcap-ng )
	iscsi? ( sys-block/open-iscsi )
	lxc? ( sys-power/pm-utils )
	lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
	nfs? ( net-fs/nfs-utils )
	numa? (
		>sys-process/numactl-2.0.2
		sys-process/numad
	)
	openvz? ( sys-kernel/openvz-sources )
	parted? (
		>=sys-block/parted-1.8[device-mapper]
		sys-fs/lvm2
	)
	pcap? ( >=net-libs/libpcap-1.0.0 )
	policykit? ( >=sys-auth/polkit-0.9 )
	qemu? (
		>=app-emulation/qemu-0.13.0
		dev-libs/yajl
		sys-power/pm-utils
	)
	rbd? ( sys-cluster/ceph )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( >=sys-libs/libselinux-2.0.85 )
	virtualbox? ( || ( app-emulation/virtualbox >=app-emulation/virtualbox-bin-2.2.0 ) )
	xen? ( app-emulation/xen-tools app-emulation/xen )
	udev? ( virtual/udev >=x11-libs/libpciaccess-0.10.9 )
	virt-network? ( net-dns/dnsmasq
		>=net-firewall/iptables-1.4.10
		net-misc/radvd
		net-firewall/ebtables
		sys-apps/iproute2[-minimal]
		firewalld? ( net-firewall/firewalld )
	)
	elibc_glibc? ( || ( >=net-libs/libtirpc-0.2.2-r1 <sys-libs/glibc-2.14 ) )"
# one? ( dev-libs/xmlrpc-c )
DEPEND="${RDEPEND}
	virtual/pkgconfig
	app-text/xhtml1
	dev-libs/libxslt
	=dev-lang/python-2*"

LXC_CONFIG_CHECK="
	~CGROUPS
	~CGROUP_FREEZER
	~CGROUP_DEVICE
	~CPUSETS
	~CGROUP_CPUACCT
	~RESOURCE_COUNTERS
	~CGROUP_SCHED
	~BLK_CGROUP
	~NAMESPACES
	~UTS_NS
	~IPC_NS
	~PID_NS
	~NET_NS
	~DEVPTS_MULTIPLE_INSTANCES
	~VETH
	~MACVLAN
	~POSIX_MQUEUE
	~!GRKERNSEC_CHROOT_MOUNT
	~!GRKERNSEC_CHROOT_DOUBLE
	~!GRKERNSEC_CHROOT_PIVOT
	~!GRKERNSEC_CHROOT_CHMOD
	~!GRKERNSEC_CHROOT_CAPS
"

VIRTNET_CONFIG_CHECK="
	~BRIDGE_NF_EBTABLES
	~NETFILTER_ADVANCED
	~NETFILTER_XT_TARGET_CHECKSUM
"

MACVTAP_CONFIG_CHECK="~MACVTAP"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup

	enewgroup qemu 77
	enewuser qemu 77 -1 -1 qemu kvm

	# Some people used the masked ebuild which was not adding the qemu
	# user to the kvm group originally. This results in VMs failing to
	# start for some users. bug #430808
	egetent group kvm | grep -q qemu
	if [[ $? -ne 0 ]]; then
		gpasswd -a qemu kvm
	fi

	# Handle specific kernel versions for different features
	kernel_is lt 3 5 && LXC_CONFIG_CHECK+=" ~USER_NS"
	kernel_is lt 3 6 && LXC_CONFIG_CHECK+=" ~CGROUP_MEM_RES_CTLR" || \
						LXC_CONFIG_CHECK+=" ~MEMCG"

	CONFIG_CHECK=""
	use lxc && CONFIG_CHECK+="${LXC_CONFIG_CHECK}"
	use macvtap && CONFIG_CHECK+="${MACVTAP}"
	use virt-network && CONFIG_CHECK+="${VIRTNET_CONFIG_CHECK}"
	if [[ -n ${CONFIG_CHECK} ]]; then
		linux-info_pkg_setup
	fi
}

src_prepare() {
	touch "${S}/.mailmap"
	[[ -n ${BACKPORTS} ]] && \
		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
			epatch

	if [[ ${PV} = *9999* ]]; then

		# git checkouts require bootstrapping to create the configure script.
		# Additionally the submodules must be cloned to the right locations
		# bug #377279
		./bootstrap || die "bootstrap failed"
		(
			git submodule status | sed 's/^[ +-]//;s/ .*//'
			git hash-object bootstrap.conf
		) >.git-module-status
	fi

	epatch_user

	[[ -n ${AUTOTOOLIZE} ]] && eautoreconf

	# Tweak the init script
	local avahi_init=
	local iscsi_init=
	local rbd_init=
	local firewalld_init=
	cp "${FILESDIR}/libvirtd.init-r11" "${S}/libvirtd.init"
	use avahi && avahi_init='avahi-daemon'
	use iscsi && iscsi_init='iscsid'
	use rbd && rbd_init='ceph'
	use firewalld && firewalld_init='need firewalld'

	sed -e "s/USE_FLAG_FIREWALLD/${firewalld_init}/" -i "${S}/libvirtd.init"
	sed -e "s/USE_FLAG_AVAHI/${avahi_init}/" -i "${S}/libvirtd.init"
	sed -e "s/USE_FLAG_ISCSI/${iscsi_init}/" -i "${S}/libvirtd.init"
	sed -e "s/USE_FLAG_RBD/${rbd_init}/" -i "${S}/libvirtd.init"
}

src_configure() {
	local myconf=""

	## enable/disable daemon, otherwise client only utils
	myconf="${myconf} $(use_with libvirtd)"

	## enable/disable the daemon using avahi to find VMs
	myconf="${myconf} $(use_with avahi)"

	## hypervisors on the local host
	myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
	myconf+=" --without-xenapi"
	if use xen && has_version ">=app-emulation/xen-tools-4.2.0"; then
		myconf+=" --with-libxl"
	else
		myconf+=" --without-libxl"
	fi
	myconf="${myconf} $(use_with openvz)"
	myconf="${myconf} $(use_with lxc)"
	if use virtualbox && has_version app-emulation/virtualbox-ose; then
		myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
	else
		myconf="${myconf} $(use_with virtualbox vbox)"
	fi
	myconf="${myconf} $(use_with uml)"
	myconf="${myconf} $(use_with qemu)"
	myconf="${myconf} $(use_with qemu yajl)" # Use QMP over HMP
	myconf="${myconf} $(use_with phyp)"
	myconf="${myconf} --with-esx"
	myconf="${myconf} --with-vmware"

	## additional host drivers
	myconf="${myconf} $(use_with virt-network network)"
	myconf="${myconf} --with-storage-fs"
	myconf="${myconf} $(use_with lvm storage-lvm)"
	myconf="${myconf} $(use_with iscsi storage-iscsi)"
	myconf="${myconf} $(use_with parted storage-disk)"
	myconf="${myconf} $(use_with lvm storage-mpath)"
	myconf="${myconf} $(use_with rbd storage-rbd)"
	myconf="${myconf} $(use_with numa numactl)"
	myconf="${myconf} $(use_with numa numad)"
	myconf="${myconf} $(use_with selinux)"

	# udev for device support details
	myconf="${myconf} $(use_with udev)"

	# linux capability support so we don't need privileged accounts
	myconf="${myconf} $(use_with caps capng)"

	## auth stuff
	myconf="${myconf} $(use_with policykit polkit)"
	myconf="${myconf} $(use_with sasl)"

	# network bits
	myconf="${myconf} $(use_with macvtap)"
	myconf="${myconf} $(use_with pcap libpcap)"
	myconf="${myconf} $(use_with vepa virtualport)"
	myconf="${myconf} $(use_with firewalld)"

	## other
	myconf="${myconf} $(use_enable nls)"
	myconf="${myconf} $(use_with python)"

	# user privilege bits fir qemu/kvm
	if use caps; then
		myconf="${myconf} --with-qemu-user=qemu"
		myconf="${myconf} --with-qemu-group=qemu"
	else
		myconf="${myconf} --with-qemu-user=root"
		myconf="${myconf} --with-qemu-group=root"
	fi

	# audit support
	myconf="${myconf} $(use_with audit)"

	## stuff we don't yet support
	myconf="${myconf} --without-netcf"

	# we use udev over hal
	myconf="${myconf} --without-hal"

	# locking support
	myconf="${myconf} --without-sanlock"

	# this is a nasty trick to work around the problem in bug
	# #275073. The reason why we don't solve this properly is that
	# it'll require us to rebuild autotools (and we don't really want
	# to do that right now). The proper solution has been sent
	# upstream and should hopefully land in 0.7.7, in the mean time,
	# mime the same functionality with this.
	case ${CHOST} in
		*cygwin* | *mingw* )
			;;
		*)
			ac_cv_prog_WINDRES=no
			;;
	esac

	econf \
		${myconf} \
		--disable-static \
		--docdir=/usr/share/doc/${PF} \
		--with-remote \
		--localstatedir=/var

	if [[ ${PV} = *9999* ]]; then
		# Restore gnulib's config.sub and config.guess
		# bug #377279
		(cd .gnulib && git reset --hard > /dev/null)
	fi
}

src_test() {
	# Explicitly allow parallel build of tests
	export VIR_TEST_DEBUG=1
	HOME="${T}" emake check || die "tests failed"
}

src_install() {
	emake install \
		DESTDIR="${D}" \
		HTML_DIR=/usr/share/doc/${PF}/html \
		DOCS_DIR=/usr/share/doc/${PF}/python \
		EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
		|| die "emake install failed"

	find "${D}" -name '*.la' -delete || die

	use libvirtd || return 0
	# From here, only libvirtd-related instructions, be warned!

	newinitd "${S}/libvirtd.init" libvirtd || die
	newconfd "${FILESDIR}/libvirtd.confd-r4" libvirtd || die

	keepdir /var/lib/libvirt/images
}

pkg_preinst() {
	# we only ever want to generate this once
	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
		rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
	fi

	# We really don't want to use or support old PolicyKit cause it
	# screws with the new polkit integration
	if has_version sys-auth/policykit; then
		rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
	fi

	# Only sysctl files ending in .conf work
	mv "${D}"/etc/sysctl.d/libvirtd "${D}"/etc/sysctl.d/libvirtd.conf
}

pkg_postinst() {
	use python && python_mod_optimize libvirt.py

	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml
	fi

	# support for dropped privileges
	if use qemu; then
		fperms 0750 "${EROOT}/var/lib/libvirt/qemu"
		fperms 0750 "${EROOT}/var/cache/libvirt/qemu"
	fi

	if use caps && use qemu; then
		fowners -R qemu:qemu "${EROOT}/var/lib/libvirt/qemu"
		fowners -R qemu:qemu "${EROOT}/var/cache/libvirt/qemu"
	elif use qemu; then
		fowners -R root:root "${EROOT}/var/lib/libvirt/qemu"
		fowners -R root:root "${EROOT}/var/cache/libvirt/qemu"
	fi

	if ! use policykit; then
		elog "To allow normal users to connect to libvirtd you must change the"
		elog "unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
	fi

	use libvirtd || return 0
	# From here, only libvirtd-related instructions, be warned!

	elog
	elog "For the basic networking support (bridged and routed networks)"
	elog "you don't need any extra software. For more complex network modes"
	elog "including but not limited to NATed network, you can enable the"
	elog "'virt-network' USE flag."
	elog
	if has_version net-dns/dnsmasq; then
		ewarn "If you have a DNS server setup on your machine, you will have"
		ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
		ewarn " bind-interfaces"
		ewarn " interface or except-interface"
		ewarn
		ewarn "Otherwise you might have issues with your existing DNS server."
	fi

	if use caps && use qemu; then
		elog "libvirt will now start qemu/kvm VMs with non-root privileges."
		elog "Ensure any resources your VMs use are accessible by qemu:qemu"
	fi
}

pkg_postrm() {
	use python && python_mod_cleanup libvirt.py
}





^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.0.2-r2.ebuild ChangeLog
@ 2013-02-24 11:22 Agostino Sarubbo (ago)
  0 siblings, 0 replies; 4+ messages in thread
From: Agostino Sarubbo (ago) @ 2013-02-24 11:22 UTC (permalink / raw
  To: gentoo-commits

ago         13/02/24 11:22:03

  Modified:             libvirt-1.0.2-r2.ebuild ChangeLog
  Log:
  Stable for amd64, wrt bug #458688
  
  (Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key 7194459F)

Revision  Changes    Path
1.2                  app-emulation/libvirt/libvirt-1.0.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?r1=1.1&r2=1.2

Index: libvirt-1.0.2-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libvirt-1.0.2-r2.ebuild	19 Feb 2013 20:41:05 -0000	1.1
+++ libvirt-1.0.2-r2.ebuild	24 Feb 2013 11:22:02 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.1 2013/02/19 20:41:05 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.2 2013/02/24 11:22:02 ago Exp $
 
 EAPI=5
 
@@ -26,7 +26,7 @@
 		ftp://libvirt.org/libvirt/${MY_P}.tar.gz
 		${BACKPORTS:+
 			http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="amd64 ~x86"
 fi
 S="${WORKDIR}/${P%_rc*}"
 



1.249                app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.249&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.249&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.248&r2=1.249

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.248
retrieving revision 1.249
diff -u -r1.248 -r1.249
--- ChangeLog	19 Feb 2013 20:41:05 -0000	1.248
+++ ChangeLog	24 Feb 2013 11:22:02 -0000	1.249
@@ -1,6 +1,9 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.248 2013/02/19 20:41:05 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.249 2013/02/24 11:22:02 ago Exp $
+
+  24 Feb 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.0.2-r2.ebuild:
+  Stable for amd64, wrt bug #458688
 
 *libvirt-1.0.2-r2 (19 Feb 2013)
 





^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.0.2-r2.ebuild ChangeLog
@ 2013-02-24 11:29 Agostino Sarubbo (ago)
  0 siblings, 0 replies; 4+ messages in thread
From: Agostino Sarubbo (ago) @ 2013-02-24 11:29 UTC (permalink / raw
  To: gentoo-commits

ago         13/02/24 11:29:50

  Modified:             libvirt-1.0.2-r2.ebuild ChangeLog
  Log:
  Stable for x86, wrt bug #458688
  
  (Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key 7194459F)

Revision  Changes    Path
1.3                  app-emulation/libvirt/libvirt-1.0.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?r1=1.2&r2=1.3

Index: libvirt-1.0.2-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- libvirt-1.0.2-r2.ebuild	24 Feb 2013 11:22:02 -0000	1.2
+++ libvirt-1.0.2-r2.ebuild	24 Feb 2013 11:29:50 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.2 2013/02/24 11:22:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.3 2013/02/24 11:29:50 ago Exp $
 
 EAPI=5
 
@@ -26,7 +26,7 @@
 		ftp://libvirt.org/libvirt/${MY_P}.tar.gz
 		${BACKPORTS:+
 			http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
-	KEYWORDS="amd64 ~x86"
+	KEYWORDS="amd64 x86"
 fi
 S="${WORKDIR}/${P%_rc*}"
 



1.250                app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.250&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.250&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.249&r2=1.250

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.249
retrieving revision 1.250
diff -u -r1.249 -r1.250
--- ChangeLog	24 Feb 2013 11:22:02 -0000	1.249
+++ ChangeLog	24 Feb 2013 11:29:50 -0000	1.250
@@ -1,6 +1,9 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.249 2013/02/24 11:22:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.250 2013/02/24 11:29:50 ago Exp $
+
+  24 Feb 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.0.2-r2.ebuild:
+  Stable for x86, wrt bug #458688
 
   24 Feb 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.0.2-r2.ebuild:
   Stable for amd64, wrt bug #458688





^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.0.2-r2.ebuild ChangeLog
@ 2013-03-07 22:39 Doug Goldstein (cardoe)
  0 siblings, 0 replies; 4+ messages in thread
From: Doug Goldstein (cardoe) @ 2013-03-07 22:39 UTC (permalink / raw
  To: gentoo-commits

cardoe      13/03/07 22:39:00

  Modified:             libvirt-1.0.2-r2.ebuild ChangeLog
  Log:
  Backport USE=fuse to prevent automagical depend on sys-fs/fuse.
  
  (Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key D7DFA8D318FA9AEF!)

Revision  Changes    Path
1.4                  app-emulation/libvirt/libvirt-1.0.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild?r1=1.3&r2=1.4

Index: libvirt-1.0.2-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- libvirt-1.0.2-r2.ebuild	24 Feb 2013 11:29:50 -0000	1.3
+++ libvirt-1.0.2-r2.ebuild	7 Mar 2013 22:38:59 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.3 2013/02/24 11:29:50 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.0.2-r2.ebuild,v 1.4 2013/03/07 22:38:59 cardoe Exp $
 
 EAPI=5
 
@@ -34,7 +34,7 @@
 HOMEPAGE="http://www.libvirt.org/"
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="audit avahi +caps firewalld iscsi +libvirtd lvm +lxc +macvtap nfs \
+IUSE="audit avahi +caps firewalld fuse iscsi +libvirtd lvm +lxc +macvtap nfs \
 	nls numa openvz parted pcap phyp policykit python qemu rbd sasl \
 	selinux +udev uml +vepa virtualbox virt-network xen elibc_glibc"
 REQUIRED_USE="libvirtd? ( || ( lxc openvz qemu uml virtualbox xen ) )
@@ -69,6 +69,7 @@
 	audit? ( sys-process/audit )
 	avahi? ( >=net-dns/avahi-0.6[dbus] )
 	caps? ( sys-libs/libcap-ng )
+	fuse? ( >=sys-fs/fuse-2.8.6 )
 	iscsi? ( sys-block/open-iscsi )
 	lxc? ( sys-power/pm-utils )
 	lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
@@ -164,6 +165,7 @@
 						LXC_CONFIG_CHECK+=" ~MEMCG"
 
 	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+=" ~FUSE_FS"
 	use lxc && CONFIG_CHECK+="${LXC_CONFIG_CHECK}"
 	use macvtap && CONFIG_CHECK+="${MACVTAP}"
 	use virt-network && CONFIG_CHECK+="${VIRTNET_CONFIG_CHECK}"
@@ -253,6 +255,7 @@
 	myconf="${myconf} $(use_with numa numactl)"
 	myconf="${myconf} $(use_with numa numad)"
 	myconf="${myconf} $(use_with selinux)"
+	myconf="${myconf} $(use_with fuse)"
 
 	# udev for device support details
 	myconf="${myconf} $(use_with udev)"



1.255                app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.255&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.255&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.254&r2=1.255

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.254
retrieving revision 1.255
diff -u -r1.254 -r1.255
--- ChangeLog	7 Mar 2013 22:36:55 -0000	1.254
+++ ChangeLog	7 Mar 2013 22:38:59 -0000	1.255
@@ -1,6 +1,9 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.254 2013/03/07 22:36:55 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.255 2013/03/07 22:38:59 cardoe Exp $
+
+  07 Mar 2013; Doug Goldstein <cardoe@gentoo.org> libvirt-1.0.2-r2.ebuild:
+  Backport USE=fuse to prevent automagical depend on sys-fs/fuse.
 
   07 Mar 2013; Doug Goldstein <cardoe@gentoo.org> -libvirt-0.10.2.1.ebuild,
   -libvirt-0.10.2.2.ebuild, -libvirt-1.0.1.ebuild:





^ permalink raw reply	[flat|nested] 4+ messages in thread
end of thread, other threads:[~2013-03-07 22:39 UTC | newest]

Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-02-24 11:29 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.0.2-r2.ebuild ChangeLog Agostino Sarubbo (ago)
  -- strict thread matches above, loose matches on Subject: below --
2013-03-07 22:39 Doug Goldstein (cardoe)
2013-02-24 11:22 Agostino Sarubbo (ago)
2013-02-19 20:41 Doug Goldstein (cardoe)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox