[gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: ChangeLog plasma-workspace-4.10.0-r1.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: ChangeLog plasma-workspace-4.10.0-r1.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    13/02/08 20:30:09

  Modified:             ChangeLog
  Added:                plasma-workspace-4.10.0-r1.ebuild
  Log:
  Add workaround patch for plasma-workspace crash, see bug 450818 and kde bug 311751 comments 2 and 32.
  
  (Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key B6C5F7DE)

Revision  Changes    Path
1.195                kde-base/plasma-workspace/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.195&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.195&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?r1=1.194&r2=1.195

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v
retrieving revision 1.194
retrieving revision 1.195
diff -u -r1.194 -r1.195
--- ChangeLog	7 Feb 2013 04:57:24 -0000	1.194
+++ ChangeLog	8 Feb 2013 20:30:09 -0000	1.195
@@ -1,6 +1,14 @@
 # ChangeLog for kde-base/plasma-workspace
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.194 2013/02/07 04:57:24 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.195 2013/02/08 20:30:09 dilfridge Exp $
+
+*plasma-workspace-4.10.0-r1 (08 Feb 2013)
+
+  08 Feb 2013; Andreas K. Huettel <dilfridge@gentoo.org>
+  +plasma-workspace-4.10.0-r1.ebuild,
+  +files/plasma-workspace-4.10.0-norepeater.patch:
+  Add workaround patch for plasma-workspace crash, see bug 450818 and kde bug
+  311751 comments 2 and 32.
 
 *plasma-workspace-4.10.0 (06 Feb 2013)
 



1.1                  kde-base/plasma-workspace/plasma-workspace-4.10.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: plasma-workspace-4.10.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.0-r1.ebuild,v 1.1 2013/02/08 20:30:09 dilfridge Exp $

EAPI=5

DECLARATIVE_REQUIRED="always"
KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
KMMODULE="plasma"
PYTHON_DEPEND="python? 2"
OPENGL_REQUIRED="always"
inherit python kde4-meta

DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug google-gadgets gps json python qalculate +rss semantic-desktop"

COMMONDEPEND="
	dev-libs/libdbusmenu-qt
	!kde-misc/ktouchpadenabler
	$(add_kdebase_dep kactivities)
	$(add_kdebase_dep kdelibs 'semantic-desktop=')
	$(add_kdebase_dep kephal)
	$(add_kdebase_dep ksysguard)
	$(add_kdebase_dep libkworkspace)
	$(add_kdebase_dep libplasmagenericshell)
	$(add_kdebase_dep libtaskmanager)
	$(add_kdebase_dep solid)
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXfixes
	x11-libs/libXrender
	google-gadgets? ( >=x11-misc/google-gadgets-0.11.0[qt4] )
	gps? ( >=sci-geosciences/gpsd-2.37 )
	json? ( dev-libs/qjson )
	python? (
		>=dev-python/PyQt4-4.4.0[X]
		$(add_kdebase_dep pykde4)
	)
	qalculate? ( sci-libs/libqalculate )
	rss? (
		$(add_kdebase_dep kdepimlibs 'semantic-desktop=')
		$(add_kdebase_dep libplasmaclock 'holidays')
	)
	!rss? ( $(add_kdebase_dep libplasmaclock '-holidays') )
	semantic-desktop? (
		dev-libs/soprano
		$(add_kdebase_dep nepomuk-core)
	)
"
DEPEND="${COMMONDEPEND}
	rss? ( dev-libs/boost )
	x11-proto/compositeproto
	x11-proto/damageproto
	x11-proto/fixesproto
	x11-proto/renderproto
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep plasma-runtime)
"

PATCHES=( "${FILESDIR}/${P}"-norepeater.patch )

KMEXTRA="
	appmenu/
	ktouchpadenabler/
	statusnotifierwatcher/
"
KMEXTRACTONLY="
	kcheckpass/
	krunner/dbus/org.freedesktop.ScreenSaver.xml
	krunner/dbus/org.kde.krunner.App.xml
	ksmserver/org.kde.KSMServerInterface.xml
	ksmserver/screenlocker/
	libs/kephal/
	libs/kworkspace/
	libs/taskmanager/
	libs/plasmagenericshell/
	libs/ksysguard/
	libs/kdm/kgreeterplugin.h
	ksysguard/
"

KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"

pkg_setup() {
	if use python ; then
		python_set_active_version 2
		python_pkg_setup
	fi
	kde4-meta_pkg_setup
}

src_unpack() {
	if use handbook; then
		KMEXTRA+=" doc/plasma-desktop"
	fi

	kde4-meta_src_unpack
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with google-gadgets Googlegadgets)
		$(cmake-utils_use_with gps libgps)
		$(cmake-utils_use_with json QJSON)
		$(cmake-utils_use_with python PythonLibrary)
		$(cmake-utils_use_with qalculate)
		$(cmake-utils_use_with rss KdepimLibs)
		$(cmake-utils_use_with semantic-desktop Akonadi)
		$(cmake-utils_use_with semantic-desktop NepomukCore)
		$(cmake-utils_use_with semantic-desktop Soprano)
		-DWITH_Xmms=OFF
	)

	kde4-meta_src_configure
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	if use python; then
		python_mod_optimize \
			PyKDE4/plasmascript.py \
			/usr/share/apps/plasma_scriptengine_python
	fi
}

pkg_postrm() {
	kde4-meta_pkg_postrm

	if use python; then
		python_mod_cleanup \
			PyKDE4/plasmascript.py \
			/usr/share/apps/plasma_scriptengine_python
	fi
}