[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20130119.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20130119.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    13/01/20 10:58:08

  Modified:             ChangeLog
  Added:                plan9port-20130119.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.9                  dev-util/plan9port/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	6 Jan 2013 15:45:59 -0000	1.8
+++ ChangeLog	20 Jan 2013 10:58:07 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/plan9port
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.8 2013/01/06 15:45:59 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.9 2013/01/20 10:58:07 blueness Exp $
+
+*plan9port-20130119 (20 Jan 2013)
+
+  20 Jan 2013; Anthony G. Basile <blueness@gentoo.org>
+  +plan9port-20130119.ebuild:
+  Version bump
 
 *plan9port-20130105 (06 Jan 2013)
 



1.1                  dev-util/plan9port/plan9port-20130119.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20130119.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20130119.ebuild?rev=1.1&content-type=text/plain

Index: plan9port-20130119.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20130119.ebuild,v 1.1 2013/01/20 10:58:07 blueness Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Port of many Plan 9 programs and libraries"
HOMEPAGE="http://swtch.com/plan9port/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="9base BSD-4 MIT LGPL-2.1 BigelowHolmes"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-apps/xauth"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

PLAN9=/usr/lib/plan9

src_prepare()
{
	epatch "${FILESDIR}/${PN}-"{9660srv-errno,noexecstack}".patch"

	# Fix paths, done in place of ./INSTALL -c
	einfo "Fixing hard-coded /usr/local/plan9 paths"
	grep  --null -l -r '/usr/local/plan9' |
	xargs --null sed -i "s!/usr/local/plan9!${PLAN9}!g"
}

src_compile() {
	# Convert -j5 to NPROC=5 for mk
	export NPROC="$(echo "$MAKEOPTS" | sed -r -n 's/.*(^| )-j([0-9]*).*/\2/p')"

	# The INSTALL script builds mk then [re]builds everything using that
	einfo "Compiling Plan 9 from User Space can take a very long time"
	einfo "depending on the speed of your computer. Please be patient!"
	./INSTALL -b
}

src_install() {
	dodir "${PLAN9}"

	# P9P's man does not handle compression
	docompress -x $PLAN9/man

	# do* plays with the executable bit, and we should not modify them
	cp -a * "${D}/${PLAN9}"

	# build the environment variables and install them in env.d
	cat > "${T}/30plan9" <<-EOF
		PLAN9="${PLAN9}"
		PATH="${PLAN9}/bin"
		ROOTPATH="${PLAN9}/bin"
		MANPATH="${PLAN9}/man"
	EOF
	doenvd "${T}/30plan9"
}

pkg_postinst() {
	elog "Plan 9 from User Space has been successfully installed into"
	elog "${PLAN9}. Your PLAN9 and PATH environment variables have"
	elog "also been appropriately set, please use env-update and"
	elog "source /etc/profile to bring that into immediate effect."
	elog
	elog "Please note that ${PLAN9}/bin has been appended to the"
	elog "*end* or your PATH to prevent conflicts. To use the Plan9"
	elog "versions of common UNIX tools, use the absolute path:"
	elog "${PLAN9}/bin or the 9 command (eg: 9 troff)"
	elog
	elog "Please report any bugs to bugs.gentoo.org, NOT Plan9Port."
}