[gentoo-commits] gentoo-x86 commit in net-analyzer/ettercap: ettercap-0.7.5.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-analyzer/ettercap: ettercap-0.7.5.1.ebuild ChangeLog

[Agostino Sarubbo (ago)]

ago         13/01/06 19:22:40

  Modified:             ChangeLog
  Added:                ettercap-0.7.5.1.ebuild
  Log:
  Version bump to 0.7.5.1
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.113                net-analyzer/ettercap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/ettercap/ChangeLog?rev=1.113&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/ettercap/ChangeLog?rev=1.113&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/ettercap/ChangeLog?r1=1.112&r2=1.113

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ChangeLog,v
retrieving revision 1.112
retrieving revision 1.113
diff -u -r1.112 -r1.113
--- ChangeLog	3 Jan 2013 13:18:23 -0000	1.112
+++ ChangeLog	6 Jan 2013 19:22:40 -0000	1.113
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/ettercap
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ChangeLog,v 1.112 2013/01/03 13:18:23 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ChangeLog,v 1.113 2013/01/06 19:22:40 ago Exp $
+
+*ettercap-0.7.5.1 (06 Jan 2013)
+
+  06 Jan 2013; Agostino Sarubbo <ago@gentoo.org> +ettercap-0.7.5.1.ebuild:
+  Version bump to 0.7.5.1
 
 *ettercap-0.7.5_p20130103 (03 Jan 2013)
 



1.1                  net-analyzer/ettercap/ettercap-0.7.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/ettercap/ettercap-0.7.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/ettercap/ettercap-0.7.5.1.ebuild?rev=1.1&content-type=text/plain

Index: ettercap-0.7.5.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ettercap-0.7.5.1.ebuild,v 1.1 2013/01/06 19:22:40 ago Exp $

EAPI=4

CMAKE_MIN_VERSION=2.8

inherit cmake-utils

DESCRIPTION="A suite for man in the middle attacks"
HOMEPAGE="https://github.com/Ettercap/ettercap"
SRC_URI="https://github.com/Ettercap/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz" #mirror does not work

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="gtk ipv6 ncurses +plugins ssl"

RDEPEND="dev-libs/libpcre
	net-libs/libnet:1.1
	>=net-libs/libpcap-0.8.1
	sys-libs/zlib
	gtk? (
		>=dev-libs/atk-1.2.4
		>=dev-libs/glib-2.2.2:2
		media-libs/freetype
		x11-libs/cairo
		x11-libs/gdk-pixbuf:2
		>=x11-libs/gtk+-2.2.2:2
		>=x11-libs/pango-1.2.3
	)
	ncurses? ( >=sys-libs/ncurses-5.3 )
	plugins? (
		>=net-misc/curl-7.26.0
		sys-devel/libtool
	)
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	app-text/ghostscript-gpl
	sys-devel/flex
	virtual/yacc"

src_prepare() {
	#ettercap defaults to using mozilla so let's try to use xdg-open and pray it works
	sed -i 's#mozilla -remote openurl(http://%host%url)#xdg-open 'http://%host%url'#' \
	share/etter.conf || die
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable ncurses CURSES)
		$(cmake-utils_use_enable gtk)
		$(cmake-utils_use_enable ssl)
		$(cmake-utils_use_enable plugins)
		$(cmake-utils_use_enable ipv6)
	)
	cmake-utils_src_configure
}