[gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: ChangeLog gstreamer-1.0.5-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: ChangeLog gstreamer-1.0.5-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    13/02/12 04:23:08

  Modified:             ChangeLog
  Added:                gstreamer-1.0.5-r1.ebuild
  Log:
  Remove .la files (bug #456164, thanks to Paolo Pedroni).
  
  (Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.329                media-libs/gstreamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.329&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.329&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?r1=1.328&r2=1.329

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v
retrieving revision 1.328
retrieving revision 1.329
diff -u -r1.328 -r1.329
--- ChangeLog	10 Feb 2013 22:27:02 -0000	1.328
+++ ChangeLog	12 Feb 2013 04:23:08 -0000	1.329
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.328 2013/02/10 22:27:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.329 2013/02/12 04:23:08 tetromino Exp $
+
+*gstreamer-1.0.5-r1 (12 Feb 2013)
+
+  12 Feb 2013; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +gstreamer-1.0.5-r1.ebuild:
+  Remove .la files (bug #456164, thanks to Paolo Pedroni).
 
   10 Feb 2013; Agostino Sarubbo <ago@gentoo.org> gstreamer-0.10.36.ebuild:
   Stable for sparc, wrt bug #454906



1.1                  media-libs/gstreamer/gstreamer-1.0.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.0.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.0.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: gstreamer-1.0.5-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-1.0.5-r1.ebuild,v 1.1 2013/02/12 04:23:08 tetromino Exp $

EAPI="5"

inherit eutils multilib pax-utils

DESCRIPTION="Streaming media framework"
HOMEPAGE="http://gstreamer.freedesktop.org/"
SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"

LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+introspection nls +orc test"

RDEPEND="
	>=dev-libs/glib-2.32:2
	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=dev-util/gtk-doc-am-1.12
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
"
# gtk-doc-am to install API docs

src_configure() {
	if [[ ${CHOST} == *-interix* ]] ; then
		export ac_cv_lib_dl_dladdr=no
		export ac_cv_func_poll=no
	fi
	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
		# GCC groks this, but then refers to an implementation (___multi3,
		# ___udivti3) that don't exist (at least I can't find it), so force
		# this one to be off, such that we use 2x64bit emulation code.
		export gst_cv_uint128_t=no
	fi

	# Disable static archives, dependency tracking and examples
	# to speed up build time
	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
	econf \
		--disable-debug \
		--disable-examples \
		--disable-static \
		--disable-valgrind \
		--enable-check \
		$(use_enable introspection) \
		$(use_enable nls) \
		$(use_enable test tests) \
		--with-package-name="GStreamer ebuild for Gentoo" \
		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
}

src_install() {
	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
	default
	prune_libtool_files --modules

	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
		"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
}