* [gentoo-commits] gentoo-x86 commit in net-libs/gnutls: ChangeLog gnutls-3.1.6.ebuild
@ 2013-01-02 23:34 Tim Harder (radhermit)
0 siblings, 0 replies; 2+ messages in thread
From: Tim Harder (radhermit) @ 2013-01-02 23:34 UTC (permalink / raw
To: gentoo-commits
radhermit 13/01/02 23:34:44
Modified: ChangeLog
Added: gnutls-3.1.6.ebuild
Log:
Version bump. Simplify adding linguas use flags to IUSE.
(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
Revision Changes Path
1.397 net-libs/gnutls/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.397&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.397&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?r1=1.396&r2=1.397
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v
retrieving revision 1.396
retrieving revision 1.397
diff -u -r1.396 -r1.397
--- ChangeLog 30 Dec 2012 11:58:43 -0000 1.396
+++ ChangeLog 2 Jan 2013 23:34:44 -0000 1.397
@@ -1,6 +1,11 @@
# ChangeLog for net-libs/gnutls
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.396 2012/12/30 11:58:43 flameeyes Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.397 2013/01/02 23:34:44 radhermit Exp $
+
+*gnutls-3.1.6 (02 Jan 2013)
+
+ 02 Jan 2013; Tim Harder <radhermit@gentoo.org> +gnutls-3.1.6.ebuild:
+ Version bump. Simplify adding linguas use flags to IUSE.
30 Dec 2012; Diego E. Pettenò <flameeyes@gentoo.org>
-files/gnutls-3.0.20-parallelmake.patch, -gnutls-3.1.3.ebuild,
1.1 net-libs/gnutls/gnutls-3.1.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild?rev=1.1&content-type=text/plain
Index: gnutls-3.1.6.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild,v 1.1 2013/01/02 23:34:44 radhermit Exp $
EAPI=4
inherit autotools libtool eutils
DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"
if [[ "${PV}" == *pre* ]]; then
SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
else
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
fi
# LGPL-3 for libgnutls library and GPL-3 for libgnutls-extra library.
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE_LINGUAS=" en cs de fi fr it ms nl pl sv uk vi zh_CN"
IUSE="+cxx dane doc examples guile nls pkcs11 static-libs test zlib ${IUSE_LINGUAS// / linguas_}"
RDEPEND=">=dev-libs/libtasn1-2.14
>=dev-libs/nettle-2.5[gmp]
sys-devel/autogen
dane? ( net-dns/unbound )
guile? ( >=dev-scheme/guile-1.8[networking] )
nls? ( virtual/libintl )
pkcs11? ( >=app-crypt/p11-kit-0.11 )
zlib? ( >=sys-libs/zlib-1.2.3.1 )"
DEPEND="${RDEPEND}
virtual/pkgconfig
sys-devel/libtool
doc? ( dev-util/gtk-doc )
nls? ( sys-devel/gettext )
test? ( app-misc/datefudge )"
S=${WORKDIR}/${P%_pre*}
DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )
src_prepare() {
local dir file
# tests/suite directory is not distributed.
sed -i \
-e ':AC_CONFIG_FILES(\[tests/suite/Makefile\]):d' \
-e '/^AM_INIT_AUTOMAKE/s/-Werror//' \
configure.ac || die
sed -i \
-e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' \
doc/Makefile.am || die
for dir in m4 gl/m4; do
rm -f "${dir}/lt"* "${dir}/libtool.m4"
done
find . -name ltmain.sh -exec rm {} \;
# use system libopts
sed -i -e "/^enable_local_libopts/s/yes/no/" configure.ac || die
# force regeneration of autogen-ed files
for file in $(grep -l AutoGen-ed src/*.c) ; do
rm src/$(basename ${file} .c).{c,h} || die
done
epatch "${FILESDIR}"/${PN}-3.1.3-guile-parallelmake.patch
# support user patches
epatch_user
eautoreconf
# Use sane .so versioning on FreeBSD.
elibtoolize
}
src_configure() {
LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
# TPM needs to be tested before being enabled
econf \
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
--disable-silent-rules \
--disable-valgrind-tests \
$(use_enable cxx) \
$(use_enable dane libdane) \
$(use_enable doc gtk-doc) \
$(use_enable doc gtk-doc-pdf) \
$(use_enable guile) \
$(use_enable nls) \
$(use_enable static-libs static) \
$(use_with pkcs11 p11-kit) \
$(use_with zlib) \
--without-tpm
}
src_test() {
# let it build in parallel
emake check
}
src_install() {
default
find "${ED}" -name '*.la' -exec rm -f {} +
dodoc doc/certtool.cfg
if use doc; then
dodoc doc/gnutls.pdf
dohtml doc/gnutls.html
fi
if use examples; then
docinto examples
dodoc doc/examples/*.c
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-libs/gnutls: ChangeLog gnutls-3.1.6.ebuild
@ 2013-01-03 3:13 Tim Harder (radhermit)
0 siblings, 0 replies; 2+ messages in thread
From: Tim Harder (radhermit) @ 2013-01-03 3:13 UTC (permalink / raw
To: gentoo-commits
radhermit 13/01/03 03:13:30
Modified: ChangeLog gnutls-3.1.6.ebuild
Log:
Use updated SRC_URI and drop guile parallel make patch since it's fixed upstream.
(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
Revision Changes Path
1.398 net-libs/gnutls/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.398&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.398&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?r1=1.397&r2=1.398
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v
retrieving revision 1.397
retrieving revision 1.398
diff -u -r1.397 -r1.398
--- ChangeLog 2 Jan 2013 23:34:44 -0000 1.397
+++ ChangeLog 3 Jan 2013 03:13:30 -0000 1.398
@@ -1,6 +1,10 @@
# ChangeLog for net-libs/gnutls
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.397 2013/01/02 23:34:44 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.398 2013/01/03 03:13:30 radhermit Exp $
+
+ 03 Jan 2013; Tim Harder <radhermit@gentoo.org> gnutls-3.1.6.ebuild:
+ Use updated SRC_URI and drop guile parallel make patch since it's fixed
+ upstream.
*gnutls-3.1.6 (02 Jan 2013)
1.2 net-libs/gnutls/gnutls-3.1.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild?r1=1.1&r2=1.2
Index: gnutls-3.1.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gnutls-3.1.6.ebuild 2 Jan 2013 23:34:44 -0000 1.1
+++ gnutls-3.1.6.ebuild 3 Jan 2013 03:13:30 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild,v 1.1 2013/01/02 23:34:44 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.1.6.ebuild,v 1.2 2013/01/03 03:13:30 radhermit Exp $
EAPI=4
@@ -8,12 +8,7 @@
DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"
-
-if [[ "${PV}" == *pre* ]]; then
- SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
-else
- SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
-fi
+SRC_URI="ftp://ftp.gnutls.org/gcrypt/gnutls/v${PV:0:3}/${P}.tar.xz"
# LGPL-3 for libgnutls library and GPL-3 for libgnutls-extra library.
LICENSE="GPL-3 LGPL-3"
@@ -37,8 +32,6 @@
nls? ( sys-devel/gettext )
test? ( app-misc/datefudge )"
-S=${WORKDIR}/${P%_pre*}
-
DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )
src_prepare() {
@@ -67,8 +60,6 @@
rm src/$(basename ${file} .c).{c,h} || die
done
- epatch "${FILESDIR}"/${PN}-3.1.3-guile-parallelmake.patch
-
# support user patches
epatch_user
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-01-03 3:13 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-01-02 23:34 [gentoo-commits] gentoo-x86 commit in net-libs/gnutls: ChangeLog gnutls-3.1.6.ebuild Tim Harder (radhermit)
-- strict thread matches above, loose matches on Subject: below --
2013-01-03 3:13 Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox