* [gentoo-commits] gentoo-x86 commit in dev-games/openscenegraph: ChangeLog openscenegraph-3.0.1-r1.ebuild openscenegraph-3.0.1.ebuild
@ 2013-02-07 23:14 Maciej Mrozowski (reavertm)
0 siblings, 0 replies; only message in thread
From: Maciej Mrozowski (reavertm) @ 2013-02-07 23:14 UTC (permalink / raw
To: gentoo-commits
reavertm 13/02/07 23:14:45
Modified: ChangeLog
Added: openscenegraph-3.0.1-r1.ebuild
Removed: openscenegraph-3.0.1.ebuild
Log:
Build shared libs exclusively, bug 448050. Remove related pkg_postinst message.
(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key B1E955DB)
Revision Changes Path
1.52 dev-games/openscenegraph/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/openscenegraph/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/openscenegraph/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/openscenegraph/ChangeLog?r1=1.51&r2=1.52
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/openscenegraph/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog 14 Jul 2012 16:22:56 -0000 1.51
+++ ChangeLog 7 Feb 2013 23:14:45 -0000 1.52
@@ -1,6 +1,12 @@
# ChangeLog for dev-games/openscenegraph
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/openscenegraph/ChangeLog,v 1.51 2012/07/14 16:22:56 reavertm Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/openscenegraph/ChangeLog,v 1.52 2013/02/07 23:14:45 reavertm Exp $
+
+*openscenegraph-3.0.1-r1 (07 Feb 2013)
+
+ 07 Feb 2013; Maciej Mrozowski <reavertm@gentoo.org>
+ -openscenegraph-3.0.1.ebuild, +openscenegraph-3.0.1-r1.ebuild:
+ Build shared libs exclusively, bug 448050.
14 Jul 2012; Maciej Mrozowski <reavertm@gentoo.org>
-files/openscenegraph-2.8.3-cmake.patch,
1.1 dev-games/openscenegraph/openscenegraph-3.0.1-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/openscenegraph/openscenegraph-3.0.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/openscenegraph/openscenegraph-3.0.1-r1.ebuild?rev=1.1&content-type=text/plain
Index: openscenegraph-3.0.1-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/openscenegraph/openscenegraph-3.0.1-r1.ebuild,v 1.1 2013/02/07 23:14:45 reavertm Exp $
EAPI=3
inherit eutils cmake-utils flag-o-matic wxwidgets
MY_PN="OpenSceneGraph"
MY_P=${MY_PN}-${PV}
DESCRIPTION="Open source high performance 3D graphics toolkit"
HOMEPAGE="http://www.openscenegraph.org/projects/osg/"
SRC_URI="http://www.openscenegraph.org/downloads/stable_releases/${MY_P}/source/${MY_P}.zip"
LICENSE="wxWinLL-3 LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="curl debug doc examples ffmpeg fltk fox gdal gif glut gtk itk jpeg jpeg2k
openexr openinventor osgapps pdf png qt4 sdl svg tiff truetype vnc wxwidgets xine xrandr zlib"
# NOTE: OpenAL (support missing)
# TODO: COLLADA, FBX, OpenVRML, Performer, DCMTK
RDEPEND="
x11-libs/libSM
x11-libs/libXext
virtual/glu
virtual/opengl
curl? ( net-misc/curl )
examples? (
fltk? ( x11-libs/fltk:1[opengl] )
fox? ( x11-libs/fox:1.6[opengl] )
glut? ( media-libs/freeglut )
gtk? ( x11-libs/gtkglext )
qt4? (
x11-libs/qt-core:4
x11-libs/qt-gui:4
x11-libs/qt-opengl:4
)
sdl? ( media-libs/libsdl )
wxwidgets? ( x11-libs/wxGTK[opengl,X] )
)
ffmpeg? ( virtual/ffmpeg )
gdal? ( sci-libs/gdal )
gif? ( media-libs/giflib )
itk? ( dev-tcltk/itk )
jpeg? ( virtual/jpeg )
jpeg2k? ( media-libs/jasper )
openexr? (
media-libs/ilmbase
media-libs/openexr
)
openinventor? (
|| (
media-libs/coin
media-libs/openinventor
)
)
pdf? ( app-text/poppler[cairo] )
png? ( media-libs/libpng:0 )
svg? (
gnome-base/librsvg
x11-libs/cairo
)
tiff? ( media-libs/tiff:0 )
truetype? ( media-libs/freetype:2 )
vnc? ( net-libs/libvncserver )
xine? ( media-libs/xine-lib )
xrandr? ( x11-libs/libXrandr )
zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
app-arch/unzip
virtual/pkgconfig
x11-proto/xextproto
doc? ( app-doc/doxygen )
xrandr? ( x11-proto/randrproto )
"
S=${WORKDIR}/${MY_P}
DOCS=(AUTHORS.txt ChangeLog NEWS.txt)
PATCHES=(
"${FILESDIR}"/${PN}-3.0.1-cmake.patch
"${FILESDIR}"/${PN}-3.0.1-libav-0.7.patch
"${FILESDIR}"/${PN}-3.0.1-xinelib12x.patch
)
src_configure() {
if use examples && use wxwidgets; then
WX_GTK_VER="2.8"
need-wxwidgets unicode
fi
# Needed by FFmpeg
append-cppflags -D__STDC_CONSTANT_MACROS
mycmakeargs=(
-DDYNAMIC_OPENSCENEGRAPH=ON
-DWITH_OpenAL=OFF # Commented out in buildsystem
-DGENTOO_DOCDIR="/usr/share/doc/${PF}"
$(cmake-utils_use_with curl)
$(cmake-utils_use_build doc DOCUMENTATION)
$(cmake-utils_use_build osgapps OSG_APPLICATIONS)
$(cmake-utils_use_build examples OSG_EXAMPLES)
$(cmake-utils_use_with ffmpeg FFmpeg)
$(cmake-utils_use_with fltk)
$(cmake-utils_use_with fox)
$(cmake-utils_use_with gdal)
$(cmake-utils_use_with gif GIFLIB)
$(cmake-utils_use_with glut)
$(cmake-utils_use_with gtk GtkGl)
$(cmake-utils_use_with itk)
$(cmake-utils_use_with jpeg)
$(cmake-utils_use_with jpeg2k Jasper)
$(cmake-utils_use_with openexr OpenEXR)
$(cmake-utils_use_with openinventor Inventor)
$(cmake-utils_use_with pdf Poppler-glib)
$(cmake-utils_use_with png)
$(cmake-utils_use_with qt4)
$(cmake-utils_use_with sdl)
$(cmake-utils_use_with svg rsvg)
$(cmake-utils_use_with tiff)
$(cmake-utils_use_with truetype FreeType)
$(cmake-utils_use_with vnc LibVNCServer)
$(cmake-utils_use_with wxwidgets wxWidgets)
$(cmake-utils_use_with xine)
$(cmake-utils_use xrandr OSGVIEWER_USE_XRANDR)
$(cmake-utils_use_with zlib)
)
cmake-utils_src_configure
}
src_compile() {
cmake-utils_src_compile
use doc && cmake-utils_src_compile doc_openscenegraph doc_openthreads
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-02-07 23:14 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-02-07 23:14 [gentoo-commits] gentoo-x86 commit in dev-games/openscenegraph: ChangeLog openscenegraph-3.0.1-r1.ebuild openscenegraph-3.0.1.ebuild Maciej Mrozowski (reavertm)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox