[gentoo-commits] gentoo-x86 commit in sys-kernel/aufs-sources: ChangeLog aufs-sources-3.7.7.ebuild

[gentoo-commits] gentoo-x86 commit in sys-kernel/aufs-sources: ChangeLog aufs-sources-3.7.7.ebuild

[Justin Lecher (jlec)]

jlec        13/02/13 08:48:08

  Modified:             ChangeLog
  Added:                aufs-sources-3.7.7.ebuild
  Log:
  sys-kernel/aufs-sources: Bump to Linux-3.7.7
  
  (Portage version: 2.2.0_alpha162/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.15                 sys-kernel/aufs-sources/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/aufs-sources/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/aufs-sources/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/aufs-sources/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	7 Feb 2013 08:08:48 -0000	1.14
+++ ChangeLog	13 Feb 2013 08:48:08 -0000	1.15
@@ -1,6 +1,11 @@
 # ChangeLog for sys-kernel/aufs-sources
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.14 2013/02/07 08:08:48 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.15 2013/02/13 08:48:08 jlec Exp $
+
+*aufs-sources-3.7.7 (13 Feb 2013)
+
+  13 Feb 2013; Justin Lecher <jlec@gentoo.org> +aufs-sources-3.7.7.ebuild:
+  Bump to Linux-3.7.7
 
 *aufs-sources-3.7.6 (07 Feb 2013)
 



1.1                  sys-kernel/aufs-sources/aufs-sources-3.7.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/aufs-sources/aufs-sources-3.7.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/aufs-sources/aufs-sources-3.7.7.ebuild?rev=1.1&content-type=text/plain

Index: aufs-sources-3.7.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/aufs-sources-3.7.7.ebuild,v 1.1 2013/02/13 08:48:08 jlec Exp $

EAPI=5

ETYPE="sources"
K_WANT_GENPATCHES="base extras"
K_GENPATCHES_VER="9"
K_DEBLOB_AVAILABLE="1"
inherit kernel-2 eutils
detect_version
detect_arch

AUFS_VERSION=3.7.6
AUFS_TARBALL="aufs-sources-${AUFS_VERSION}.tar.xz"
# git archive -v --remote=git://aufs.git.sourceforge.net/gitroot/aufs/aufs3-standalone.git aufs3.7 > ${AUFS_TARBALL}
AUFS_URI="http://dev.gentoo.org/~jlec/distfiles/${AUFS_TARBALL}"

KEYWORDS="~amd64 ~x86"
HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
IUSE="deblob module proc"

DESCRIPTION="Full sources including the Gentoo patchset for the ${KV_MAJOR}.${KV_MINOR} kernel tree and aufs3 support"
SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${AUFS_URI}"

UNIPATCH_LIST="
	"${WORKDIR}"/aufs3-kbuild.patch
	"${WORKDIR}"/aufs3-base.patch"

PDEPEND=">=sys-fs/aufs-util-3.7"

src_unpack() {
	use module && UNIPATCH_LIST+=" "${WORKDIR}"/aufs3-standalone.patch"
	use proc && UNIPATCH_LIST+=" "${WORKDIR}"/aufs3-proc.patch"
	unpack ${AUFS_TARBALL}
	kernel-2_src_unpack
}

src_prepare() {
	if ! use module; then
		sed -e 's:tristate:bool:g' -i "${WORKDIR}"/fs/aufs/Kconfig || die
	fi
	if ! use proc; then
		sed '/config AUFS_PROC_MAP/,/^$/d' -i "${WORKDIR}"/fs/aufs/Kconfig || die
	fi
	cp -i "${WORKDIR}"/include/linux/aufs_type.h include/linux/aufs_type.h || die
	cp -i "${WORKDIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
	cp -ri "${WORKDIR}"/{Documentation,fs} . || die
	sed -i "s:__user::g" include/uapi/linux/aufs_type.h || die
}

pkg_postinst() {
	kernel-2_pkg_postinst
	einfo "For more info on this patchset, and how to report problems, see:"
	einfo "${HOMEPAGE}"
	if ! has_version sys-fs/aufs-util; then
		einfo "In order to use aufs FS you need to install sys-fs/aufs-util"
	fi
}

pkg_postrm() {
	kernel-2_pkg_postrm
}