[gentoo-commits] gentoo-x86 commit in net-misc/electrum: electrum-1.6.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/electrum: electrum-1.6.2.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    13/02/12 02:48:50

  Modified:             ChangeLog
  Added:                electrum-1.6.2.ebuild
  Log:
  Version bump, bug #452932
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.2                  net-misc/electrum/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/electrum/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/electrum/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/electrum/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/electrum/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	16 Sep 2012 20:45:21 -0000	1.1
+++ ChangeLog	12 Feb 2013 02:48:50 -0000	1.2
@@ -1,10 +1,14 @@
 # ChangeLog for net-misc/electrum
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/electrum/ChangeLog,v 1.1 2012/09/16 20:45:21 blueness Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/electrum/ChangeLog,v 1.2 2013/02/12 02:48:50 blueness Exp $
+
+*electrum-1.6.2 (12 Feb 2013)
+
+  12 Feb 2013; Anthony G. Basile <blueness@gentoo.org> +electrum-1.6.2.ebuild:
+  Version bump, bug #452932
 
 *electrum-1.0 (16 Sep 2012)
 
   16 Sep 2012; Anthony G. Basile <blueness@gentoo.org> +electrum-1.0.ebuild,
   +metadata.xml:
   Initial commit
-



1.1                  net-misc/electrum/electrum-1.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/electrum/electrum-1.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/electrum/electrum-1.6.2.ebuild?rev=1.1&content-type=text/plain

Index: electrum-1.6.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/electrum/electrum-1.6.2.ebuild,v 1.1 2013/02/12 02:48:50 blueness Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )

inherit eutils distutils-r1 gnome2-utils

MY_P=Electrum-${PV}
DESCRIPTION="User friendly Bitcoin client"
HOMEPAGE="http://electrum.org/"
SRC_URI="http://download.electrum.org/download/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk qt4"
REQUIRED_USE="|| ( gtk qt4 )"

LANGS="br cs de eo es fr it lv nl ru sl vi zh"

for X in ${LANGS}; do
	IUSE+=" linguas_${X}"
done
unset X

RDEPEND="
	dev-python/setuptools
	dev-python/ecdsa
	dev-python/slowaes
	gtk? ( dev-python/pygtk:2 )
	qt4? ( dev-python/PyQt4 )"

S=${WORKDIR}/${MY_P}

DOCS="RELEASE-NOTES"

src_prepare() {
	# Prevent icon from being installed in the wrong location:
	sed -i '/electrum\.png/ d' setup.py || die
	sed -i "s:^Icon=.*:Icon=${PN}:" "${PN}.desktop" || die

	# Remove unrequested localization files:
	local lang
	for lang in ${LANGS#en}; do
		if use linguas_$lang; then
			test -f "locale/$lang/LC_MESSAGES/${PN}.mo" || die
		else
			rm -r "locale/$lang" || die
		fi
	done

	# Remove unrequested GUI implementations:
	if use !gtk; then
		rm lib/gui.py || die
	fi
	if use !qt4; then
		rm lib/gui_qt.py lib/gui_lite.py || die
		sed -i 's/default="lite"/default="gtk"/' electrum || die
	fi

	distutils-r1_src_prepare
}

src_install() {
	doicon -s 64 icons/${PN}.png
	distutils-r1_src_install
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}