[gentoo-commits] gentoo-x86 commit in app-portage/eix: ChangeLog eix-0.28.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-portage/eix: ChangeLog eix-0.28.0.ebuild

[Ian Stakenvicius (axs)]

axs         13/01/14 13:54:01

  Modified:             ChangeLog
  Added:                eix-0.28.0.ebuild
  Log:
  version bump; internal restructuring, minor bugfixes, documentation updates
  
  (Portage version: 2.1.11.38/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.442                app-portage/eix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?rev=1.442&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?rev=1.442&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?r1=1.441&r2=1.442

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v
retrieving revision 1.441
retrieving revision 1.442
diff -u -r1.441 -r1.442
--- ChangeLog	22 Dec 2012 16:42:43 -0000	1.441
+++ ChangeLog	14 Jan 2013 13:54:01 -0000	1.442
@@ -1,6 +1,11 @@
 # ChangeLog for app-portage/eix
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v 1.441 2012/12/22 16:42:43 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v 1.442 2013/01/14 13:54:01 axs Exp $
+
+*eix-0.28.0 (14 Jan 2013)
+
+  14 Jan 2013; Ian Stakenvicius <axs@gentoo.org> +eix-0.28.0.ebuild:
+  version bump; internal restructuring, minor bugfixes, documentation updates
 
   22 Dec 2012; Agostino Sarubbo <ago@gentoo.org> eix-0.27.6.ebuild:
   Add ~ppc, wrt bug #425494



1.1                  app-portage/eix/eix-0.28.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/eix-0.28.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/eix-0.28.0.ebuild?rev=1.1&content-type=text/plain

Index: eix-0.28.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/eix-0.28.0.ebuild,v 1.1 2013/01/14 13:54:01 axs Exp $

EAPI=5

PLOCALES="de ru"
inherit bash-completion-r1 eutils multilib l10n

DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
HOMEPAGE="http://eix.berlios.de"
SRC_URI="mirror://berlios/${PN}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="clang debug +dep doc nls optimization security strong-optimization sqlite tools zsh-completion"

RDEPEND="app-shells/push
	sqlite? ( >=dev-db/sqlite-3 )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	clang? ( sys-devel/clang )
	nls? ( sys-devel/gettext )"

pkg_setup() {
	if [[ ${REPLACING_VERSIONS//./} -lt 0253 ]]; then
	    local eixcache="${EROOT}"/var/cache/${PN}
	    [[ -f ${eixcache} ]] && rm -f "${eixcache}"
	fi
}

src_prepare() {
	epatch_user
}

src_configure() {
	econf $(use_with sqlite) $(use_with doc extra-doc) \
		$(use_with zsh-completion) \
		$(use_enable nls) $(use_enable tools separate-tools) \
		$(use_enable security) $(use_enable optimization) \
		$(use_enable strong-optimization) $(use_enable debug debugging) \
		$(use_with prefix always-accept-keywords) \
		$(use_with dep dep-default) \
		$(use_with clang nongnu-cxx clang++) \
		--with-ebuild-sh-default="/usr/$(get_libdir)/portage/bin/ebuild.sh" \
		--with-portage-rootpath="${ROOTPATH}" \
		--with-eprefix-default="${EPREFIX}" \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
}

src_install() {
	default
	dobashcomp bash/eix
	keepdir "/var/cache/${PN}"
	fowners portage:portage "/var/cache/${PN}"
	fperms 775 "/var/cache/${PN}"
}

pkg_postinst() {
	# fowners in src_install doesn't work for owner/group portage:
	# merging changes this owner/group back to root.
	use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
	local obs="${EROOT}var/cache/eix.previous"
	! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
}