[gentoo-commits] gentoo-x86 commit in dev-vcs/tortoisehg: ChangeLog tortoisehg-2.6.2.ebuild tortoisehg-2.6.ebuild

["Lars Wendler (polynomial-c)" <polynomial-c@gentoo.org>]

polynomial-c    13/01/03 14:49:50

  Modified:             ChangeLog
  Added:                tortoisehg-2.6.2.ebuild
  Removed:              tortoisehg-2.6.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.28                 dev-vcs/tortoisehg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	20 Dec 2012 13:36:53 -0000	1.27
+++ ChangeLog	3 Jan 2013 14:49:50 -0000	1.28
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/tortoisehg
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.27 2012/12/20 13:36:53 polynomial-c Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.28 2013/01/03 14:49:50 polynomial-c Exp $
+
+*tortoisehg-2.6.2 (03 Jan 2013)
+
+  03 Jan 2013; Lars Wendler <polynomial-c@gentoo.org> -tortoisehg-2.6.ebuild,
+  +tortoisehg-2.6.2.ebuild:
+  Version bump. Removed old.
 
 *tortoisehg-2.6.1 (20 Dec 2012)
 



1.1                  dev-vcs/tortoisehg/tortoisehg-2.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.6.2.ebuild?rev=1.1&content-type=text/plain

Index: tortoisehg-2.6.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.6.2.ebuild,v 1.1 2013/01/03 14:49:50 polynomial-c Exp $

EAPI=4

SUPPORT_PYTHON_ABIS=1
PYTHON_DEPEND="2:2.5"
RESTRICT_PYTHON_ABIS="2.4 3.* *-pypy-*"

inherit distutils eutils

# At the time I added this ebuild the 2.6.2 source tarball was not available
# at the usual upstream download space although the release was already
# announced. So I created the tarball through the following steps:
#   hg clone https://bitbucket.org/tortoisehg/thg
#   hg checkout 2.6.2
#   cd thg && python setup.py sdist && ls -l dist/

if [[ ${PV} != *9999* ]]; then
	KEYWORDS="~amd64 ~x86"
	#SRC_URI="mirror://bitbucket/${PN}/targz/downloads/${MY_P}.tar.gz"
	SRC_URI="http://dev.gentoo.org/~polynomial-c/${P}.tar.gz"
	HG_DEPEND=">=dev-vcs/mercurial-2.3 <dev-vcs/mercurial-2.5"
else
	inherit mercurial
	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
	KEYWORDS=""
	SRC_URI=""
	HG_DEPEND="dev-vcs/mercurial"
fi

DESCRIPTION="Set of graphical tools for Mercurial"
HOMEPAGE="http://tortoisehg.bitbucket.org"

LICENSE="GPL-2"
SLOT="0"
IUSE="doc"

RDEPEND="${HG_DEPEND}
	dev-python/iniparse
	dev-python/pygments
	dev-python/PyQt4
	dev-python/qscintilla-python"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-1.0.3 )"

src_prepare() {
	if [[ ${LINGUAS+set} ]]; then
		pushd i18n/tortoisehg > /dev/null || die
		local x y keep
		for x in *.po; do
			keep=false
			for y in ${LINGUAS}; do
				if [[ ${y} == ${x%.po}* ]]; then
					keep=true
					break
				fi
			done
			${keep} || rm "${x}" || die
		done
		popd > /dev/null || die
	fi

	distutils_src_prepare
}

src_compile() {
	distutils_src_compile

	if use doc ; then
		emake -C doc html
	fi
}

src_install() {
	distutils_src_install
	dodoc doc/ReadMe*.txt doc/TODO

	if use doc ; then
		dohtml -r doc/build/html
	fi

	newicon -s scalable icons/scalable/apps/thg-logo.svg tortoisehg_logo.svg
	domenu contrib/${PN}.desktop
}

pkg_postinst() {
	elog "When startup of ${PN} fails with an API version mismatch error"
	elog "between dev-python/sip and dev-python/PyQt4 please rebuild"
	elog "dev-python/qscintilla-python."
}