[gentoo-commits] gentoo-x86 commit in net-misc/badvpn: ChangeLog badvpn-1.999.127.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/badvpn: ChangeLog badvpn-1.999.127.ebuild

[Julian Ospald (hasufell)]

hasufell    13/02/21 15:43:14

  Modified:             ChangeLog
  Added:                badvpn-1.999.127.ebuild
  Log:
  version bump by Ambroz Bizjak wrt #454476
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.11                 net-misc/badvpn/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	26 Dec 2012 02:22:00 -0000	1.10
+++ ChangeLog	21 Feb 2013 15:43:14 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/badvpn
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.10 2012/12/26 02:22:00 hasufell Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.11 2013/02/21 15:43:14 hasufell Exp $
+
+*badvpn-1.999.127 (21 Feb 2013)
+
+  21 Feb 2013; Julian Ospald <hasufell@gentoo.org> +badvpn-1.999.127.ebuild,
+  +files/badvpn-1.999.127-ncd.init, +files/badvpn-ncd.service:
+  version bump by Ambroz Bizjak wrt #454476
 
 *badvpn-1.999.126 (26 Dec 2012)
 



1.1                  net-misc/badvpn/badvpn-1.999.127.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.127.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.127.ebuild?rev=1.1&content-type=text/plain

Index: badvpn-1.999.127.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/badvpn-1.999.127.ebuild,v 1.1 2013/02/21 15:43:14 hasufell Exp $

EAPI=5
inherit eutils cmake-utils user toolchain-funcs systemd

MY_P=${PN}-${PV/_rc/rc}
DESCRIPTION="Peer-to-peer VPN, NCD scripting language, tun2socks proxifier"
HOMEPAGE="http://code.google.com/p/badvpn/"
SRC_URI="http://badvpn.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="BSD"
KEYWORDS="~amd64 ~arm ~x86"
SLOT="0"
TARGETS="+client +ncd +server +tun2socks +udpgw"
IUSE="${TARGETS} debug"
# tests are only ncd related
RESTRICT="!ncd? ( test )"

COMMON_DEPEND="
	client? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	server? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	ncd? (
		dev-libs/openssl
	)"
RDEPEND="${COMMON_DEPEND}
	ncd? (
		sys-apps/iproute2
		>=virtual/udev-171
	)"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"
# we need at least one target
REQUIRED_USE="|| ( ${TARGETS//+/} )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewuser ${PN}
}

src_prepare() {
	# allow user to easily apply patches
	epatch_user
}

src_configure() {
	local mycmakeargs=(
		-DBUILD_NOTHING_BY_DEFAULT=1
		$(cmake-utils_use_build client CLIENT)
		$(cmake-utils_use_build server SERVER)
		$(cmake-utils_use_build ncd NCD)
		$(cmake-utils_use_build tun2socks TUN2SOCKS)
		$(cmake-utils_use_build udpgw UDPGW)
	)

	cmake-utils_src_configure
}

src_test() {
	# OOHMSA: do this on portage level?
	tc-is-cross-compiler && die "these tests do not work when cross compiling!"

	einfo "Running NCD tests"
	cd "${S}"/ncd/tests || die
	bash ./run_tests "${CMAKE_BUILD_DIR}/ncd/badvpn-ncd" \
		|| die "one or more tests failed"
}

src_install() {
	cmake-utils_src_install
	dodoc ChangeLog

	if use server; then
		newinitd "${FILESDIR}"/${PN}-server.init ${PN}-server
		newconfd "${FILESDIR}"/${PN}-server.conf ${PN}-server
	fi

	if use ncd; then
		newinitd "${FILESDIR}"/${P}-ncd.init ${PN}-ncd
		newconfd "${FILESDIR}"/${PN}-ncd.conf ${PN}-ncd
		systemd_dounit "${FILESDIR}"/badvpn-ncd.service
	fi
}