[gentoo-commits] gentoo-x86 commit in dev-util/monkeystudio: monkeystudio-1.9.0.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-util/monkeystudio: monkeystudio-1.9.0.4.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    13/02/06 14:55:19

  Modified:             ChangeLog
  Added:                monkeystudio-1.9.0.4.ebuild
  Log:
  Version bump wrt bug #454524.
  
  (Portage version: 2.1.11.50/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

Revision  Changes    Path
1.2                  dev-util/monkeystudio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monkeystudio/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monkeystudio/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monkeystudio/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/monkeystudio/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	3 Jul 2012 17:20:33 -0000	1.1
+++ ChangeLog	6 Feb 2013 14:55:19 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/monkeystudio
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/monkeystudio/ChangeLog,v 1.1 2012/07/03 17:20:33 kensington Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/monkeystudio/ChangeLog,v 1.2 2013/02/06 14:55:19 kensington Exp $
+
+*monkeystudio-1.9.0.4 (06 Feb 2013)
+
+  06 Feb 2013; Michael Palimaka <kensington@gentoo.org>
+  +files/monkeystudio-1.9.0.4-install.patch, +monkeystudio-1.9.0.4.ebuild:
+  Version bump wrt bug #454524.
 
 *monkeystudio-1.9.0.2 (03 Jul 2012)
 



1.1                  dev-util/monkeystudio/monkeystudio-1.9.0.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monkeystudio/monkeystudio-1.9.0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monkeystudio/monkeystudio-1.9.0.4.ebuild?rev=1.1&content-type=text/plain

Index: monkeystudio-1.9.0.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monkeystudio/monkeystudio-1.9.0.4.ebuild,v 1.1 2013/02/06 14:55:19 kensington Exp $

EAPI=5
LANGS="be es fr ru"

inherit qt4-r2

MY_P="mks_${PV}-src"

DESCRIPTION="A cross platform Qt 4 IDE"
HOMEPAGE="http://www.monkeystudio.org"
SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc plugins"

RDEPEND="plugins? ( >=x11-libs/qt-webkit-4.7.0:4 )
	>=x11-libs/qt-assistant-4.7.0:4
	>=x11-libs/qt-core-4.7.0:4
	>=x11-libs/qt-gui-4.7.0:4
	>=x11-libs/qt-sql-4.7.0:4
	x11-libs/qscintilla:="
DEPEND="${RDEPEND}
	doc? ( >=app-doc/doxygen-1.5.8 )"

PATCHES=( "${FILESDIR}/${P}-install.patch" )
DOCS=( ChangeLog readme.txt )

S=${WORKDIR}/${MY_P}

src_prepare() {
	# Revert upstream change designed to permit shadow building
	# which is causing build failure
	sed -e '/PACKAGE_BUILD_PATH  = $$(PWD)\/build/d' \
		-e 's/#PACKAGE_BUILD_PATH/PACKAGE_BUILD_PATH/' \
		-i config.pri || die

	rm -r qscintilla/QScintilla-gpl-snapshot \
		|| die "failed removing bundled qscintilla"

	qt4-r2_src_prepare
}

src_configure() {
	eqmake4 prefix=/usr system_qscintilla=1

	if use plugins ; then
		eqmake4 plugins/plugins.pro
	fi
}

src_install() {
	qt4-r2_src_install

	if use plugins ; then
		insinto /usr/lib64/monkeystudio
		doins -r bin/plugins/*
	fi

	insinto /usr/share/${PN}/translations
	local lang
	for lang in ${LANGS} ; do
		if use linguas_${lang} ; then
			doins datas/translations/monkeystudio_${lang}.qm
		fi
	done

	fperms 755 /usr/bin/${PN}

	if use doc ; then
		doxygen || die "doxygen failed"
		dohtml -r doc/html/*
	fi
}