From: "Julian Ospald (hasufell)" <hasufell@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.3.4.ebuild
Date: Sat, 16 Feb 2013 22:27:27 +0000 (UTC) [thread overview]
Message-ID: <20130216222727.EE4292171D@flycatcher.gentoo.org> (raw)
hasufell 13/02/16 22:27:27
Modified: ChangeLog
Added: freeciv-2.3.4.ebuild
Log:
version bump
(Portage version: 2.2.0_alpha162/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
Revision Changes Path
1.143 games-strategy/freeciv/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/ChangeLog?r1=1.142&r2=1.143
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog 30 Jan 2013 18:47:10 -0000 1.142
+++ ChangeLog 16 Feb 2013 22:27:27 -0000 1.143
@@ -1,6 +1,11 @@
# ChangeLog for games-strategy/freeciv
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.142 2013/01/30 18:47:10 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.143 2013/02/16 22:27:27 hasufell Exp $
+
+*freeciv-2.3.4 (16 Feb 2013)
+
+ 16 Feb 2013; Julian Ospald <hasufell@gentoo.org> +freeciv-2.3.4.ebuild:
+ version bump
30 Jan 2013; Michael Sterrett <mr_bones_@gentoo.org>
-files/freeciv-2.3.2-clean-man.patch, -freeciv-2.3.2.ebuild:
1.1 games-strategy/freeciv/freeciv-2.3.4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/freeciv-2.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/freeciv/freeciv-2.3.4.ebuild?rev=1.1&content-type=text/plain
Index: freeciv-2.3.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/freeciv-2.3.4.ebuild,v 1.1 2013/02/16 22:27:27 hasufell Exp $
EAPI=5
inherit eutils gnome2-utils games-ggz games
DESCRIPTION="multiplayer strategy game (Civilization Clone)"
HOMEPAGE="http://www.freeciv.org/"
SRC_URI="mirror://sourceforge/freeciv/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="auth dedicated ggz +gtk ipv6 nls readline sdl +sound"
REQUIRED_USE="|| ( gtk sdl )"
RDEPEND="readline? ( sys-libs/readline )
sys-libs/zlib
app-arch/bzip2
auth? ( virtual/mysql )
!dedicated? (
nls? ( virtual/libintl )
gtk? ( x11-libs/gtk+:2 )
sdl? (
media-libs/libsdl[video]
media-libs/sdl-image[png]
media-libs/freetype:2
)
sound? (
media-libs/libsdl[audio]
media-libs/sdl-mixer[vorbis]
)
ggz? ( games-board/ggz-gtk-client )
media-libs/libpng:0
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
!dedicated? (
nls? ( sys-devel/gettext )
x11-proto/xextproto
)"
src_prepare() {
# install the .desktop in /usr/share/applications
# install the icons in /usr/share/pixmaps
sed -i \
-e 's:^.*\(desktopfiledir = \).*:\1/usr/share/applications:' \
-e 's:^\(icon[0-9]*dir = \)$(prefix)\(.*\):\1/usr\2:' \
-e 's:^\(icon[0-9]*dir = \)$(datadir)\(.*\):\1/usr/share\2:' \
client/Makefile.in \
server/Makefile.in \
modinst/Makefile.in \
data/Makefile.in \
data/icons/Makefile.in \
|| die
}
src_configure() {
local myclient myopts
if use dedicated ; then
myclient="no"
else
use sdl && myclient="${myclient} sdl"
use gtk && myclient="${myclient} gtk"
myopts=$(use_with ggz ggz-client)
fi
egamesconf \
--localedir=/usr/share/locale \
--with-ggzconfig=/usr/bin \
--enable-noregistry="${GGZ_MODDIR}" \
$(use_enable auth) \
$(use_enable ipv6) \
$(use_enable nls) \
$(use_with readline) \
$(use_enable sound sdl-mixer) \
${myopts} \
--enable-client="${myclient}"
}
src_install() {
emake DESTDIR="${D}" install
if use dedicated ; then
rm -rf "${D}/usr/share/pixmaps"
rm -f "${D}"/usr/share/man/man6/freeciv-{client,gtk2,sdl,xaw}*
else
# Create and install the html manual. It can't be done for dedicated
# servers, because the 'freeciv-manual' tool is then not built. Also
# delete freeciv-manual from the GAMES_BINDIR, because it's useless.
# Note: to have it localized, it should be ran from _postinst, or
# something like that, but then it's a PITA to avoid orphan files...
./manual/freeciv-manual || die
dohtml manual*.html
if use sdl ; then
make_desktop_entry freeciv-sdl "Freeciv (SDL)" freeciv-client
else
rm -f "${D}"/usr/share/man/man6/freeciv-sdl*
fi
rm -f "${D}"/usr/share/man/man6/freeciv-xaw*
fi
find "${D}" -name "freeciv-manual*" -delete
dodoc ChangeLog NEWS doc/{BUGS,CodingStyle,HACKING,HOWTOPLAY,README*,TODO}
rm -rf "${D}$(games_get_libdir)"
prepgamesdirs
}
pkg_preinst() {
games_pkg_preinst
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
games-ggz_update_modules
gnome2_icon_cache_update
}
pkg_postrm() {
games-ggz_update_modules
gnome2_icon_cache_update
}
next reply other threads:[~2013-02-16 22:27 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2013-02-16 22:27 Julian Ospald (hasufell) [this message]
-- strict thread matches above, loose matches on Subject: below --
2013-03-31 16:16 [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.3.4.ebuild Jeff Horelick (jdhore)
2014-05-15 17:03 Ulrich Mueller (ulm)
2015-03-26 17:52 Michael Sterrett (mr_bones_)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20130216222727.EE4292171D@flycatcher.gentoo.org \
--to=hasufell@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox