* [gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: graphicsmagick-1.3.17.ebuild ChangeLog
@ 2012-10-15 6:03 Tim Harder (radhermit)
0 siblings, 0 replies; 2+ messages in thread
From: Tim Harder (radhermit) @ 2012-10-15 6:03 UTC (permalink / raw
To: gentoo-commits
radhermit 12/10/15 06:03:16
Modified: ChangeLog
Added: graphicsmagick-1.3.17.ebuild
Log:
Version bump. Update to EAPI 5.
(Portage version: 2.2.0_alpha136/cvs/Linux x86_64)
Revision Changes Path
1.108 media-gfx/graphicsmagick/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?r1=1.107&r2=1.108
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog 4 Oct 2012 14:59:10 -0000 1.107
+++ ChangeLog 15 Oct 2012 06:03:16 -0000 1.108
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/graphicsmagick
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.107 2012/10/04 14:59:10 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.108 2012/10/15 06:03:16 radhermit Exp $
+
+*graphicsmagick-1.3.17 (15 Oct 2012)
+
+ 15 Oct 2012; Tim Harder <radhermit@gentoo.org> +graphicsmagick-1.3.17.ebuild:
+ Version bump. Update to EAPI 5.
04 Oct 2012; Samuli Suominen <ssuominen@gentoo.org>
-graphicsmagick-1.3.13.ebuild,
1.1 media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild?rev=1.1&content-type=text/plain
Index: graphicsmagick-1.3.17.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild,v 1.1 2012/10/15 06:03:16 radhermit Exp $
EAPI=5
inherit toolchain-funcs
MY_P=${P/graphicsm/GraphicsM}
DESCRIPTION="Collection of tools and libraries for many image formats"
HOMEPAGE="http://www.graphicsmagick.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="bzip2 cxx debug fpx imagemagick jbig jpeg jpeg2k lcms lzma modules openmp perl png postscript q16 q32 static-libs svg threads tiff truetype wmf X zlib"
RDEPEND=">=sys-devel/libtool-2.2.6b
bzip2? ( app-arch/bzip2 )
fpx? ( media-libs/libfpx )
imagemagick? ( !media-gfx/imagemagick )
jbig? ( media-libs/jbigkit )
jpeg? ( virtual/jpeg )
jpeg2k? ( media-libs/jasper )
lcms? ( media-libs/lcms:2 )
lzma? ( app-arch/xz-utils )
perl? ( dev-lang/perl )
png? ( media-libs/libpng:0 )
postscript? ( app-text/ghostscript-gpl )
svg? ( dev-libs/libxml2 )
tiff? ( media-libs/tiff:0 )
truetype? (
media-fonts/urw-fonts
>=media-libs/freetype-2
)
wmf? ( media-libs/libwmf )
X? (
x11-libs/libSM
x11-libs/libXext
)
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"
S=${WORKDIR}/${MY_P}
src_configure() {
local depth=8
use q16 && depth=16
use q32 && depth=32
local openmp=disable
if use openmp && tc-has-openmp; then
openmp=enable
fi
econf \
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
--${openmp}-openmp \
--enable-largefile \
--enable-shared \
$(use_enable static-libs static) \
$(use_enable debug prof) \
$(use_enable debug gcov) \
$(use_enable imagemagick magick-compat) \
$(use_with threads) \
--without-included-ltdl \
$(use_with modules) \
--with-quantum-depth=${depth} \
--without-frozenpaths \
$(use_with cxx magick-plus-plus) \
$(use_with perl) \
--with-perl-options=INSTALLDIRS=vendor \
$(use_with bzip2 bzlib) \
$(use_with postscript dps) \
$(use_with fpx) \
--without-gslib \
$(use_with jbig) \
$(use_with jpeg) \
$(use_with jpeg2k jp2) \
--without-lcms \
$(use_with lcms lcms2) \
$(use_with lzma) \
$(use_with png) \
$(use_with tiff) \
$(use_with truetype ttf) \
$(use_with wmf) \
--with-fontpath="${EPREFIX}"/usr/share/fonts \
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts \
$(use_with svg xml) \
$(use_with zlib) \
$(use_with X x)
}
src_compile() {
emake
use perl && emake perl-build
}
src_install() {
emake DESTDIR="${D}" install
if use perl; then
emake -C PerlMagick DESTDIR="${D}" install
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
fi
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: graphicsmagick-1.3.17.ebuild ChangeLog
@ 2013-01-21 5:18 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2013-01-21 5:18 UTC (permalink / raw
To: gentoo-commits
vapier 13/01/21 05:18:13
Modified: graphicsmagick-1.3.17.ebuild ChangeLog
Log:
Fix cross-compiling with freetype while upstream sorts it out.
(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.2 media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild?r1=1.1&r2=1.2
Index: graphicsmagick-1.3.17.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- graphicsmagick-1.3.17.ebuild 15 Oct 2012 06:03:16 -0000 1.1
+++ graphicsmagick-1.3.17.ebuild 21 Jan 2013 05:18:13 -0000 1.2
@@ -1,9 +1,9 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild,v 1.1 2012/10/15 06:03:16 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.17.ebuild,v 1.2 2013/01/21 05:18:13 vapier Exp $
EAPI=5
-inherit toolchain-funcs
+inherit toolchain-funcs eutils
MY_P=${P/graphicsm/GraphicsM}
@@ -44,6 +44,10 @@
S=${WORKDIR}/${MY_P}
+src_prepare() {
+ epatch "${FILESDIR}"/${PN}-1.3.17-freetype.patch
+}
+
src_configure() {
local depth=8
use q16 && depth=16
1.109 media-gfx/graphicsmagick/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?r1=1.108&r2=1.109
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog 15 Oct 2012 06:03:16 -0000 1.108
+++ ChangeLog 21 Jan 2013 05:18:13 -0000 1.109
@@ -1,6 +1,10 @@
# ChangeLog for media-gfx/graphicsmagick
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.108 2012/10/15 06:03:16 radhermit Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.109 2013/01/21 05:18:13 vapier Exp $
+
+ 21 Jan 2013; Mike Frysinger <vapier@gentoo.org>
+ +files/graphicsmagick-1.3.17-freetype.patch, graphicsmagick-1.3.17.ebuild:
+ Fix cross-compiling with freetype while upstream sorts it out.
*graphicsmagick-1.3.17 (15 Oct 2012)
@@ -341,4 +345,3 @@
02 Aug 2008; Janne Rönkkö (jroo) <jroo@iki.fi>
+graphicsmagick-1.2.5.ebuild, +metadata.xml:
New Ebuild for bug 190372.
-
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-01-21 5:18 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-01-21 5:18 [gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: graphicsmagick-1.3.17.ebuild ChangeLog Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2012-10-15 6:03 Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox