[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20130103.ebuild plan9port-20121219.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20130103.ebuild plan9port-20121219.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    13/01/05 13:00:12

  Modified:             plan9port-20121219.ebuild ChangeLog
  Added:                plan9port-20130103.ebuild
  Log:
  Version bump, fix up license
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.3                  dev-util/plan9port/plan9port-20121219.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild?r1=1.2&r2=1.3

Index: plan9port-20121219.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- plan9port-20121219.ebuild	4 Jan 2013 04:06:41 -0000	1.2
+++ plan9port-20121219.ebuild	5 Jan 2013 13:00:12 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild,v 1.2 2013/01/04 04:06:41 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20121219.ebuild,v 1.3 2013/01/05 13:00:12 blueness Exp $
 
 EAPI="4"
 
@@ -10,7 +10,7 @@
 HOMEPAGE="http://swtch.com/plan9port/"
 SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"
 
-LICENSE="9base"
+LICENSE="9base BSD-4 MIT LGPL-2.1 BigelowHolmes"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE=""



1.7                  dev-util/plan9port/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	4 Jan 2013 04:06:41 -0000	1.6
+++ ChangeLog	5 Jan 2013 13:00:12 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/plan9port
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.6 2013/01/04 04:06:41 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.7 2013/01/05 13:00:12 blueness Exp $
+
+*plan9port-20130103 (05 Jan 2013)
+
+  05 Jan 2013; Anthony G. Basile <blueness@gentoo.org>
+  +plan9port-20130103.ebuild, plan9port-20121219.ebuild:
+  Version bump, fix up license
 
 *plan9port-20121219 (27 Dec 2012)
 
@@ -37,4 +43,3 @@
   +metadata.xml, +plan9port-20070522.ebuild:
   Initial ebuild for Plan9Port, a set of Plan 9 utilities ported to POSIX
   environments.
-



1.1                  dev-util/plan9port/plan9port-20130103.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20130103.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20130103.ebuild?rev=1.1&content-type=text/plain

Index: plan9port-20130103.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20130103.ebuild,v 1.1 2013/01/05 13:00:12 blueness Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Port of many Plan 9 programs and libraries"
HOMEPAGE="http://swtch.com/plan9port/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="9base BSD-4 MIT LGPL-2.1 BigelowHolmes"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-apps/xauth"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

PLAN9=/usr/lib/plan9

src_prepare()
{
	epatch "${FILESDIR}/${PN}-"{9660srv-errno,noexecstack}".patch"

	# Fix paths, done in place of ./INSTALL -c
	einfo "Fixing hard-coded /usr/local/plan9 paths"
	grep  --null -l -r '/usr/local/plan9' |
	xargs --null sed -i "s!/usr/local/plan9!${PLAN9}!g"
}

src_compile() {
	# Convert -j5 to NPROC=5 for mk
	export NPROC="$(echo "$MAKEOPTS" | sed -r -n 's/.*(^| )-j([0-9]*).*/\2/p')"

	# The INSTALL script builds mk then [re]builds everything using that
	einfo "Compiling Plan 9 from User Space can take a very long time"
	einfo "depending on the speed of your computer. Please be patient!"
	./INSTALL -b
}

src_install() {
	dodir "${PLAN9}"

	# P9P's man does not handle compression
	docompress -x $PLAN9/man

	# do* plays with the executable bit, and we should not modify them
	cp -a * "${D}/${PLAN9}"

	# build the environment variables and install them in env.d
	cat > "${T}/30plan9" <<-EOF
		PLAN9="${PLAN9}"
		PATH="${PLAN9}/bin"
		ROOTPATH="${PLAN9}/bin"
		MANPATH="${PLAN9}/man"
	EOF
	doenvd "${T}/30plan9"
}

pkg_postinst() {
	elog "Plan 9 from User Space has been successfully installed into"
	elog "${PLAN9}. Your PLAN9 and PATH environment variables have"
	elog "also been appropriately set, please use env-update and"
	elog "source /etc/profile to bring that into immediate effect."
	elog
	elog "Please note that ${PLAN9}/bin has been appended to the"
	elog "*end* or your PATH to prevent conflicts. To use the Plan9"
	elog "versions of common UNIX tools, use the absolute path:"
	elog "${PLAN9}/bin or the 9 command (eg: 9 troff)"
	elog
	elog "Please report any bugs to bugs.gentoo.org, NOT Plan9Port."
}