[gentoo-commits] gentoo-x86 commit in x11-misc/spacefm: ChangeLog spacefm-0.8.5.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/spacefm: ChangeLog spacefm-0.8.5.ebuild

[Julian Ospald (hasufell)]

hasufell    13/01/14 17:55:16

  Modified:             ChangeLog
  Added:                spacefm-0.8.5.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha151/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.45                 x11-misc/spacefm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/spacefm/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/spacefm/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/spacefm/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/spacefm/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	25 Dec 2012 02:58:42 -0000	1.44
+++ ChangeLog	14 Jan 2013 17:55:16 -0000	1.45
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/spacefm
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/ChangeLog,v 1.44 2012/12/25 02:58:42 jdhore Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/ChangeLog,v 1.45 2013/01/14 17:55:16 hasufell Exp $
+
+*spacefm-0.8.5 (14 Jan 2013)
+
+  14 Jan 2013; Julian Ospald <hasufell@gentoo.org> +spacefm-0.8.5.ebuild:
+  version bump
 
   25 Dec 2012; Jeff Horelick <jdhore@gentoo.org> spacefm-0.8.3.ebuild:
   marked x86 per bug 448040



1.1                  x11-misc/spacefm/spacefm-0.8.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/spacefm/spacefm-0.8.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/spacefm/spacefm-0.8.5.ebuild?rev=1.1&content-type=text/plain

Index: spacefm-0.8.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/spacefm-0.8.5.ebuild,v 1.1 2013/01/14 17:55:16 hasufell Exp $

EAPI=5

inherit fdo-mime gnome2-utils linux-info

DESCRIPTION="A multi-panel tabbed file manager"
HOMEPAGE="http://ignorantguru.github.com/spacefm/"
SRC_URI="http://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz
	mirror://sourceforge/${PN}/${P}.tar.xz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+startup-notification"

RDEPEND="dev-libs/glib:2
	dev-util/desktop-file-utils
	>=virtual/udev-143
	virtual/freedesktop-icon-theme
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	x11-libs/pango
	x11-libs/libX11
	x11-misc/shared-mime-info
	startup-notification? ( x11-libs/startup-notification )"
DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig
	sys-devel/gettext"

src_configure() {
	econf \
		--htmldir=/usr/share/doc/${PF}/html \
		$(use_enable startup-notification) \
		--disable-hal \
		--enable-inotify \
		--disable-pixmaps \
		--with-gtk3=no # still glitches in gtk3
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update

	einfo
	elog "To mount as non-root user you need one of the following:"
	elog "  sys-apps/udevil (recommended, see below)"
	elog "  sys-apps/pmount"
	elog "  sys-fs/udisks:0"
	elog "  sys-fs/udisks:2"
	elog "To support ftp/nfs/smb/ssh URLs in the path bar you need:"
	elog "  sys-apps/udevil"
	elog "To perform as root functionality you need one of the following:"
	elog "  x11-misc/ktsuss"
	elog "  x11-libs/gksu"
	elog "  kde-base/kdesu"
	elog "Other optional dependencies:"
	elog "  sys-apps/dbus"
	elog "  sys-process/lsof (device processes)"
	elog "  virtual/eject (eject media)"
	einfo
	if ! has_version 'sys-fs/udisks' ; then
		elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
		elog "you may need to enable kernel polling for device media changes to be detected."
		elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
		has_version '<virtual/udev-173' && ewarn "You need at least udev-173"
		kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
		einfo
	fi
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}