* [gentoo-commits] gentoo-x86 commit in sys-fs/udisks: ChangeLog udisks-1.0.4-r5.ebuild
@ 2013-01-25 4:34 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2013-01-25 4:34 UTC (permalink / raw
To: gentoo-commits
ssuominen 13/01/25 04:34:39
Modified: ChangeLog
Added: udisks-1.0.4-r5.ebuild
Log:
Revert part of upstream commit that prevented UDisks1 from polling for floppy drive so often but while at it broke the actual mounting of floppies wrt #338185 by Ian Abbott and others
(Portage version: 2.2.0_alpha155/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)
Revision Changes Path
1.119 sys-fs/udisks/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.119&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.119&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?r1=1.118&r2=1.119
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v
retrieving revision 1.118
retrieving revision 1.119
diff -u -r1.118 -r1.119
--- ChangeLog 19 Jan 2013 15:53:57 -0000 1.118
+++ ChangeLog 25 Jan 2013 04:34:39 -0000 1.119
@@ -1,6 +1,14 @@
# ChangeLog for sys-fs/udisks
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.118 2013/01/19 15:53:57 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.119 2013/01/25 04:34:39 ssuominen Exp $
+
+*udisks-1.0.4-r5 (25 Jan 2013)
+
+ 25 Jan 2013; Samuli Suominen <ssuominen@gentoo.org> +udisks-1.0.4-r5.ebuild,
+ +files/udisks-1.0.4-revert-floppy.patch:
+ Revert part of upstream commit that prevented UDisks1 from polling for floppy
+ drive so often but while at it broke the actual mounting of floppies wrt
+ #338185 by Ian Abbott and others
19 Jan 2013; Samuli Suominen <ssuominen@gentoo.org> udisks-1.0.4-r4.ebuild,
udisks-2.0.91.ebuild:
1.1 sys-fs/udisks/udisks-1.0.4-r5.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.4-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.4-r5.ebuild?rev=1.1&content-type=text/plain
Index: udisks-1.0.4-r5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/udisks-1.0.4-r5.ebuild,v 1.1 2013/01/25 04:34:39 ssuominen Exp $
EAPI=5
inherit eutils bash-completion-r1 linux-info udev
DESCRIPTION="Daemon providing interfaces to work with storage devices"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/udisks"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="debug nls remote-access selinux"
COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
>=dev-libs/glib-2.30
>=dev-libs/libatasmart-0.19
>=sys-auth/polkit-0.110
>=sys-apps/dbus-1.6
>=sys-apps/sg3_utils-1.27.20090411
>=sys-block/parted-3
>=sys-fs/lvm2-2.02.66
>=virtual/udev-197[gudev,hwdb]
selinux? ( sec-policy/selinux-devicekit )"
# util-linux -> mount, umount, swapon, swapoff (see also #403073)
RDEPEND="${COMMON_DEPEND}
>=sys-apps/util-linux-2.20.1-r2
virtual/eject
remote-access? ( net-dns/avahi )"
DEPEND="${COMMON_DEPEND}
app-text/docbook-xsl-stylesheets
dev-libs/libxslt
dev-util/intltool
virtual/pkgconfig"
pkg_setup() {
# Listing only major arch's here to avoid tracking kernel's defconfig
if use amd64 || use arm || use ppc || use ppc64 || use x86; then
CONFIG_CHECK="~!IDE" #319829
CONFIG_CHECK+=" ~USB_SUSPEND" #331065
CONFIG_CHECK+=" ~NLS_UTF8" #425562
linux-info_pkg_setup
fi
}
src_prepare() {
epatch \
"${FILESDIR}"/${PN}-1.0.2-ntfs-3g.patch \
"${FILESDIR}"/${P}-kernel-2.6.36-compat.patch \
"${FILESDIR}"/${P}-drop-pci-db.patch \
"${FILESDIR}"/${P}-revert-floppy.patch
sed -i -e "s:/lib/udev:$(udev_get_udevdir):" data/80-udisks.rules || die
}
src_configure() {
# device-mapper -> lvm2 -> mandatory depend -> force enabled
econf \
--localstatedir="${EPREFIX}"/var \
--disable-static \
$(use_enable debug verbose-mode) \
--enable-man-pages \
--disable-gtk-doc \
--enable-lvm2 \
--enable-dmmp \
$(use_enable remote-access) \
$(use_enable nls) \
--with-html-dir="${EPREFIX}"/deprecated
}
src_test() {
ewarn "Skipping testsuite because sys-fs/udisks:0 is deprecated"
ewarn "in favour of sys-fs/udisks:2."
}
src_install() {
emake \
DESTDIR="${D}" \
slashsbindir=/usr/sbin \
slashlibdir=/usr/lib \
udevhelperdir="$(udev_get_udevdir)" \
udevrulesdir="$(udev_get_udevdir)"/rules.d \
install #398081
dodoc AUTHORS HACKING NEWS README
rm -f "${ED}"/etc/profile.d/udisks-bash-completion.sh
newbashcomp tools/udisks-bash-completion.sh ${PN}
prune_libtool_files --all
keepdir /media
keepdir /var/lib/udisks #383091
rm -rf "${ED}"/deprecated
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-01-25 4:34 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-01-25 4:34 [gentoo-commits] gentoo-x86 commit in sys-fs/udisks: ChangeLog udisks-1.0.4-r5.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox