[gentoo-commits] gentoo-x86 commit in net-irc/znc: ChangeLog znc-1.0-r1.ebuild znc-1.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-irc/znc: ChangeLog znc-1.0-r1.ebuild znc-1.0.ebuild

[Alex Alexander (wired)]

wired       13/01/22 18:56:25

  Modified:             ChangeLog
  Added:                znc-1.0-r1.ebuild
  Removed:              znc-1.0.ebuild
  Log:
  changed default system-wide-config folder from /etc/znc to /var/lib/znc
  
  (Portage version: 2.2.0_alpha159/cvs/Linux x86_64, signed Manifest commit with key EB9B4AFA)

Revision  Changes    Path
1.61                 net-irc/znc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	21 Nov 2012 18:11:31 -0000	1.60
+++ ChangeLog	22 Jan 2013 18:56:25 -0000	1.61
@@ -1,6 +1,14 @@
 # ChangeLog for net-irc/znc
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.60 2012/11/21 18:11:31 wired Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.61 2013/01/22 18:56:25 wired Exp $
+
+*znc-1.0-r1 (22 Jan 2013)
+
+  22 Jan 2013; Alex Alexander <wired@gentoo.org> -znc-1.0.ebuild,
+  +znc-1.0-r1.ebuild, files/znc.confd:
+  changed default system-wide-config folder from /etc/znc to /var/lib/znc - znc
+  stores a lot of things in that folder - modules, logs, etc, making /var/lib a
+  better location for it.
 
 *znc-1.0 (21 Nov 2012)
 



1.1                  net-irc/znc/znc-1.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/znc-1.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/znc-1.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: znc-1.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/znc-1.0-r1.ebuild,v 1.1 2013/01/22 18:56:25 wired Exp $

EAPI=5

PYTHON_DEPEND="python? 3"
inherit base python user

MY_PV=${PV/_/-}
DESCRIPTION="An advanced IRC Bouncer"
HOMEPAGE="http://znc.in"
SRC_URI="http://znc.in/releases/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="daemon debug ipv6 perl python ssl sasl tcl"

RDEPEND="
	perl? ( >=dev-lang/perl-5.10 )
	sasl? ( >=dev-libs/cyrus-sasl-2 )
	ssl? ( >=dev-libs/openssl-0.9.7d )
	tcl? ( dev-lang/tcl )
"
DEPEND="
	virtual/pkgconfig
	perl? ( dev-lang/swig )
	python? (
		>=dev-lang/swig-2.0.2
		>=dev-lang/perl-5.10
	)
	${RDEPEND}
"

S=${WORKDIR}/${PN}-${MY_PV}

PATCHES=(
	"${FILESDIR}/${P}-systemwideconfig.patch"
)

CONFDIR="/var/lib/znc"

pkg_setup() {
	if use python; then
		python_set_active_version 3
		python_pkg_setup
	fi
	if use daemon; then
		enewgroup ${PN}
		enewuser ${PN} -1 -1 /dev/null ${PN}
	fi
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_enable perl) \
		$(use python && echo "--enable-python=python-$(python_get_version)") \
		$(use_enable sasl cyrus) \
		$(use_enable ssl openssl) \
		$(use_enable tcl tcl)
}

src_install() {
	emake install DESTDIR="${D}"
	dodoc AUTHORS README.md
	if use daemon; then
		newinitd "${FILESDIR}"/znc.initd znc
		newconfd "${FILESDIR}"/znc.confd znc
	fi
}

pkg_postinst() {
	if use !daemon; then
		elog
		elog "Run 'znc --makeconf' as the user you want to run ZNC as"
		elog "to make a configuration file"
		elog "If you are using SSL you should also run 'znc --makepem'"
		elog
	else
		elog
		elog "An init-script was installed in /etc/init.d"
		elog "A config file was installed in /etc/conf.d"
		if [[ ! -d "${EROOT}${CONFDIR}" ]]; then
			elog
			elog "Run 'emerge --config znc' to configure ZNC"
			elog "as a system-wide daemon."
			elog
			elog "If you are using SSL you should also run:"
			elog "  znc --system-wide-config-as znc --makepem -d ${CONFDIR}"
			elog "as root"
			elog
			elog "If migrating from a user-based install"
			elog "you can use your existing config files:"
			elog "  mkdir ${CONFDIR}"
			elog "  mv /home/\$USER/.znc/* ${CONFDIR}"
			elog "  rm -rf /home/\$USER/.znc"
			elog "  chown -R znc:znc ${CONFDIR}"
			elog
			elog "If you already have znc set up and want take advantage of the"
			elog "init script but skip of all the above, you can also edit"
			elog "  /etc/conf.d/znc"
			elog "and adjust the variables to your current znc user and config"
			elog "location."
			if [[ -d "${EROOT}"/etc/znc ]]; then
				elog
				ewarn "/etc/znc exists on your system."
				ewarn "Due to the nature of the contents of that folder,"
				ewarn "we have changed the default configuration to use"
				ewarn "	/var/lib/znc"
				ewarn "please move /etc/znc to /var/lib/znc"
				ewarn "or adjust /etc/conf.d/znc"
			fi
		else
			elog "Existing config detected in ${CONFDIR}"
			elog "You're good to go :)"
		fi
		elog
	fi
}

pkg_config() {
	if use daemon && ! [[ -d "${EROOT}${CONFDIR}" ]]; then
		einfo "Press ENTER to interactively create a new configuration file for znc."
		einfo "To abort, press Control-C"
		read
		mkdir -p "${EROOT}${CONFDIR}" || die
		chown -R ${PN}:${PN} "${EROOT}${CONFDIR}" ||
			die "Setting permissions failed"
		"${EROOT}"/usr/bin/znc --system-wide-config-as znc -c -r -d "${EROOT}${CONFDIR}" ||
			die "Config failed"
		echo
		einfo "To start znc, run '/etc/init.d/znc start'"
		einfo "or add znc to a runlevel:"
		einfo "  rc-update add znc default"
	else
		if use daemon; then
			ewarn "${CONFDIR} already exists, aborting to avoid damaging"
			ewarn "any existing configuration. If you are sure you want"
			ewarn "to generate a new configuration, remove the folder"
			ewarn "and try again."
		else
			ewarn "To configure znc as a system-wide daemon you have to"
			ewarn "enable the 'daemon' use flag."
		fi
	fi
}