[gentoo-commits] gentoo-x86 commit in net-dialup/accel-ppp: accel-ppp-1.7.3.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in net-dialup/accel-ppp: accel-ppp-1.7.3.ebuild ChangeLog metadata.xml

[Sergey Popov (pinkbyte)]

pinkbyte    13/01/03 21:32:08

  Added:                accel-ppp-1.7.3.ebuild ChangeLog metadata.xml
  Log:
  Initial commit, wrt bug #448054. Thanks to all, who helps writing ebuild and other stuff
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.1                  net-dialup/accel-ppp/accel-ppp-1.7.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.7.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.7.3.ebuild?rev=1.1&content-type=text/plain

Index: accel-ppp-1.7.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.7.3.ebuild,v 1.1 2013/01/03 21:32:08 pinkbyte Exp $

EAPI=5

inherit cmake-utils linux-info

DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
HOMEPAGE="http://accel-ppp.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc postgres radius shaper snmp"

DEPEND="postgres? ( dev-db/postgresql-base )
	snmp? ( net-analyzer/net-snmp )
	dev-libs/libpcre
	dev-libs/openssl:0"
RDEPEND="${DEPEND}"

DOCS=( README )
CONFIG_CHECK="~CONFIG_L2TP ~CONFIG_PPPOE ~CONFIG_PPTP"

src_prepare() {
	sed -i  -e "/mkdir/d" \
		-e "/echo/d" \
		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
	# TBF shaper is obsolete by upstream, so it's disabled
	epatch "${FILESDIR}/${PN}-remove_obsolete_tbf_shaper.patch"

	# Respect lib64
	for i in $(find . -name CMakeLists.txt) ; do
		sed -i -e "s:\(DESTINATION lib\):\1\${LIB_SUFFIX}:" "$i" || die 'sed failed'
	done

	epatch_user
}

src_configure() {
	# There must be also dev-libs/tomcrypt (TOMCRYPT) as crypto alternative to OpenSSL
	local mycmakeargs=(
		-DBUILD_DRIVER=FALSE
		-DCRYPTO=OPENSSL
		$(cmake-utils_use debug MEMDEBUG)
		$(cmake-utils_use debug VALGRIND)
		$(cmake-utils_use postgres LOG_PGSQL)
		$(cmake-utils_use radius RADIUS)
		$(cmake-utils_use shaper SHAPER)
		$(cmake-utils_use snmp NETSNMP)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	use doc && dodoc -r rfc

	if use snmp; then
		insinto /usr/share/snmp/mibs
		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
	fi

	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
	newconfd "${FILESDIR}"/${PN}.confd ${PN}d

	dodir /var/log/accel-ppp
}



1.1                  net-dialup/accel-ppp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-dialup/accel-ppp
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/ChangeLog,v 1.1 2013/01/03 21:32:08 pinkbyte Exp $

*accel-ppp-1.7.3 (03 Jan 2013)

  03 Jan 2013; Sergey Popov <pinkbyte@gentoo.org> +accel-ppp-1.7.3.ebuild,
  +files/accel-ppp.confd, +files/accel-ppp.initd,
  +files/accel-ppp-remove_obsolete_tbf_shaper.patch, +metadata.xml:
  Initial commit, wrt bug #448054. Thanks to all, who helps writing ebuild and
  other stuff




1.1                  net-dialup/accel-ppp/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>pinkbyte@gentoo.org</email>
		<name>Sergey Popov</name>
	</maintainer>
	<use>
		<flag name="shaper">Support for traffic shaping</flag>
	</use>
</pkgmetadata>