[gentoo-commits] gentoo-x86 commit in dev-libs/dietlibc: dietlibc-0.33_pre20130103.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/dietlibc: dietlibc-0.33_pre20130103.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/01/03 20:15:02

  Modified:             ChangeLog
  Added:                dietlibc-0.33_pre20130103.ebuild
  Log:
  Bump with snapshot taken today to get all the changes upstream did
  
  (Portage version: 2.1.11.38/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.94                 dev-libs/dietlibc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dietlibc/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dietlibc/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dietlibc/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/dietlibc/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	1 Jan 2013 11:42:02 -0000	1.93
+++ ChangeLog	3 Jan 2013 20:15:02 -0000	1.94
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/dietlibc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dietlibc/ChangeLog,v 1.93 2013/01/01 11:42:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dietlibc/ChangeLog,v 1.94 2013/01/03 20:15:02 pacho Exp $
+
+*dietlibc-0.33_pre20130103 (03 Jan 2013)
+
+  03 Jan 2013; Pacho Ramos <pacho@gentoo.org> +dietlibc-0.33_pre20130103.ebuild:
+  Bump with snapshot taken today to get all the changes upstream did
 
   01 Jan 2013; Agostino Sarubbo <ago@gentoo.org>
   dietlibc-0.33_pre20110403.ebuild:



1.1                  dev-libs/dietlibc/dietlibc-0.33_pre20130103.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dietlibc/dietlibc-0.33_pre20130103.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dietlibc/dietlibc-0.33_pre20130103.ebuild?rev=1.1&content-type=text/plain

Index: dietlibc-0.33_pre20130103.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/dietlibc/dietlibc-0.33_pre20130103.ebuild,v 1.1 2013/01/03 20:15:02 pacho Exp $

EAPI=5
inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="A libc optimized for small size"
HOMEPAGE="http://www.fefe.de/dietlibc/"
SRC_URI="http://dev.gentoo.org/~pacho/maintainer-needed/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm -hppa ~ia64 ~mips ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE=""

DEPEND=""
RDEPEND=""

DIETHOME=/usr/diet

src_prepare() {
	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
	use sparc && replace-sparc64-flags

	# gcc-hppa suffers support for SSP, compilation will fail
	use hppa && strip-unsupported-flags

	# Makefile does not append CFLAGS
	append-flags -nostdinc -W -Wall -Wextra -Wchar-subscripts \
		-Wmissing-prototypes -Wmissing-declarations -Wno-switch \
		-Wno-unused -Wredundant-decls -fno-strict-aliasing

	# only use -nopie on archs that support it
	gcc-specs-pie && append-flags -nopie

	sed -i -e 's:strip::' Makefile || die
	append-flags -Wa,--noexecstack
}

src_compile() {
	emake prefix="${EPREFIX}"${DIETHOME} \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		STRIP=":"
}

src_install() {
	emake prefix="${EPREFIX}"${DIETHOME} \
		DESTDIR="${D}" \
		install-bin \
		install-headers

	dobin "${ED}"${DIETHOME}/bin/*
	doman "${ED}"${DIETHOME}/man/*/*
	rm -r "${ED}"${DIETHOME}/{man,bin} || die

	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
}