[gentoo-commits] gentoo-x86 commit in app-office/openerp: openerp-7.0.20130219-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-office/openerp: openerp-7.0.20130219-r1.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     13/02/19 09:45:54

  Modified:             ChangeLog
  Added:                openerp-7.0.20130219-r1.ebuild
  Log:
  Fixing for /run migration
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.5                  app-office/openerp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/openerp/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/openerp/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/openerp/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/openerp/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	19 Feb 2013 09:31:41 -0000	1.4
+++ ChangeLog	19 Feb 2013 09:45:53 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/openerp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/openerp/ChangeLog,v 1.4 2013/02/19 09:31:41 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/openerp/ChangeLog,v 1.5 2013/02/19 09:45:53 patrick Exp $
+
+*openerp-7.0.20130219-r1 (19 Feb 2013)
+
+  19 Feb 2013; Patrick Lauer <patrick@gentoo.org> +files/openerp-2,
+  +files/openerp-confd-2, +openerp-7.0.20130219-r1.ebuild:
+  Fixing for /run migration
 
 *openerp-7.0.20130219 (19 Feb 2013)
 



1.1                  app-office/openerp/openerp-7.0.20130219-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/openerp/openerp-7.0.20130219-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/openerp/openerp-7.0.20130219-r1.ebuild?rev=1.1&content-type=text/plain

Index: openerp-7.0.20130219-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/openerp/openerp-7.0.20130219-r1.ebuild,v 1.1 2013/02/19 09:45:53 patrick Exp $

EAPI="3"
PYTHON_DEPEND="2"

inherit eutils distutils user

DESCRIPTION="Open Source ERP & CRM"
HOMEPAGE="http://www.openerp.com/"
#yes, this is definitely a horrible URI
MY_PV=${PV/7.0./7.0-}
FNAME="${PN}-${MY_PV}-002614"
SRC_URI="http://nightly.openerp.com/7.0/nightly/src/${FNAME}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="+postgres ldap ssl"

CDEPEND="postgres? ( dev-db/postgresql-server )
	dev-python/psutil
	dev-python/docutils
	dev-python/lxml
	dev-python/psycopg:2
	dev-python/pychart
	dev-python/reportlab
	media-gfx/pydot
	dev-python/vobject
	dev-python/mako
	dev-python/pyyaml
	dev-python/Babel
	dev-python/gdata
	ldap? ( dev-python/python-ldap )
	dev-python/python-openid
	dev-python/werkzeug
	dev-python/xlwt
	dev-python/feedparser
	dev-python/python-dateutil
	dev-python/pywebdav
	ssl? ( dev-python/pyopenssl )
	dev-python/vatnumber
	dev-python/zsi
	dev-python/mock
	dev-python/unittest2"

RDEPEND="${CDEPEND}"
DEPEND="${CDEPEND}"

OPENERP_USER="openerp"
OPENERP_GROUP="openerp"

S="${WORKDIR}/${FNAME}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_install() {
	distutils_src_install

	doinitd "${FILESDIR}/${PN}-2"
	newconfd "${FILESDIR}/openerp-confd-2" "${PN}"
	keepdir /var/log/openerp

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/openerp.logrotate openerp || die
	dodir /etc/openerp
	insinto /etc/openerp
	newins "${FILESDIR}"/openerp.cfg openerp.cfg || die
}

pkg_preinst() {
	enewgroup ${OPENERP_GROUP}
	enewuser ${OPENERP_USER} -1 -1 -1 ${OPENERP_GROUP}

	fowners ${OPENERP_USER}:${OPENERP_GROUP} /var/log/openerp
	fowners -R ${OPENERP_USER}:${OPENERP_GROUP} "$(python_get_sitedir)/${PN}/addons/"

	use postgres || sed -i '6,8d' "${D}/etc/init.d/openerp" || die "sed failed"
}

pkg_postinst() {
	chown ${OPENERP_USER}:${OPENERP_GROUP} /var/log/openerp
	chown -R ${OPENERP_USER}:${OPENERP_GROUP} "$(python_get_sitedir)/${PN}/addons/"

	elog "In order to setup the initial database, run:"
	elog " emerge --config =${CATEGORY}/${PF}"
	elog "Be sure the database is started before"
}

psqlquery() {
	psql -q -At -U postgres -d template1 -c "$@"
}

pkg_config() {
	einfo "In the following, the 'postgres' user will be used."
	if ! psqlquery "SELECT usename FROM pg_user WHERE usename = '${OPENERP_USER}'" | grep -q ${OPENERP_USER}; then
		ebegin "Creating database user ${OPENERP_USER}"
		createuser --username=postgres --createdb --no-adduser ${OPENERP_USER}
		eend $? || die "Failed to create database user"
	fi
}