[gentoo-commits] gentoo-x86 commit in dev-util/global: global-6.2.7.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-util/global: global-6.2.7.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     13/01/20 19:00:22

  Modified:             ChangeLog
  Added:                global-6.2.7.ebuild
  Log:
  Version bump by Arfrever.
  
  (Portage version: 2.2.0_alpha155/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.105                dev-util/global/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.105&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.105&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?r1=1.104&r2=1.105

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v
retrieving revision 1.104
retrieving revision 1.105
diff -u -r1.104 -r1.105
--- ChangeLog	9 Sep 2012 16:02:29 -0000	1.104
+++ ChangeLog	20 Jan 2013 19:00:22 -0000	1.105
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/global
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.104 2012/09/09 16:02:29 armin76 Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.105 2013/01/20 19:00:22 floppym Exp $
+
+*global-6.2.7 (20 Jan 2013)
+
+  20 Jan 2013; Mike Gilbert <floppym@gentoo.org> +global-6.2.7.ebuild:
+  Version bump by Arfrever.
 
   09 Sep 2012; Raúl Porcel <armin76@gentoo.org> global-5.9.5.ebuild,
   global-5.9.7.ebuild, global-6.1.ebuild, global-6.2.ebuild,



1.1                  dev-util/global/global-6.2.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-6.2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-6.2.7.ebuild?rev=1.1&content-type=text/plain

Index: global-6.2.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-6.2.7.ebuild,v 1.1 2013/01/20 19:00:22 floppym Exp $

EAPI="5"

inherit elisp-common eutils

DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
HOMEPAGE="http://www.gnu.org/software/global/global.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="doc emacs vim"

RDEPEND="emacs? ( virtual/emacs )
	vim? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="${DEPEND}
	doc? ( app-text/texi2html sys-apps/texinfo )"

SITEFILE="50gtags-gentoo.el"

src_configure() {
	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
}

src_compile() {
	if use doc; then
		texi2pdf -q -o doc/global.pdf doc/global.texi
		texi2html -o doc/global.html doc/global.texi
	fi

	if use emacs; then
		elisp-compile *.el || die "elisp-compile failed"
	fi

	emake
}

src_install() {
	emake DESTDIR="${D}" install

	if use doc; then
		dohtml doc/global.html
		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
	fi

	dodoc AUTHORS FAQ NEWS README THANKS

	insinto /etc
	doins gtags.conf

	if use vim; then
		insinto /usr/share/vim/vimfiles/plugin
		doins gtags.vim
	fi

	if use emacs; then
		elisp-install ${PN} *.{el,elc} || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"
	fi

	prune_libtool_files --all
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}