[gentoo-commits] gentoo-x86 commit in games-action/powermanga: ChangeLog powermanga-0.91.ebuild

[gentoo-commits] gentoo-x86 commit in games-action/powermanga: ChangeLog powermanga-0.91.ebuild

[Julian Ospald (hasufell)]

hasufell    13/02/01 00:13:07

  Modified:             ChangeLog
  Added:                powermanga-0.91.ebuild
  Log:
  version bump wrt #452296
  
  (Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.25                 games-action/powermanga/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/powermanga/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/powermanga/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/powermanga/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-action/powermanga/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	24 Aug 2012 06:59:11 -0000	1.24
+++ ChangeLog	1 Feb 2013 00:13:06 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for games-action/powermanga
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-action/powermanga/ChangeLog,v 1.24 2012/08/24 06:59:11 mr_bones_ Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-action/powermanga/ChangeLog,v 1.25 2013/02/01 00:13:06 hasufell Exp $
+
+*powermanga-0.91 (31 Jan 2013)
+
+  31 Jan 2013; Julian Ospald <hasufell@gentoo.org> +powermanga-0.91.ebuild,
+  +files/powermanga-0.91-flags.patch, +files/powermanga-0.91-segfault.patch,
+  +files/powermanga-0.91-underlink.patch:
+  version bump wrt #452296
 
   24 Aug 2012; Michael Sterrett <mr_bones_@gentoo.org> powermanga-0.90.ebuild:
   any mod support will do



1.1                  games-action/powermanga/powermanga-0.91.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/powermanga/powermanga-0.91.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/powermanga/powermanga-0.91.ebuild?rev=1.1&content-type=text/plain

Index: powermanga-0.91.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/powermanga/powermanga-0.91.ebuild,v 1.1 2013/02/01 00:13:06 hasufell Exp $

EAPI=5
inherit eutils autotools games

DESCRIPTION="An arcade 2D shoot-em-up game"
HOMEPAGE="http://linux.tlk.fr/"
SRC_URI="http://linux.tlk.fr/games/Powermanga/download/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2[audio,joystick,video]
	media-libs/libpng:0
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXxf86dga
	media-libs/sdl-mixer[mod]"
DEPEND="${RDEPEND}"

src_prepare() {
	local f
	for f in src/assembler.S src/assembler_opt.S ; do
		einfo "patching $f"
		cat <<-EOF >> ${f}
		#if defined(__linux__) && defined(__ELF__)
		.section .note.GNU-stack,"",%progbits
		#endif
		EOF
	done
	epatch \
		"${FILESDIR}"/${P}-underlink.patch \
		"${FILESDIR}"/${P}-segfault.patch \
		"${FILESDIR}"/${P}-flags.patch
	sed -i \
		-e "/scoredir/s#/var/games/powermanga#${GAMES_DATADIR}/powermanga#" \
		src/Makefile.am || die
	eautoreconf
}

src_configure() {
	egamesconf --prefix=/usr
}

src_install() {
	newgamesbin src/powermanga powermanga.bin
	doman powermanga.6
	dodoc AUTHORS CHANGES README

	insinto "${GAMES_DATADIR}/powermanga"
	doins -r data sounds graphics texts

	find "${D}${GAMES_DATADIR}/powermanga/" -name "Makefil*" -execdir rm -f \{\} +

	insinto "${GAMES_STATEDIR}"
	local f
	for f in powermanga.hi-easy powermanga.hi powermanga.hi-hard ; do
		touch "${D}${GAMES_STATEDIR}/${f}" || die
		fperms 660 "${GAMES_STATEDIR}/${f}"
	done

	games_make_wrapper powermanga powermanga.bin "${GAMES_DATADIR}/powermanga"
	make_desktop_entry powermanga Powermanga
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	ewarn "NOTE: The highscore file format has changed."
	ewarn "Older highscores will not be retained."
}